recipes-wam/chromium/chromium_git.bb

   1 require chromium.inc
   2
   3 SRC_URI = "\
   4     git://github.com/igalia/chromium87;branch=@10.agl.marlin;protocol=https;rev=${SRCREV_chromium87};name=chromium87 \
   5     git://github.com/webosose/chromium-v8;branch=@chromium87;destsuffix=git/src/v8;rev=${SRCREV_v8};name=v8;protocol=https \
   6 "
   7
   8 # Needed by catapult
   9 DEPENDS += "python-six-native python-beautifulsoup4-native python-lxml-native python-html5lib-native python-webencodings-native"
  10
  11 SRCREV_chromium87 = "7412ccde56b8054af89d6f515bc7c852287fc3b2"
  12 SRCREV_v8 = "935065d097cce0090bc858746e6aee0919b222de"
  13
  14 CHROMIUM_VERSION = "87.0.4280.88"
  15 PV_BRANCH_SUFFIX = "ose10.agl.marlin"
  16
  17 PV = "${CHROMIUM_VERSION}.${PV_BRANCH_SUFFIX}+git"
  18
  19 BROWSER_APPLICATION = "chromium-browser"
  20 BROWSER_APPLICATION_DIR = "/opt/chromium"
  21 MKSNAPSHOT_PATH = "v8_snapshot/"
  22
  23 GN_ARGS += "use_gtk=false"
  24
  25 # Disable closure compile
  26 # Else we need HOSTTOOLS += "java"
  27 GN_ARGS += " \
  28   enable_mojom_closure_compile=false\
  29   enable_js_type_check=false\
  30 "
  31
  32 # When using meta-clang, one can switch to using the lld linker
  33 # by using the ld-is-lld distro feature otherwise use gold linker
  34 GN_ARGS += "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', 'use_lld=true use_gold=false', bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', 'use_lld=false use_gold=true', 'use_lld=false use_gold=false', d), d)}"
  35
  36 # Toolchains we will use for the build. We need to point to the toolchain file
  37 # we've created, set the right target architecture and make sure we are not
  38 # using Chromium's toolchain (bundled clang, bundled binutils etc).
  39 GN_ARGS += "\
  40     host_toolchain=\"//build/toolchain/cros:host\" \
  41     cros_host_is_clang=false \
  42     use_custom_libcxx_for_host=false \
  43     cros_host_ar=\"${BUILD_AR}\" \
  44     cros_host_cc=\"${BUILD_CC} ${BUILD_CFLAGS}\" \
  45     cros_host_cxx=\"${BUILD_CXX} ${BUILD_CXXFLAGS}\" \
  46     cros_host_extra_ldflags=\"${BUILD_LDFLAGS}\" \
  47     custom_toolchain=\"//build/toolchain/cros:target\" \
  48     is_clang=false \
  49     use_custom_libcxx=false \
  50     target_cpu=\"${@gn_arch_name('${TUNE_ARCH}')}\" \
  51     cros_target_ar=\"${AR}\" \
  52     cros_target_cc=\"${CC}\" \
  53     cros_target_cxx=\"${CXX}\" \
  54     cros_target_extra_ldflags=\"${LDFLAGS}\" \
  55     v8_snapshot_toolchain=\"//build/toolchain/cros:v8_snapshot\" \
  56     cros_v8_snapshot_is_clang=false \
  57     cros_v8_snapshot_ar=\"${BUILD_AR}\" \
  58     cros_v8_snapshot_cc=\"${BUILD_CC}\" \
  59     cros_v8_snapshot_cxx=\"${BUILD_CXX}\" \
  60     gold_path=\"\" \
  61     v8_enable_embedded_builtins=false \
  62     use_v8_context_snapshot=false \
  63 "
  64
  65 GN_ARGS:append = " \
  66   use_system_minigbm=false \
  67   use_wayland_gbm=false \
  68 "
  69
  70 GN_ARGS:append = " \
  71   is_webos=false \
  72   is_agl=true \
  73 "
  74
  75 # TODO: drop this after we migrate to ubuntu 16.04 or above
  76 GN_ARGS += "\
  77     fatal_linker_warnings=false\
  78 "
  79
  80 # TODO(rzanoni) copied from original recipe to fix qemux86 build.
  81 # check if it can be removed in the future.
  82 PACKAGECONFIG:remove:qemux86 = "gstreamer umediaserver neva-media gav neva-webrtc"
  83 #END TODO