src/CMakeLists.txt

   1 #
   2 # Copyright (c) 2017 TOYOTA MOTOR CORPORATION
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 #      http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 wlproto(IVI_CON ivi-wm)
  18
  19 include(FindPkgConfig)
  20 pkg_check_modules(AFB REQUIRED afb-daemon)
  21 pkg_check_modules(SD REQUIRED libsystemd>=222)
  22
  23 # We do not want a prefix for our module
  24 set(CMAKE_SHARED_MODULE_PREFIX "")
  25
  26 set(TARGETS_WM windowmanager-service)
  27
  28 add_library(${TARGETS_WM} MODULE
  29    main.cpp
  30    wayland_ivi_wm.cpp
  31    util.cpp
  32    layout.cpp
  33    ${IVI_CON_PROTO}
  34    json_helper.cpp
  35    app.cpp
  36    layers.cpp)
  37
  38 target_include_directories(${TARGETS_WM}
  39     PRIVATE
  40         ${AFB_INCLUDE_DIRS}
  41         ${SD_INCLUDE_DIRS}
  42         ../include
  43         ../src)
  44
  45 target_link_libraries(${TARGETS_WM}
  46     PRIVATE
  47         ${AFB_LIBRARIES}
  48         ${WLC_LIBRARIES}
  49         ${SD_LIBRARIES})
  50
  51 target_compile_definitions(${TARGETS_WM}
  52     PRIVATE
  53         AFB_BINDING_VERSION=2
  54         # We do not want source location of messages
  55         AFB_BINDING_PRAGMA_NO_VERBOSE_DETAILS
  56         WINMAN_VERSION_STRING="${PACKAGE_VERSION}"
  57         _GNU_SOURCE)
  58
  59 if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "Release")
  60    target_compile_definitions(${TARGETS_WM}
  61        PRIVATE
  62            _GLIBCXX_DEBUG)
  63 endif()
  64
  65 target_compile_options(${TARGETS_WM}
  66     PRIVATE
  67         -Wall -Wextra -Wno-unused-parameter -Wno-comment)
  68
  69 set_target_properties(${TARGETS_WM}
  70     PROPERTIES
  71     # INTERPROCEDURAL_OPTIMIZATION ON
  72
  73         CXX_EXTENSIONS OFF
  74         CXX_STANDARD 14
  75         CXX_STANDARD_REQUIRED ON
  76
  77         C_EXTENSIONS OFF
  78         C_STANDARD 99
  79         C_STANDARD_REQUIRED ON
  80
  81         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map")
  82
  83 if (LINK_LIBCXX)
  84    set_target_properties(${TARGETS_WM}
  85            PROPERTIES
  86            LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map -lc++")
  87 endif()
  88
  89 if (NOT ${SANITIZER_MODE} STREQUAL "none" AND NOT ${SANITIZER_MODE} STREQUAL "")
  90    target_compile_options(${TARGETS_WM}
  91       PRIVATE
  92          -fsanitize=${SANITIZER_MODE} -g -fno-omit-frame-pointer)
  93    set_target_properties(${TARGETS_WM}
  94       PROPERTIES
  95          LINK_FLAGS "-fsanitize=${SANITIZER_MODE} -g")
  96 endif()
  97
  98 if(NOT EXISTS ${PROJECT_BINARY_DIR}/package)
  99    add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 100       COMMAND cp -rf ${PROJECT_SOURCE_DIR}/package ${PROJECT_BINARY_DIR}
 101    )
 102 endif()
 103
 104 add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 105    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/lib
 106    COMMAND cp -rf ${PROJECT_BINARY_DIR}/src/${TARGETS_WM}.so ${PROJECT_BINARY_DIR}/package/root/lib
 107    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/etc
 108    COMMAND cp -f ${PROJECT_SOURCE_DIR}/layers.json ${PROJECT_BINARY_DIR}/package/root/etc
 109 )
 110
 111 add_custom_target(package DEPENDS ${PROJECT_BINARY_DIR}/package/root
 112    COMMAND wgtpkg-pack -f -o ${PROJECT_BINARY_DIR}/package/${TARGETS_WM}-2017.wgt ${PROJECT_BINARY_DIR}/package/root
 113 )