src/CMakeLists.txt

   1 #
   2 # Copyright (c) 2017 TOYOTA MOTOR CORPORATION
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 #      http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 include(FindPkgConfig)
  18 pkg_check_modules(AFB REQUIRED afb-daemon)
  19 pkg_check_modules(ILM REQUIRED ilmControl ilmCommon)
  20 pkg_check_modules(SD REQUIRED libsystemd>=222)
  21
  22 # We do not want a prefix for our module
  23 set(CMAKE_SHARED_MODULE_PREFIX "")
  24
  25 set(TARGETS_WM windowmanager-service)
  26
  27 add_library(${TARGETS_WM} MODULE
  28    main.cpp
  29    util.cpp
  30    json_helper.cpp
  31    applist.cpp
  32    request.cpp
  33    pm_wrapper.cpp
  34    window_manager.cpp
  35    wm_client.cpp
  36    wm_error.cpp
  37    wm_layer.cpp
  38    wm_layer_control.cpp)
  39
  40 target_include_directories(${TARGETS_WM}
  41     PRIVATE
  42         ${AFB_INCLUDE_DIRS}
  43         ${SD_INCLUDE_DIRS}
  44         ${ILM_INCLUDE_DIRS}
  45         ../src
  46         ../${PLUGIN_PM})
  47
  48 target_link_libraries(${TARGETS_WM}
  49     PRIVATE
  50         ${AFB_LIBRARIES}
  51         ${WLC_LIBRARIES}
  52         ${ILM_LIBRARIES}
  53         ${SD_LIBRARIES}
  54         ${PLUGIN_PM})
  55
  56 target_compile_definitions(${TARGETS_WM}
  57     PRIVATE
  58         AFB_BINDING_VERSION=2
  59         # We do not want source location of messages
  60         AFB_BINDING_PRAGMA_NO_VERBOSE_DETAILS
  61         WINMAN_VERSION_STRING="${PACKAGE_VERSION}"
  62         _GNU_SOURCE)
  63
  64 if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "Release")
  65    target_compile_definitions(${TARGETS_WM}
  66        PRIVATE
  67            _GLIBCXX_DEBUG)
  68 endif()
  69
  70 target_compile_options(${TARGETS_WM}
  71     PRIVATE
  72         -Wall -Wextra -Wno-unused-parameter -Wno-comment -Wno-missing-field-initializers)
  73
  74 set_target_properties(${TARGETS_WM}
  75     PROPERTIES
  76     # INTERPROCEDURAL_OPTIMIZATION ON
  77
  78         CXX_EXTENSIONS OFF
  79         CXX_STANDARD 14
  80         CXX_STANDARD_REQUIRED ON
  81
  82         C_EXTENSIONS OFF
  83         C_STANDARD 99
  84         C_STANDARD_REQUIRED ON
  85
  86         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map -Wl,-rpath,'$ORIGIN'")
  87
  88 if (LINK_LIBCXX)
  89    set_target_properties(${TARGETS_WM}
  90            PROPERTIES
  91            LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map -lc++ -Wl,-rpath,'$ORIGIN'")
  92 endif()
  93
  94 if (NOT ${SANITIZER_MODE} STREQUAL "none" AND NOT ${SANITIZER_MODE} STREQUAL "")
  95    target_compile_options(${TARGETS_WM}
  96       PRIVATE
  97          -fsanitize=${SANITIZER_MODE} -g -fno-omit-frame-pointer)
  98    set_target_properties(${TARGETS_WM}
  99       PROPERTIES
 100          LINK_FLAGS "-fsanitize=${SANITIZER_MODE} -g")
 101 endif()
 102
 103 if(NOT EXISTS ${PROJECT_BINARY_DIR}/package)
 104    add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 105       COMMAND cp -rf ${PROJECT_SOURCE_DIR}/package ${PROJECT_BINARY_DIR}
 106    )
 107 endif()
 108
 109 add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 110    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/lib
 111    COMMAND cp -rf ${PROJECT_BINARY_DIR}/src/${TARGETS_WM}.so ${PROJECT_BINARY_DIR}/package/root/lib
 112    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/etc
 113    COMMAND cp -f ${PROJECT_SOURCE_DIR}/conf/old_roles.db ${PROJECT_BINARY_DIR}/package/root/etc
 114    COMMAND cp -f ${CMAKE_SOURCE_DIR}/conf/layers.json ${PROJECT_BINARY_DIR}/package/root/etc
 115    COMMAND cp -f ${CMAKE_SOURCE_DIR}/conf/areas.json ${PROJECT_BINARY_DIR}/package/root/etc
 116 )
 117
 118 add_custom_target(package DEPENDS ${PROJECT_BINARY_DIR}/package/root
 119    COMMAND wgtpkg-pack -f -o ${PROJECT_BINARY_DIR}/package/${TARGETS_WM}-2017.wgt ${PROJECT_BINARY_DIR}/package/root
 120 )