recipes-wam/chromium/chromium84_git.bb

   1 require chromium.inc
   2
   3 SRC_URI = "\
   4     git://github.com/igalia/${PN};branch=marlin;protocol=https;rev=${SRCREV_chromium84};name=chromium84 \
   5     git://github.com/webosose/chromium-v8;branch=@chromium84;destsuffix=git/src/v8;rev=${SRCREV_v8};name=v8;protocol=https \
   6 "
   7
   8 # Needed by catapult
   9 DEPENDS += "python-six-native python-beautifulsoup4-native python-lxml-native python-html5lib-native python-webencodings-native"
  10
  11 SRCREV_chromium84 = "005a9257d3ba9eb363e19f5a8efc6758924dbf9b"
  12 SRCREV_v8 = "5c1d89dd2945a10cf7a6a3458050b3177a870b09"
  13
  14 BROWSER_APPLICATION = "chromium84-browser"
  15 BROWSER_APPLICATION_DIR = "/opt/chromium84"
  16 MKSNAPSHOT_PATH = "v8_snapshot/"
  17
  18 GN_ARGS += "use_gtk=false"
  19
  20 # Disable closure_compile
  21 # Else we need HOSTTOOLS += "java"
  22 GN_ARGS += "closure_compile=false"
  23
  24 # When using meta-clang, one can switch to using the lld linker
  25 # by using the ld-is-lld distro feature otherwise use gold linker
  26 GN_ARGS += "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', 'use_lld=true use_gold=false', bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', 'use_lld=false use_gold=true', 'use_lld=false use_gold=false', d), d)}"
  27
  28 # Toolchains we will use for the build. We need to point to the toolchain file
  29 # we've created, set the right target architecture and make sure we are not
  30 # using Chromium's toolchain (bundled clang, bundled binutils etc).
  31 GN_ARGS += "\
  32     host_toolchain=\"//build/toolchain/cros:host\" \
  33     cros_host_is_clang=false \
  34     use_custom_libcxx_for_host=false \
  35     cros_host_ar=\"${BUILD_AR}\" \
  36     cros_host_cc=\"${BUILD_CC} ${BUILD_CFLAGS}\" \
  37     cros_host_cxx=\"${BUILD_CXX} ${BUILD_CXXFLAGS}\" \
  38     cros_host_extra_ldflags=\"${BUILD_LDFLAGS}\" \
  39     custom_toolchain=\"//build/toolchain/cros:target\" \
  40     is_clang=false \
  41     use_custom_libcxx=false \
  42     target_cpu=\"${@gn_arch_name('${TUNE_ARCH}')}\" \
  43     cros_target_ar=\"${AR}\" \
  44     cros_target_cc=\"${CC}\" \
  45     cros_target_cxx=\"${CXX}\" \
  46     cros_target_extra_ldflags=\"${LDFLAGS}\" \
  47     v8_snapshot_toolchain=\"//build/toolchain/cros:v8_snapshot\" \
  48     cros_v8_snapshot_is_clang=false \
  49     cros_v8_snapshot_ar=\"${BUILD_AR}\" \
  50     cros_v8_snapshot_cc=\"${BUILD_CC}\" \
  51     cros_v8_snapshot_cxx=\"${BUILD_CXX}\" \
  52     linux_use_bundled_binutils=false \
  53     gold_path=\"\" \
  54     v8_enable_embedded_builtins=false \
  55     use_v8_context_snapshot=false \
  56 "
  57
  58 GN_ARGS:append = " \
  59   use_system_minigbm=false \
  60   use_wayland_gbm=false \
  61 "
  62
  63 GN_ARGS:append = " \
  64   is_webos=false \
  65   is_agl=true \
  66 "
  67
  68 # TODO: drop this after we migrate to ubuntu 16.04 or above
  69 GN_ARGS += "\
  70     fatal_linker_warnings=false\
  71 "
  72
  73 # TODO(rzanoni) copied from original recipe to fix qemux86 build.
  74 # check if it can be removed in the future.
  75 PACKAGECONFIG:remove:qemux86 = "gstreamer umediaserver neva-media gav neva-webrtc"
  76 #END TODO