src/CMakeLists.txt

   1 #
   2 # Copyright (c) 2017 TOYOTA MOTOR CORPORATION
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 #      http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 wlproto(IVI_CON ivi-wm)
  18
  19 include(FindPkgConfig)
  20 pkg_check_modules(AFB REQUIRED afb-daemon)
  21 pkg_check_modules(SD REQUIRED libsystemd>=222)
  22
  23 # We do not want a prefix for our module
  24 set(CMAKE_SHARED_MODULE_PREFIX "")
  25
  26 set(TARGETS_WM windowmanager-service)
  27
  28 add_library(${TARGETS_WM} MODULE
  29    main.cpp
  30    wayland_ivi_wm.cpp
  31    util.cpp
  32    layout.cpp
  33    ${IVI_CON_PROTO}
  34    json_helper.cpp
  35    window_manager.cpp
  36    layers.cpp
  37    wm_client.cpp
  38    wm_error.cpp
  39    applist.cpp
  40    request.cpp
  41    pm_wrapper.cpp)
  42
  43 target_include_directories(${TARGETS_WM}
  44     PRIVATE
  45         ${AFB_INCLUDE_DIRS}
  46         ${SD_INCLUDE_DIRS}
  47         ../include
  48         ../src
  49         ../${PLUGIN_PM})
  50
  51 target_link_libraries(${TARGETS_WM}
  52     PRIVATE
  53         ${AFB_LIBRARIES}
  54         ${WLC_LIBRARIES}
  55         ${SD_LIBRARIES}
  56         ${PLUGIN_PM})
  57
  58 target_compile_definitions(${TARGETS_WM}
  59     PRIVATE
  60         AFB_BINDING_VERSION=2
  61         # We do not want source location of messages
  62         AFB_BINDING_PRAGMA_NO_VERBOSE_DETAILS
  63         WINMAN_VERSION_STRING="${PACKAGE_VERSION}"
  64         _GNU_SOURCE)
  65
  66 if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "Release")
  67    target_compile_definitions(${TARGETS_WM}
  68        PRIVATE
  69            _GLIBCXX_DEBUG)
  70 endif()
  71
  72 target_compile_options(${TARGETS_WM}
  73     PRIVATE
  74         -Wall -Wextra -Wno-unused-parameter -Wno-comment)
  75
  76 set_target_properties(${TARGETS_WM}
  77     PROPERTIES
  78     # INTERPROCEDURAL_OPTIMIZATION ON
  79
  80         CXX_EXTENSIONS OFF
  81         CXX_STANDARD 14
  82         CXX_STANDARD_REQUIRED ON
  83
  84         C_EXTENSIONS OFF
  85         C_STANDARD 99
  86         C_STANDARD_REQUIRED ON
  87
  88         LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map -Wl,-rpath,'$ORIGIN'")
  89
  90 if (LINK_LIBCXX)
  91    set_target_properties(${TARGETS_WM}
  92            PROPERTIES
  93            LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_SOURCE_DIR}/../export.map -lc++ -Wl,-rpath,'$ORIGIN'")
  94 endif()
  95
  96 if (NOT ${SANITIZER_MODE} STREQUAL "none" AND NOT ${SANITIZER_MODE} STREQUAL "")
  97    target_compile_options(${TARGETS_WM}
  98       PRIVATE
  99          -fsanitize=${SANITIZER_MODE} -g -fno-omit-frame-pointer)
 100    set_target_properties(${TARGETS_WM}
 101       PROPERTIES
 102          LINK_FLAGS "-fsanitize=${SANITIZER_MODE} -g")
 103 endif()
 104
 105 if(NOT EXISTS ${PROJECT_BINARY_DIR}/package)
 106    add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 107       COMMAND cp -rf ${PROJECT_SOURCE_DIR}/package ${PROJECT_BINARY_DIR}
 108    )
 109 endif()
 110
 111 add_custom_command(TARGET ${TARGETS_WM} POST_BUILD
 112    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/lib
 113    COMMAND cp -rf ${PROJECT_BINARY_DIR}/src/${TARGETS_WM}.so ${PROJECT_BINARY_DIR}/package/root/lib
 114    COMMAND mkdir -p ${PROJECT_BINARY_DIR}/package/root/etc
 115    COMMAND cp -f ${PROJECT_SOURCE_DIR}/layers.json ${PROJECT_BINARY_DIR}/package/root/etc
 116    COMMAND cp -f ${PROJECT_SOURCE_DIR}/src/db/old_roles.db ${PROJECT_BINARY_DIR}/package/root/etc
 117    COMMAND cp -f ${PROJECT_SOURCE_DIR}/src/db/areas.db ${PROJECT_BINARY_DIR}/package/root/etc
 118 )
 119
 120 add_custom_target(package DEPENDS ${PROJECT_BINARY_DIR}/package/root
 121    COMMAND wgtpkg-pack -f -o ${PROJECT_BINARY_DIR}/package/${TARGETS_WM}-2017.wgt ${PROJECT_BINARY_DIR}/package/root
 122 )