reference/etc/macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27
  28 # Generic useful macro
  29 # -----------------------
  30 macro(PROJECT_TARGET_ADD TARGET_NAME)
  31         set(PROJECT_TARGETS ${PROJECT_TARGETS} ${TARGET_NAME} CACHE INTERNAL PROJECT_TARGETS)
  32         set(TARGET_NAME ${TARGET_NAME})
  33
  34         # Cmake does not maintain targets list before 3.7
  35         # -------------------------------------------------
  36         if(${CMAKE_VERSION} VERSION_LESS 3.7)
  37                 set(GLOBAL_TARGET_LIST ${PROJECT_TARGETS})
  38         else()
  39                 get_property(GLOBAL_TARGET_LIST GLOBAL PROPERTY GlobalTargetList)
  40         endif()
  41 endmacro(PROJECT_TARGET_ADD)
  42
  43 # Check GCC minimal version version
  44 if (gcc_minimal_version)
  45    message ("-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})")
  46 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  47     message(FATAL_ERROR "**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  48 endif()
  49 endif(gcc_minimal_version)
  50
  51 macro(defstr name value)
  52         add_definitions(-D${name}=${value})
  53 endmacro(defstr)
  54
  55 # WGT packaging
  56 macro(project_targets_populate)
  57         foreach(TARGET ${PROJECT_TARGETS})
  58                 get_target_property(T ${TARGET} LABELS)
  59                 if(T)
  60                         # Declaration of a custom command that will populate widget tree with the target
  61                         set(POPULE_WIDGET_TARGET "project_populate_${TARGET}")
  62
  63                         get_target_property(P ${TARGET} PREFIX)
  64                         get_target_property(BD ${TARGET} BINARY_DIR)
  65                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  66
  67                         if(P MATCHES "NOTFOUND$")
  68                                 if (${T} STREQUAL "BINDING")
  69                                         set(P "lib")
  70                                 else()
  71                                         set(P "")
  72                                 endif()
  73                         endif()
  74
  75                         if(${T} STREQUAL "BINDING")
  76                                 add_custom_command(OUTPUT ${WIDGET_LIBDIR}/${P}${TARGET}.so
  77                                         DEPENDS ${TARGET}
  78                                         COMMAND mkdir -p ${WIDGET_LIBDIR}
  79                                         COMMAND cp ${BD}/${P}${OUT}.so ${WIDGET_LIBDIR}
  80                                 )
  81                                 add_custom_target(${POPULE_WIDGET_TARGET} ALL DEPENDS ${WIDGET_LIBDIR}/${P}${TARGET}.so)
  82                         elseif(${T} STREQUAL "EXECUTABLE")
  83                                 add_custom_command(OUTPUT ${WIDGET_BINDIR}/${P}${TARGET}
  84                                         DEPENDS ${TARGET}
  85                                         COMMAND mkdir -p ${WIDGET_BINDIR}
  86                                         COMMAND cp ${BD}/${P}${OUT} ${WIDGET_BINDIR}
  87                                 )
  88                                 add_custom_target(${POPULE_WIDGET_TARGET} ALL DEPENDS ${WIDGET_BINDIR}/${P}${TARGET})
  89                         elseif(${T} STREQUAL "HTDOCS")
  90                                 add_custom_command(OUTPUT ${WIDGET_HTTPDIR}
  91                                         DEPENDS ${TARGET}
  92                                         COMMAND cp -r ${BD}/${P}${OUT} ${WIDGET_HTTPDIR}
  93                                         )
  94                                         add_custom_target(${POPULE_WIDGET_TARGET} ALL DEPENDS ${WIDGET_HTTPDIR})
  95                         elseif(${T} STREQUAL "DATA")
  96                                 add_custom_command(OUTPUT ${WIDGET_DATADIR}
  97                                         DEPENDS ${TARGET}
  98                                         COMMAND cp -r ${BD}/${P}${OUT} ${WIDGET_DATADIR}
  99                                         )
 100                                         add_custom_target(${POPULE_WIDGET_TARGET} ALL DEPENDS ${WIDGET_HTTPDIR})
 101                         endif(${T} STREQUAL "BINDING")
 102                         PROJECT_TARGET_ADD(${POPULE_WIDGET_TARGET})
 103 #               elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 104 #                                       MESSAGE(AUTHOR_WARNING "This target, ${TARGET}, will be not be included in the package.")
 105                 endif()
 106         endforeach()
 107 endmacro(project_targets_populate)
 108
 109 macro(project_package_build)
 110         if("${PROJECT_TARGETS}" MATCHES "project_populate_")
 111                 if(NOT EXISTS ${WIDGET_DIR}/config.xml.in OR NOT EXISTS ${WIDGET_DIR}/${PROJECT_ICON}.in)
 112                         configure_file(${PROJECT_WGT_DIR}/config.xml.in ${WIDGET_DIR}/config.xml)
 113                         file(COPY ${PROJECT_WGT_DIR}/${PROJECT_ICON}.in DESTINATION ${WIDGET_DIR}/${PROJECT_ICON})
 114                 endif(NOT EXISTS ${WIDGET_DIR}/config.xml.in OR NOT EXISTS ${WIDGET_DIR}/${PROJECT_ICON}.in)
 115
 116                 file(GLOB PROJECT_CONF_FILES "${PROJECT_WGT_DIR}/etc/*")
 117                 if(${PROJECT_CONF_FILES})
 118                         file(COPY "${PROJECT_WGT_DIR}/etc/*" DESTINATION ${WIDGET_ETCDIR}/)
 119                 endif(${PROJECT_CONF_FILES})
 120
 121                 add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 122                 DEPENDS ${PROJECT_TARGETS}
 123                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${WIDGET_DIR}
 124                 )
 125                 add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 126                 set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 127         else()
 128                 MESSAGE(FATAL_ERROR "Widget tree empty, please populate it by calling  populate_widget() macro with target you want to include into it.")
 129         endif("${PROJECT_TARGETS}" MATCHES "project_populate_")
 130 endmacro(project_package_build)
 131
 132 macro(project_subdirs_add)
 133         if(${ARGV0})
 134                 file(GLOB filelist "${ARGV0}")
 135         else()
 136                 file(GLOB filelist "*")
 137         endif(${ARGV0})
 138
 139         foreach(filename ${filelist})
 140                 if(EXISTS "${filename}/CMakeLists.txt")
 141                         add_subdirectory(${filename})
 142                 endif(EXISTS "${filename}/CMakeLists.txt")
 143         endforeach()
 144 endmacro(project_subdirs_add)
 145
 146 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 147 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 148 set(CMP0048 1)
 149
 150 # Include project configuration
 151 # ------------------------------
 152 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 153 set(PROJECT_WGT_DIR "packaging/wgt" CACHE PATH "Subpath to the widget directory")
 154 set(PROJECT_LIBDIR "libs" CACHE PATH "Subpath to libraries")
 155 set(PROJECT_RESOURCES "data" CACHE PATH "Subpath to data")
 156
 157 INCLUDE(FindPkgConfig)
 158 INCLUDE(CheckIncludeFiles)
 159 INCLUDE(CheckLibraryExists)
 160 INCLUDE(GNUInstallDirs)
 161
 162 # Default compilation options
 163 ############################################################################
 164 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 165 add_compile_options(-Wall -Wextra -Wconversion)
 166 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 167 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 168 add_compile_options(-Werror=maybe-uninitialized)
 169 add_compile_options(-Werror=implicit-function-declaration)
 170 add_compile_options(-ffunction-sections -fdata-sections)
 171 add_compile_options(-fPIC)
 172 add_compile_options(-g)
 173
 174 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 175 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 176 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 177 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 178
 179 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 180 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 181 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 182 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 183
 184 set(CMAKE_INSTALL_PREFIX      "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 185
 186 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 187 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 188
 189 # Loop on required package and add options
 190 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 191         PKG_CHECK_MODULES(${PKG_CONFIG} REQUIRED ${PKG_CONFIG})
 192
 193         INCLUDE_DIRECTORIES(${${PKG_CONFIG}_INCLUDE_DIRS})
 194         list (APPEND link_libraries ${${PKG_CONFIG}_LIBRARIES})
 195         add_compile_options (${${PKG_CONFIG}_CFLAGS})
 196 endforeach(PKG_CONFIG)
 197
 198 # Optional LibEfence Malloc debug library
 199 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 200 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 201 IF(HAVE_LIBEFENCE)
 202         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 203         SET(libefence_LIBRARIES "-lefence")
 204         list (APPEND link_libraries ${libefence_LIBRARIES})
 205 ENDIF(HAVE_LIBEFENCE)
 206 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 207
 208 # set default include directories
 209 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 210
 211 # If no install dir try to guess some smart default
 212 if(BINDINGS_INSTALL_PREFIX)
 213         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME})
 214 else()
 215         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME})
 216 endif()
 217
 218 # Define a default package directory
 219 if(WIDGET_PREFIX)
 220         set(WIDGET_DIR ${WIDGET_PREFIX}/package)
 221 else()
 222         set(WIDGET_DIR ${CMAKE_CURRENT_BINARY_DIR}/package)
 223 endif()
 224
 225 # and their subsequent subdir
 226 set(WIDGET_BINDIR ${WIDGET_DIR}/bin)
 227 set(WIDGET_ETCDIR ${WIDGET_DIR}/etc)
 228 set(WIDGET_LIBDIR ${WIDGET_DIR}/lib)
 229 set(WIDGET_HTTPDIR ${WIDGET_DIR}/htdocs)
 230 set(WIDGET_DATADIR ${WIDGET_DIR}/data)
 231
 232 # Default Linkflag
 233 if(NOT BINDINGS_LINK_FLAG)
 234         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${CMAKE_SOURCE_DIR}/etc/export.map")
 235 endif()
 236
 237 # Add a dummy target to enable global dependency order
 238 # -----------------------------------------------------
 239 if(EXTRA_DEPENDENCIES_ORDER)
 240         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 241         add_custom_target(${DEPENDENCIES_TARGET} ALL
 242                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 243         )
 244 endif()
 245
 246 # Print developer helper message when everything is done
 247 # -------------------------------------------------------
 248 macro(project_closing_msg)
 249         if(CLOSING_MESSAGE AND GLOBAL_TARGET_LIST)
 250                 add_custom_target(${PROJECT_NAME}_done ALL
 251                         DEPENDS ${DEPENDENCIES_TARGET} ${GLOBAL_TARGET_LIST}
 252                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 253                 )
 254         endif()
 255 endmacro()