templates/hybrid-html5/etc/macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27
  28 # Generic useful macro
  29 # -----------------------
  30 macro(PROJECT_TARGET_ADD TARGET_NAME)
  31         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  32         set(TARGET_NAME ${TARGET_NAME})
  33 endmacro(PROJECT_TARGET_ADD)
  34
  35 # Check GCC minimal version version
  36 if (gcc_minimal_version)
  37    message ("-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})")
  38 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  39     message(FATAL_ERROR "**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  40 endif()
  41 endif(gcc_minimal_version)
  42
  43 macro(defstr name value)
  44         add_definitions(-D${name}=${value})
  45 endmacro(defstr)
  46
  47 # WGT packaging
  48 macro(project_targets_populate)
  49         add_custom_target(MAIN_POPULATE)
  50         foreach(TARGET ${PROJECT_TARGETS})
  51                 get_target_property(T ${TARGET} LABELS)
  52                 if(T)
  53                         # Declaration of a custom command that will populate widget tree with the target
  54                         set(POPULE_WIDGET_TARGET "project_populate_${TARGET}")
  55
  56                         get_target_property(P ${TARGET} PREFIX)
  57                         get_target_property(BD ${TARGET} BINARY_DIR)
  58                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  59
  60                         if(P MATCHES "NOTFOUND$")
  61                                 if (${T} STREQUAL "BINDING")
  62                                         set(P "lib")
  63                                 else()
  64                                         set(P "")
  65                                 endif()
  66                         endif()
  67
  68                         if(${T} STREQUAL "BINDING")
  69                                 add_custom_command(OUTPUT ${WIDGET_LIBDIR}/${P}${TARGET}.so
  70                                         DEPENDS ${TARGET}
  71                                         COMMAND mkdir -p ${WIDGET_LIBDIR}
  72                                         COMMAND cp ${BD}/${P}${OUT}.so ${WIDGET_LIBDIR}
  73                                 )
  74                                 add_custom_target(${POPULE_WIDGET_TARGET} DEPENDS ${WIDGET_LIBDIR}/${P}${TARGET}.so)
  75                                 add_dependencies(MAIN_POPULATE ${POPULE_WIDGET_TARGET})
  76                         elseif(${T} STREQUAL "EXECUTABLE")
  77                                 add_custom_command(OUTPUT ${WIDGET_BINDIR}/${P}${TARGET}
  78                                         DEPENDS ${TARGET}
  79                                         COMMAND mkdir -p ${WIDGET_BINDIR}
  80                                         COMMAND cp ${BD}/${P}${OUT} ${WIDGET_BINDIR}
  81                                 )
  82                                 add_custom_target(${POPULE_WIDGET_TARGET} DEPENDS ${WIDGET_BINDIR}/${P}${TARGET})
  83                                 add_dependencies(MAIN_POPULATE ${POPULE_WIDGET_TARGET})
  84                         elseif(${T} STREQUAL "HTDOCS")
  85                                 add_custom_command(OUTPUT ${WIDGET_HTTPDIR}
  86                                         DEPENDS ${TARGET}
  87                                         COMMAND cp -r ${BD}/${P}${OUT} ${WIDGET_HTTPDIR}
  88                                         )
  89                                         add_custom_target(${POPULE_WIDGET_TARGET} DEPENDS ${WIDGET_HTTPDIR})
  90                                         add_dependencies(MAIN_POPULATE ${POPULE_WIDGET_TARGET})
  91                         elseif(${T} STREQUAL "DATA")
  92                                 add_custom_command(OUTPUT ${WIDGET_DATADIR}
  93                                         DEPENDS ${TARGET}
  94                                         COMMAND cp -r ${BD}/${P}${OUT} ${WIDGET_DATADIR}
  95                                         )
  96                                         add_custom_target(${POPULE_WIDGET_TARGET} DEPENDS ${WIDGET_HTTPDIR})
  97                                         add_dependencies(MAIN_POPULATE ${POPULE_WIDGET_TARGET})
  98                         endif(${T} STREQUAL "BINDING")
  99 #               elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 100 #                                       MESSAGE(WARNING "This target, ${TARGET}, will be not be included in the package.")
 101                 endif()
 102         endforeach()
 103 endmacro(project_targets_populate)
 104
 105 macro(project_package_build)
 106                 if(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_WGT_DIR}/config.xml.in OR NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_WGT_DIR}/${PROJECT_ICON}.in)
 107                         MESSAGE(FATAL_ERROR "Missing mandatory files: you need config.xml.in and ${PROJECT_ICON}.in files in ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_WGT_DIR} folder.")
 108                 endif()
 109
 110                 if(NOT EXISTS ${WIDGET_DIR}/config.xml.in OR NOT EXISTS ${WIDGET_DIR}/${PROJECT_ICON}.in)
 111                         configure_file(${PROJECT_WGT_DIR}/config.xml.in ${WIDGET_DIR}/config.xml)
 112                         file(COPY ${PROJECT_WGT_DIR}/${PROJECT_ICON}.in DESTINATION ${WIDGET_DIR}/${PROJECT_ICON})
 113                 endif(NOT EXISTS ${WIDGET_DIR}/config.xml.in OR NOT EXISTS ${WIDGET_DIR}/${PROJECT_ICON}.in)
 114
 115                 file(GLOB PROJECT_CONF_FILES "${PROJECT_WGT_DIR}/etc/*")
 116                 if(${PROJECT_CONF_FILES})
 117                         file(COPY "${PROJECT_WGT_DIR}/etc/*" DESTINATION ${WIDGET_ETCDIR}/)
 118                 endif(${PROJECT_CONF_FILES})
 119
 120                 add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 121                         DEPENDS ${PROJECT_TARGETS}
 122                         COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${WIDGET_DIR}
 123                 )
 124
 125                 add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 126                 add_dependencies(widget MAIN_POPULATE)
 127                 set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 128
 129                 if(WIDGET_MESSAGE)
 130                 add_custom_command(TARGET widget
 131                         POST_BUILD
 132                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${WIDGET_MESSAGE}")
 133                 endif()
 134 endmacro(project_package_build)
 135
 136 macro(project_subdirs_add)
 137         if(${ARGV0})
 138                 file(GLOB filelist "${ARGV0}")
 139         else()
 140                 file(GLOB filelist "*")
 141         endif(${ARGV0})
 142
 143         foreach(filename ${filelist})
 144                 if(EXISTS "${filename}/CMakeLists.txt")
 145                         add_subdirectory(${filename})
 146                 endif(EXISTS "${filename}/CMakeLists.txt")
 147         endforeach()
 148 endmacro(project_subdirs_add)
 149
 150 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 151 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 152 set(CMP0048 1)
 153
 154 # Include project configuration
 155 # ------------------------------
 156 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 157 set(PROJECT_WGT_DIR "packaging/wgt" CACHE PATH "Subpath to the widget directory")
 158 set(PROJECT_LIBDIR "libs" CACHE PATH "Subpath to libraries")
 159 set(PROJECT_RESOURCES "data" CACHE PATH "Subpath to data")
 160
 161 INCLUDE(FindPkgConfig)
 162 INCLUDE(CheckIncludeFiles)
 163 INCLUDE(CheckLibraryExists)
 164 INCLUDE(GNUInstallDirs)
 165
 166 # Default compilation options
 167 ############################################################################
 168 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 169 add_compile_options(-Wall -Wextra -Wconversion)
 170 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 171 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 172 add_compile_options(-Werror=maybe-uninitialized)
 173 add_compile_options(-Werror=implicit-function-declaration)
 174 add_compile_options(-ffunction-sections -fdata-sections)
 175 add_compile_options(-fPIC)
 176 add_compile_options(-g)
 177
 178 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 179 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 180 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 181 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 182
 183 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 184 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 185 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 186 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 187
 188 set(CMAKE_INSTALL_PREFIX      "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 189
 190 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 191 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 192
 193 # Loop on required package and add options
 194 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 195         PKG_CHECK_MODULES(${PKG_CONFIG} REQUIRED ${PKG_CONFIG})
 196
 197         INCLUDE_DIRECTORIES(${${PKG_CONFIG}_INCLUDE_DIRS})
 198         list (APPEND link_libraries ${${PKG_CONFIG}_LIBRARIES})
 199         add_compile_options (${${PKG_CONFIG}_CFLAGS})
 200 endforeach(PKG_CONFIG)
 201
 202 # Optional LibEfence Malloc debug library
 203 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 204 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 205 IF(HAVE_LIBEFENCE)
 206         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 207         SET(libefence_LIBRARIES "-lefence")
 208         list (APPEND link_libraries ${libefence_LIBRARIES})
 209 ENDIF(HAVE_LIBEFENCE)
 210 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 211
 212 # set default include directories
 213 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 214
 215 # If no install dir try to guess some smart default
 216 if(BINDINGS_INSTALL_PREFIX)
 217         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME})
 218 else()
 219         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME})
 220 endif()
 221
 222 # Define a default package directory
 223 if(WIDGET_PREFIX)
 224         set(WIDGET_DIR ${WIDGET_PREFIX}/package)
 225 else()
 226         set(WIDGET_DIR ${CMAKE_CURRENT_BINARY_DIR}/package)
 227 endif()
 228
 229 # and their subsequent subdir
 230 set(WIDGET_BINDIR ${WIDGET_DIR}/bin)
 231 set(WIDGET_ETCDIR ${WIDGET_DIR}/etc)
 232 set(WIDGET_LIBDIR ${WIDGET_DIR}/lib)
 233 set(WIDGET_HTTPDIR ${WIDGET_DIR}/htdocs)
 234 set(WIDGET_DATADIR ${WIDGET_DIR}/data)
 235
 236 # Default Linkflag
 237 if(NOT BINDINGS_LINK_FLAG)
 238         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${CMAKE_SOURCE_DIR}/etc/export.map")
 239 endif()
 240
 241 # Add a dummy target to enable global dependency order
 242 # -----------------------------------------------------
 243 if(EXTRA_DEPENDENCIES_ORDER)
 244         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 245         add_custom_target(${DEPENDENCIES_TARGET} ALL
 246                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 247         )
 248 endif()
 249
 250 # Print developer helper message when build is done
 251 # -------------------------------------------------------
 252 macro(project_closing_msg)
 253         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 254         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS})
 255                 add_custom_target(${PROJECT_NAME}_build_done ALL
 256                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 257                 )
 258                  add_dependencies(${PROJECT_NAME}_build_done
 259                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 260         endif()
 261 endmacro()