src/CMakeLists.txt

   1 #
   2 # Copyright (c) 2017 TOYOTA MOTOR CORPORATION
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 #      http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 wlproto(IVI_CON ivi-controller)
  18
  19 include(FindPkgConfig)
  20 pkg_check_modules(AFB REQUIRED afb-daemon)
  21 pkg_check_modules(SD REQUIRED libsystemd>=222)
  22
  23 # We do not want a prefix for our module
  24 set(CMAKE_SHARED_MODULE_PREFIX "")
  25
  26 set(TARGETS_WM windowmanager-service)
  27
  28 add_library(${TARGETS_WM} MODULE
  29    main.cpp
  30    wayland.cpp
  31    wayland.hpp
  32    util.cpp
  33    util.hpp
  34    layout.cpp
  35    layout.hpp
  36    ${IVI_CON_PROTO}
  37    json_helper.cpp
  38    json_helper.hpp
  39    app.hpp app.cpp
  40    afb_binding_api.cpp
  41    result.hpp
  42    afb_binding_api.hpp
  43    layers.cpp
  44    layers.hpp
  45    controller_hooks.hpp
  46    config.cpp
  47    config.hpp
  48    policy.hpp)
  49
  50 target_include_directories(${TARGETS_WM}
  51     PRIVATE
  52         ${AFB_INCLUDE_DIRS}
  53         ${SD_INCLUDE_DIRS}
  54         ../include
  55         ../src)
  56
  57 target_link_libraries(${TARGETS_WM}
  58     PRIVATE
  59         ${AFB_LIBRARIES}
  60         ${WLC_LIBRARIES}
  61         ${SD_LIBRARIES})
  62
  63 target_compile_definitions(${TARGETS_WM}
  64     PRIVATE
  65         AFB_BINDING_VERSION=2
  66         # We do not want source location of messages
  67         AFB_BINDING_PRAGMA_NO_VERBOSE_DETAILS
  68         WINMAN_VERSION_STRING="${PACKAGE_VERSION}"
  69         _GNU_SOURCE)
  70
  71 if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "Release")
  72    target_compile_definitions(${TARGETS_WM}
  73        PRIVATE
  74            _GLIBCXX_DEBUG)
  75 endif()
  76
  77 target_compile_options(${TARGETS_WM}
  78     PRIVATE
  79         -Wall -Wextra -Wno-unused-parameter -Wno-comment)
  80
  81 set_target_properties(${TARGETS_WM}
  82     PROPERTIES
  83     # INTERPROCEDURAL_OPTIMIZATION ON
  84
  85         CXX_EXTENSIONS OFF
  86         CXX_STANDARD 14
  87         CXX_STANDARD_REQUIRED ON
  88
  89         C_EXTENSIONS OFF
  90         C_STANDARD 99
  91         C_STANDARD_REQUIRED ON
  92
  93         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map")
  94
  95 if (LINK_LIBCXX)
  96    set_target_properties(${TARGETS_WM}
  97            PROPERTIES
  98            LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map -lc++")
  99 endif()
 100
 101 if (NOT ${SANITIZER_MODE} STREQUAL "none" AND NOT ${SANITIZER_MODE} STREQUAL "")
 102    target_compile_options(${TARGETS_WM}
 103       PRIVATE
 104          -fsanitize=${SANITIZER_MODE} -g -fno-omit-frame-pointer)
 105    set_target_properties(${TARGETS_WM}
 106       PROPERTIES
 107          LINK_FLAGS "-fsanitize=${SANITIZER_MODE} -g")
 108 endif()
 109
 110 if(NOT EXISTS ${PROJECT_BINARY_DIR}/package)
 111    add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 112       COMMAND cp -rf ${PROJECT_SOURCE_DIR}/package ${PROJECT_BINARY_DIR}
 113    )
 114 endif()
 115
 116 add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 117    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/lib
 118    COMMAND cp -rf ${PROJECT_BINARY_DIR}/src/${TARGETS_WM}.so ${PROJECT_BINARY_DIR}/package/root/lib
 119    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/etc
 120    COMMAND cp -f ${PROJECT_SOURCE_DIR}/layers.json ${PROJECT_BINARY_DIR}/package/root/etc
 121 )
 122
 123 add_custom_target(package DEPENDS ${PROJECT_BINARY_DIR}/package/root
 124    COMMAND wgtpkg-pack -f -o ${PROJECT_BINARY_DIR}/package/${TARGETS_WM}-2017.wgt ${PROJECT_BINARY_DIR}/package/root
 125 )