src/CMakeLists.txt

   1 #
   2 # Copyright (c) 2017 TOYOTA MOTOR CORPORATION
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 #      http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 wlproto(IVI_CON ivi-wm)
  18
  19 include(FindPkgConfig)
  20 pkg_check_modules(AFB REQUIRED afb-daemon)
  21 pkg_check_modules(SD REQUIRED libsystemd>=222)
  22
  23 # We do not want a prefix for our module
  24 set(CMAKE_SHARED_MODULE_PREFIX "")
  25
  26 set(TARGETS_WM windowmanager-service)
  27
  28 add_library(${TARGETS_WM} MODULE
  29    main.cpp
  30    wayland_ivi_wm.cpp
  31    wayland_ivi_wm.hpp
  32    util.cpp
  33    util.hpp
  34    layout.cpp
  35    layout.hpp
  36    ${IVI_CON_PROTO}
  37    json_helper.cpp
  38    json_helper.hpp
  39    app.hpp app.cpp
  40    result.hpp
  41    layers.cpp
  42    layers.hpp
  43    controller_hooks.hpp
  44    config.cpp
  45    config.hpp
  46    policy.hpp
  47    wm-client.cpp
  48    applist.cpp
  49    request.cpp)
  50
  51 target_include_directories(${TARGETS_WM}
  52     PRIVATE
  53         ${AFB_INCLUDE_DIRS}
  54         ${SD_INCLUDE_DIRS}
  55         ../include
  56         ../src)
  57
  58 target_link_libraries(${TARGETS_WM}
  59     PRIVATE
  60         ${AFB_LIBRARIES}
  61         ${WLC_LIBRARIES}
  62         ${SD_LIBRARIES})
  63
  64 target_compile_definitions(${TARGETS_WM}
  65     PRIVATE
  66         AFB_BINDING_VERSION=2
  67         # We do not want source location of messages
  68         AFB_BINDING_PRAGMA_NO_VERBOSE_DETAILS
  69         WINMAN_VERSION_STRING="${PACKAGE_VERSION}"
  70         _GNU_SOURCE)
  71
  72 if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "Release")
  73    target_compile_definitions(${TARGETS_WM}
  74        PRIVATE
  75            _GLIBCXX_DEBUG)
  76 endif()
  77
  78 target_compile_options(${TARGETS_WM}
  79     PRIVATE
  80         -Wall -Wextra -Wno-unused-parameter -Wno-comment)
  81
  82 set_target_properties(${TARGETS_WM}
  83     PROPERTIES
  84     # INTERPROCEDURAL_OPTIMIZATION ON
  85
  86         CXX_EXTENSIONS OFF
  87         CXX_STANDARD 14
  88         CXX_STANDARD_REQUIRED ON
  89
  90         C_EXTENSIONS OFF
  91         C_STANDARD 99
  92         C_STANDARD_REQUIRED ON
  93
  94         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map")
  95
  96 if (LINK_LIBCXX)
  97    set_target_properties(${TARGETS_WM}
  98            PROPERTIES
  99            LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map -lc++")
 100 endif()
 101
 102 if (NOT ${SANITIZER_MODE} STREQUAL "none" AND NOT ${SANITIZER_MODE} STREQUAL "")
 103    target_compile_options(${TARGETS_WM}
 104       PRIVATE
 105          -fsanitize=${SANITIZER_MODE} -g -fno-omit-frame-pointer)
 106    set_target_properties(${TARGETS_WM}
 107       PROPERTIES
 108          LINK_FLAGS "-fsanitize=${SANITIZER_MODE} -g")
 109 endif()
 110
 111 if(NOT EXISTS ${PROJECT_BINARY_DIR}/package)
 112    add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 113       COMMAND cp -rf ${PROJECT_SOURCE_DIR}/package ${PROJECT_BINARY_DIR}
 114    )
 115 endif()
 116
 117 add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 118    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/lib
 119    COMMAND cp -rf ${PROJECT_BINARY_DIR}/src/${TARGETS_WM}.so ${PROJECT_BINARY_DIR}/package/root/lib
 120    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/etc
 121    COMMAND cp -f ${PROJECT_SOURCE_DIR}/layers.json ${PROJECT_BINARY_DIR}/package/root/etc
 122 )
 123
 124 add_custom_target(package DEPENDS ${PROJECT_BINARY_DIR}/package/root
 125    COMMAND wgtpkg-pack -f -o ${PROJECT_BINARY_DIR}/package/${TARGETS_WM}-2017.wgt ${PROJECT_BINARY_DIR}/package/root
 126 )