src/CMakeLists.txt

   1 #
   2 # Copyright (C) 2017 Mentor Graphics Development (Deutschland) GmbH
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 #      http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 wlproto(IVI_CON ivi-controller)
  18
  19 include(FindPkgConfig)
  20 pkg_check_modules(AFB REQUIRED afb-daemon)
  21 pkg_check_modules(SD REQUIRED libsystemd>=222)
  22
  23 # We do not want a prefix for our module
  24 set(CMAKE_SHARED_MODULE_PREFIX "")
  25
  26 add_custom_command(
  27    OUTPUT afb_binding_api.hpp afb_binding_glue.inl
  28    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/../generate-binding-glue.py
  29    COMMAND python ${CMAKE_CURRENT_SOURCE_DIR}/../generate-binding-glue.py)
  30
  31 set(TARGETS_WM windowmanager-service)
  32
  33 add_library(${TARGETS_WM} MODULE
  34    main.cpp
  35    wayland.cpp
  36    wayland.hpp
  37    util.cpp
  38    util.hpp
  39    layout.cpp
  40    layout.hpp
  41    ${IVI_CON_PROTO}
  42    json_helper.cpp
  43    json_helper.hpp
  44    app.hpp app.cpp
  45    afb_binding_api.cpp
  46    result.hpp
  47    afb_binding_api.hpp
  48    afb_binding_glue.inl
  49    layers.cpp
  50    layers.hpp
  51    controller_hooks.hpp
  52    config.cpp
  53    config.hpp
  54    policy.hpp)
  55
  56 target_include_directories(${TARGETS_WM}
  57     PRIVATE
  58         ${AFB_INCLUDE_DIRS}
  59         ${SD_INCLUDE_DIRS}
  60         ../include
  61         ../src)
  62
  63 target_link_libraries(${TARGETS_WM}
  64     PRIVATE
  65         ${AFB_LIBRARIES}
  66         ${WLC_LIBRARIES}
  67         ${SD_LIBRARIES})
  68
  69 target_compile_definitions(${TARGETS_WM}
  70     PRIVATE
  71         AFB_BINDING_VERSION=2
  72         # We do not want source location of messages
  73         AFB_BINDING_PRAGMA_NO_VERBOSE_DETAILS
  74         WINMAN_VERSION_STRING="${PACKAGE_VERSION}"
  75         _GNU_SOURCE)  # XXX should I define this here?!
  76
  77 if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "Release")
  78    target_compile_definitions(${TARGETS_WM}
  79        PRIVATE
  80            _GLIBCXX_DEBUG)
  81 endif()
  82
  83 target_compile_options(${TARGETS_WM}
  84     PRIVATE
  85         -Wall -Wextra -Wno-unused-parameter -Wno-comment)
  86
  87 set_target_properties(${TARGETS_WM}
  88     PROPERTIES
  89     # INTERPROCEDURAL_OPTIMIZATION ON
  90
  91         CXX_EXTENSIONS OFF
  92         CXX_STANDARD 14
  93         CXX_STANDARD_REQUIRED ON
  94
  95         C_EXTENSIONS OFF
  96         C_STANDARD 99
  97         C_STANDARD_REQUIRED ON
  98
  99         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map")
 100
 101 if (LINK_LIBCXX)
 102    set_target_properties(${TARGETS_WM}
 103            PROPERTIES
 104            LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map -lc++")
 105 endif()
 106
 107 if (NOT ${SANITIZER_MODE} STREQUAL "none" AND NOT ${SANITIZER_MODE} STREQUAL "")
 108    target_compile_options(${TARGETS_WM}
 109       PRIVATE
 110          -fsanitize=${SANITIZER_MODE} -g -fno-omit-frame-pointer)
 111    set_target_properties(${TARGETS_WM}
 112       PROPERTIES
 113          LINK_FLAGS "-fsanitize=${SANITIZER_MODE} -g")
 114 endif()
 115
 116 if(NOT EXISTS ${PROJECT_BINARY_DIR}/package)
 117    add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 118       COMMAND cp -rf ${PROJECT_SOURCE_DIR}/package ${PROJECT_BINARY_DIR}
 119    )
 120 endif()
 121
 122 add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 123    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/lib
 124    COMMAND cp -rf ${PROJECT_BINARY_DIR}/src/${TARGETS_WM}.so ${PROJECT_BINARY_DIR}/package/root/lib
 125    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/etc
 126    COMMAND cp -f ${PROJECT_SOURCE_DIR}/layers.json ${PROJECT_BINARY_DIR}/package/root/etc
 127 )
 128
 129 add_custom_target(package DEPENDS ${PROJECT_BINARY_DIR}/package/root
 130    COMMAND wgtpkg-pack -f -o ${PROJECT_BINARY_DIR}/package/${TARGETS_WM}-2017.wgt ${PROJECT_BINARY_DIR}/package/root
 131 )