src/CMakeLists.txt

   1 #
   2 # Copyright (c) 2017 TOYOTA MOTOR CORPORATION
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 #      http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 wlproto(IVI_CON ivi-wm)
  18
  19 include(FindPkgConfig)
  20 pkg_check_modules(AFB REQUIRED afb-daemon)
  21 pkg_check_modules(SD REQUIRED libsystemd>=222)
  22
  23 # We do not want a prefix for our module
  24 set(CMAKE_SHARED_MODULE_PREFIX "")
  25
  26 set(TARGETS_WM windowmanager-service)
  27
  28 add_library(${TARGETS_WM} MODULE
  29    main.cpp
  30    wayland_ivi_wm.cpp
  31    util.cpp
  32    layout.cpp
  33    ${IVI_CON_PROTO}
  34    json_helper.cpp
  35    app.cpp
  36    layers.cpp
  37    config.cpp)
  38
  39 target_include_directories(${TARGETS_WM}
  40     PRIVATE
  41         ${AFB_INCLUDE_DIRS}
  42         ${SD_INCLUDE_DIRS}
  43         ../include
  44         ../src)
  45
  46 target_link_libraries(${TARGETS_WM}
  47     PRIVATE
  48         ${AFB_LIBRARIES}
  49         ${WLC_LIBRARIES}
  50         ${SD_LIBRARIES})
  51
  52 target_compile_definitions(${TARGETS_WM}
  53     PRIVATE
  54         AFB_BINDING_VERSION=2
  55         # We do not want source location of messages
  56         AFB_BINDING_PRAGMA_NO_VERBOSE_DETAILS
  57         WINMAN_VERSION_STRING="${PACKAGE_VERSION}"
  58         _GNU_SOURCE)
  59
  60 if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "Release")
  61    target_compile_definitions(${TARGETS_WM}
  62        PRIVATE
  63            _GLIBCXX_DEBUG)
  64 endif()
  65
  66 target_compile_options(${TARGETS_WM}
  67     PRIVATE
  68         -Wall -Wextra -Wno-unused-parameter -Wno-comment)
  69
  70 set_target_properties(${TARGETS_WM}
  71     PROPERTIES
  72     # INTERPROCEDURAL_OPTIMIZATION ON
  73
  74         CXX_EXTENSIONS OFF
  75         CXX_STANDARD 14
  76         CXX_STANDARD_REQUIRED ON
  77
  78         C_EXTENSIONS OFF
  79         C_STANDARD 99
  80         C_STANDARD_REQUIRED ON
  81
  82         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map")
  83
  84 if (LINK_LIBCXX)
  85    set_target_properties(${TARGETS_WM}
  86            PROPERTIES
  87            LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map -lc++")
  88 endif()
  89
  90 if (NOT ${SANITIZER_MODE} STREQUAL "none" AND NOT ${SANITIZER_MODE} STREQUAL "")
  91    target_compile_options(${TARGETS_WM}
  92       PRIVATE
  93          -fsanitize=${SANITIZER_MODE} -g -fno-omit-frame-pointer)
  94    set_target_properties(${TARGETS_WM}
  95       PROPERTIES
  96          LINK_FLAGS "-fsanitize=${SANITIZER_MODE} -g")
  97 endif()
  98
  99 if(NOT EXISTS ${PROJECT_BINARY_DIR}/package)
 100    add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 101       COMMAND cp -rf ${PROJECT_SOURCE_DIR}/package ${PROJECT_BINARY_DIR}
 102    )
 103 endif()
 104
 105 add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 106    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/lib
 107    COMMAND cp -rf ${PROJECT_BINARY_DIR}/src/${TARGETS_WM}.so ${PROJECT_BINARY_DIR}/package/root/lib
 108    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/etc
 109    COMMAND cp -f ${PROJECT_SOURCE_DIR}/layers.json ${PROJECT_BINARY_DIR}/package/root/etc
 110 )
 111
 112 add_custom_target(package DEPENDS ${PROJECT_BINARY_DIR}/package/root
 113    COMMAND wgtpkg-pack -f -o ${PROJECT_BINARY_DIR}/package/${TARGETS_WM}-2017.wgt ${PROJECT_BINARY_DIR}/package/root
 114 )