recipes-wam/chromium/chromium84_git.bb

   1 require chromium.inc
   2
   3 SRC_URI = "\
   4     git://github.com/igalia/${PN};branch=marlin;protocol=https;rev=${SRCREV_chromium84};name=chromium84 \
   5     git://github.com/webosose/chromium-v8;branch=@chromium84;destsuffix=git/src/v8;rev=${SRCREV_v8};name=v8;protocol=https \
   6     file://add-a-delay-to-agl-ready-event.patch \
   7     file://chromium-quiche-invalid-offsetof.patch \
   8     file://chromium-skia-no_sanitize.patch \
   9 "
  10
  11 # Needed by catapult
  12 DEPENDS += "python-six-native python-beautifulsoup4-native python-lxml-native python-html5lib-native python-webencodings-native"
  13
  14 SRCREV_chromium84 = "3d6fd5dd0b836dbda2ea356ee1b25a9149419fef"
  15 SRCREV_v8 = "5c1d89dd2945a10cf7a6a3458050b3177a870b09"
  16
  17 BROWSER_APPLICATION = "chromium84-browser"
  18 BROWSER_APPLICATION_DIR = "/opt/chromium84"
  19 MKSNAPSHOT_PATH = "v8_snapshot/"
  20
  21 GN_ARGS += "use_gtk=false"
  22
  23 # Disable closure_compile
  24 # Else we need HOSTTOOLS += "java"
  25 GN_ARGS += "closure_compile=false"
  26
  27 # When using meta-clang, one can switch to using the lld linker
  28 # by using the ld-is-lld distro feature otherwise use gold linker
  29 GN_ARGS += "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', 'use_lld=true use_gold=false', bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', 'use_lld=false use_gold=true', 'use_lld=false use_gold=false', d), d)}"
  30
  31 # Toolchains we will use for the build. We need to point to the toolchain file
  32 # we've created, set the right target architecture and make sure we are not
  33 # using Chromium's toolchain (bundled clang, bundled binutils etc).
  34 GN_ARGS += "\
  35     host_toolchain=\"//build/toolchain/cros:host\" \
  36     cros_host_is_clang=false \
  37     use_custom_libcxx_for_host=false \
  38     cros_host_ar=\"${BUILD_AR}\" \
  39     cros_host_cc=\"${BUILD_CC} ${BUILD_CFLAGS}\" \
  40     cros_host_cxx=\"${BUILD_CXX} ${BUILD_CXXFLAGS}\" \
  41     cros_host_extra_ldflags=\"${BUILD_LDFLAGS}\" \
  42     custom_toolchain=\"//build/toolchain/cros:target\" \
  43     is_clang=false \
  44     use_custom_libcxx=false \
  45     target_cpu=\"${@gn_arch_name('${TUNE_ARCH}')}\" \
  46     cros_target_ar=\"${AR}\" \
  47     cros_target_cc=\"${CC}\" \
  48     cros_target_cxx=\"${CXX}\" \
  49     cros_target_extra_ldflags=\"${LDFLAGS}\" \
  50     v8_snapshot_toolchain=\"//build/toolchain/cros:v8_snapshot\" \
  51     cros_v8_snapshot_is_clang=false \
  52     cros_v8_snapshot_ar=\"${BUILD_AR}\" \
  53     cros_v8_snapshot_cc=\"${BUILD_CC}\" \
  54     cros_v8_snapshot_cxx=\"${BUILD_CXX}\" \
  55     linux_use_bundled_binutils=false \
  56     gold_path=\"\" \
  57     v8_enable_embedded_builtins=false \
  58     use_v8_context_snapshot=false \
  59 "
  60
  61 GN_ARGS:append = " \
  62   use_system_minigbm=false \
  63   use_wayland_gbm=false \
  64 "
  65
  66 GN_ARGS:append = " \
  67   is_webos=false \
  68   is_agl=true \
  69 "
  70
  71 # TODO: drop this after we migrate to ubuntu 16.04 or above
  72 GN_ARGS += "\
  73     fatal_linker_warnings=false\
  74 "
  75
  76 # TODO(rzanoni) copied from original recipe to fix qemux86 build.
  77 # check if it can be removed in the future.
  78 PACKAGECONFIG:remove:qemux86 = "gstreamer umediaserver neva-media gav neva-webrtc"
  79 #END TODO