recipes-wam/chromium/chromium.inc

   1 # Copyright (c) 2018 LG Electronics, Inc.
   2
   3 SUMMARY = "Chromium webruntime for webOS"
   4 AUTHOR = "Lokesh Kumar Goel <lokeshkumar.goel@lge.com>"
   5 SECTION = "webos/apps"
   6 LICENSE = "Apache-2.0 & BSD-3-Clause & LGPL-2.0-only & LGPL-2.1-only"
   7 LIC_FILES_CHKSUM = "\
   8     file://src/LICENSE;md5=0fca02217a5d49a14dfe2d11837bb34d \
   9     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
  10     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
  11 "
  12
  13 require gn-utils.inc
  14
  15 inherit gettext qemu pythonnative pkgconfig
  16
  17 DEPENDS = "virtual/gettext wayland wayland-native pixman freetype glib-2.0 fontconfig openssl pango cairo icu libxkbcommon libexif dbus pciutils udev libcap alsa-lib virtual/egl elfutils-native libdrm atk at-spi2-atk gperf-native gconf nss nss-native nspr nspr-native bison-native qemu-native curl"
  18
  19 PROVIDES = "${BROWSER_APPLICATION}"
  20
  21 SRCREV_v8 = "1e3af71f1ff3735e8a5b639c48dfca63a7b8a647"
  22
  23 # we don't include SRCPV in PV, so we have to manually include SRCREVs in do_fetch vardeps
  24 do_fetch[vardeps] += "SRCREV_v8"
  25 SRCREV_FORMAT = "main_v8"
  26
  27 S = "${WORKDIR}/git"
  28
  29 SRC_DIR = "${S}/src"
  30 BUILD_TYPE = "Release"
  31
  32 B = "${WORKDIR}/build"
  33 OUT_DIR = "${B}/${BUILD_TYPE}"
  34
  35 WEBRUNTIME_BUILD_TARGET = "webos:weboswebruntime"
  36 BROWSER_APP_BUILD_TARGET = "chrome"
  37 BROWSER_APPLICATION = "chromium-browser"
  38 BROWSER_APPLICATION_DIR = "/opt/chromium"
  39
  40 TARGET = "${WEBRUNTIME_BUILD_TARGET} ${BROWSER_APP_BUILD_TARGET}"
  41
  42 # Skip do_install:append of webos_system_bus. It is not compatible with this component.
  43 WEBOS_SYSTEM_BUS_FILES_LOCATION = "${S}/files/sysbus"
  44
  45 PACKAGECONFIG[lttng] = "use_lttng=true,use_lttng=false,lttng-ust,lttng-tools lttng-modules babeltrace"
  46
  47 # Chromium can use v4l2 device for hardware accelerated video decoding on such boards as Renesas R-car M3, for example.
  48 # In case of R-car m3, additional patches are required for gstreamer and v4l2apps.
  49 # See https://github.com/igel-oss/meta-browser-hwdecode/tree/igalia-chromium71.
  50 PACKAGECONFIG[use-linux-v4l2] = "use_v4l2_codec=true use_v4lplugin=true use_linux_v4l2_only=true"
  51
  52 # Options to enable debug build. Add this PACKAGECONFIG to local.conf
  53 # to enable debug build. By default debug is completely disabled to
  54 # speed up build
  55 PACKAGECONFIG[debug] = "symbol_level=2 use_debug_fission=true,symbol_level=1"
  56 PACKAGECONFIG[debug-blink] = "blink_symbol_level=2 use_debug_fission=true,blink_symbol_level=1"
  57
  58 GN_ARGS = "\
  59     enable_memorymanager_webapi=false\
  60     ffmpeg_branding=\"Chrome\"\
  61     host_os=\"linux\"\
  62     ozone_auto_platforms=false\
  63     proprietary_codecs=true\
  64     target_os=\"linux\"\
  65     treat_warnings_as_errors=false\
  66     use_x11=false\
  67     is_agl=true\
  68     use_cbe=true\
  69     is_chrome_cbe=true\
  70     is_component_build=false\
  71     use_cups=false\
  72     use_custom_libcxx=false\
  73     use_kerberos=false\
  74     use_neva_media=false\
  75     use_ozone=true\
  76     use_xkbcommon=true\
  77     use_wayland_gbm=false\
  78     use_pmlog=false\
  79     use_system_debugger_abort=true\
  80     ${PACKAGECONFIG_CONFARGS}\
  81 "
  82
  83 # From Chromium's BUILDCONFIG.gn:
  84 # Set to enable the official build level of optimization. This has nothing
  85 # to do with branding, but enables an additional level of optimization above
  86 # release (!is_debug). This might be better expressed as a tri-state
  87 # (debug, release, official) but for historical reasons there are two
  88 # separate flags.
  89 # See also: https://groups.google.com/a/chromium.org/d/msg/chromium-dev/hkcb6AOX5gE/PPT1ukWoBwAJ
  90 GN_ARGS += "is_debug=false is_official_build=true"
  91
  92 # is_cfi default value is true for x86-64 builds with is_official_build=true.
  93 # As of M63, we explicitly need to set it to false, otherwise we fail the
  94 # following assertion in //build/config/sanitizers/sanitizers.gni:
  95 #   assert(!is_cfi || is_clang,
  96 #          "is_cfi requires setting is_clang = true in 'gn args'")
  97 GN_ARGS += "is_cfi=false"
  98
  99 # use_thin_lto should be also disabled for GCC
 100 GN_ARGS += "use_thin_lto=false"
 101
 102 # We do not want to use Chromium's own Debian-based sysroots, it is easier to
 103 # just let Chromium's build system assume we are not using a sysroot at all and
 104 # let Yocto handle everything.
 105 GN_ARGS += "use_sysroot=false"
 106
 107 # ARM builds need special additional flags (see ${S}/build/config/arm.gni).
 108 # If we do not pass |arm_arch| and friends to GN, it will deduce a value that
 109 # will then conflict with TUNE_CCARGS and CC.
 110 # Note that as of M61 in some corner cases parts of the build system disable
 111 # the "compiler_arm_fpu" GN config, whereas -mfpu is always passed via ${CC}.
 112 # We might want to rework that if there are issues in the future.
 113 def get_compiler_flag(params, param_name, d):
 114     """Given a sequence of compiler arguments in |params|, returns the value of
 115     an option |param_name| or an empty string if the option is not present."""
 116     for param in params:
 117       if param.startswith(param_name):
 118         return param.split('=')[1]
 119     return ''
 120
 121 ARM_FLOAT_ABI = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'hard', 'softfp', d)}"
 122 ARM_FPU = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mfpu', d)}"
 123 ARM_TUNE = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mcpu', d)}"
 124 ARM_VERSION:aarch64 = "8"
 125 ARM_VERSION:armv7a = "7"
 126 ARM_VERSION:armv7ve = "7"
 127 ARM_VERSION:armv6 = "6"
 128
 129 # GN computes and defaults to it automatically where needed
 130 # forcing it from cmdline breaks build on places where it ends up
 131 # overriding what GN wants
 132 TUNE_CCARGS:remove = "-mthumb"
 133
 134 GN_ARGS:append:arm = " \
 135         arm_float_abi=\"${ARM_FLOAT_ABI}\" \
 136         arm_fpu=\"${ARM_FPU}\" \
 137         arm_tune=\"${ARM_TUNE}\" \
 138         arm_version=${ARM_VERSION} \
 139 "
 140 # tcmalloc's atomicops-internals-arm-v6plus.h uses the "dmb" instruction that
 141 # is not available on (some?) ARMv6 models, which causes the build to fail.
 142 GN_ARGS:append:armv6 = ' use_allocator="none"'
 143 # The WebRTC code fails to build on ARMv6 when NEON is enabled.
 144 # https://bugs.chromium.org/p/webrtc/issues/detail?id=6574
 145 GN_ARGS:append:armv6 = ' arm_use_neon=false'
 146
 147 # Disable glibc shims on musl
 148 # tcmalloc does not play well with musl as of M62 (and possibly earlier).
 149 # https://github.com/gperftools/gperftools/issues/693
 150 GN_ARGS:append:libc-musl = ' use_allocator_shim=false'
 151
 152 # Chromium 91 build of highway with NEON is broken. Do not build.
 153 GN_ARGS:append:aarch64 = ' enable_jxl_decoder=false'
 154
 155 # More options to speed up the build
 156 GN_ARGS += "\
 157     enable_nacl=false\
 158     disable_ftp_support=true\
 159     enable_print_preview=false\
 160     enable_basic_printing=false\
 161     enable_remoting=false\
 162     use_glib=true\
 163     use_gnome_keyring=false\
 164     use_pulseaudio=false\
 165 "
 166
 167 # Doesn't build for armv[45]*
 168 COMPATIBLE_MACHINE = "(-)"
 169 COMPATIBLE_MACHINE:aarch64 = "(.*)"
 170 COMPATIBLE_MACHINE:armv6 = "(.*)"
 171 COMPATIBLE_MACHINE:armv7a = "(.*)"
 172 COMPATIBLE_MACHINE:armv7ve = "(.*)"
 173 COMPATIBLE_MACHINE:x86 = "(.*)"
 174 COMPATIBLE_MACHINE:x86-64 = "(.*)"
 175
 176 #CHROMIUM_PLUGINS_PATH = "${libdir}"
 177 CBE_DATA_PATH = "${libdir}/cbe"
 178 CBE_DATA_LOCALES_PATH = "${CBE_DATA_PATH}/locales"
 179
 180 # The text relocations are intentional -- see comments in [GF-52468]
 181 # TODO: check if we need INSANE_SKIP on ldflags
 182 INSANE_SKIP:${PN} = "textrel ldflags"
 183
 184
 185 do_compile[progress] = "outof:^\[(\d+)/(\d+)\]\s+"
 186 do_compile() {
 187     if [ ! -f ${OUT_DIR}/build.ninja ]; then
 188          do_configure
 189     fi
 190
 191     export PATH="${S}/depot_tools:$PATH"
 192     ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR} ${TARGET}
 193 }
 194
 195 do_configure() {
 196     configure_env
 197 }
 198
 199 configure_env() {
 200     export GYP_CHROMIUM_NO_ACTION=1
 201     export PATH="${S}/depot_tools:$PATH"
 202
 203     GN_ARGS="${GN_ARGS}"
 204     echo GN_ARGS is ${GN_ARGS}
 205     echo BUILD_TARGETS are ${TARGET}
 206     cd ${SRC_DIR}
 207     gn gen ${OUT_DIR} --args="${GN_ARGS}"
 208 }
 209
 210 WINDOW_SIZE ?= "1920,1080"
 211
 212 configure_browser_settings() {
 213     USER_AGENT="Mozilla/5.0 (Linux; NetCast; U) AppleWebKit/537.31 (KHTML, like Gecko) Chrome/${CHROMIUM_VERSION} Safari/537.31"
 214     echo "${USER_AGENT}" > ${D_DIR}/user_agent_conf
 215     #We can replace below WINDOW_SIZE values from build configuration if available
 216     #echo "${WINDOW_SIZE}" > ${D_DIR}/window_size_conf
 217 }
 218
 219 install_chromium_browser() {
 220     # Install browser files
 221     ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR} webos/install/default_browser
 222
 223     D_DIR=${D}${BROWSER_APPLICATION_DIR}
 224     L_DIR=${D}${CBE_DATA_PATH}
 225     install -d ${D_DIR}
 226     install -d ${L_DIR}
 227
 228     cp -R --no-dereference --preserve=mode,links -v ${OUT_DIR}/image/${BROWSER_APPLICATION_DIR}/* ${D_DIR}
 229
 230     # AGL does not have PMLOG
 231     sed -i.bak s/PmLogCtl.*// ${D_DIR}/run_webbrowser
 232
 233     # To execute chromium in JAILER, Security Part needs permissions change
 234     # run_webbrowser: Script file for launching chromium
 235     chmod -v 755 ${D_DIR}/chrome
 236     chmod -v 755 ${D_DIR}/kill_webbrowser
 237     chmod -v 755 ${D_DIR}/run_webbrowser
 238
 239     configure_browser_settings
 240 }
 241
 242 install_webruntime() {
 243
 244     # # Generate install webos webview files
 245     # ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR} webos/install/weboswebruntime
 246
 247     # # Move installation files to D directory
 248     # mv ${OUT_DIR}/image/* ${D}
 249     # # Rename include and locale directories
 250     # mv ${D}${includedir}/webruntime ${D}${includedir}/${BPN}
 251     # mv ${D}${CBE_DATA_PATH}/neva_locales ${D}${CBE_DATA_LOCALES_PATH}
 252
 253     # # move this to separate mksnapshot-cross recipe once we figure out how to build just cross mksnapshot from chromium repository
 254     # install -d ${D}${bindir_cross}
 255     # gzip -c ${OUT_DIR}/${MKSNAPSHOT_PATH}mksnapshot > ${D}${bindir_cross}/${HOST_SYS}-mksnapshot.gz
 256
 257     install -d ${D}${libdir}
 258     install -d ${D}${libdir}/swiftshader
 259     install -d ${D}${includedir}/${BPN}
 260     install -d ${D}${CBE_DATA_PATH}
 261     install -d ${D}${CBE_DATA_LOCALES_PATH}
 262
 263     # Install webos webview files
 264     ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR} webos/install/weboswebruntime
 265
 266     install -v -m 0644 ${OUT_DIR}/swiftshader/*.so ${D}${libdir}/swiftshader
 267
 268     cp -R --no-dereference --preserve=mode,links -v ${OUT_DIR}/image/${includedir}/${BPN}/* ${D}${includedir}/${BPN}/
 269     install -v -m 0644 ${OUT_DIR}/image/${libdir}/*.so ${D}${libdir}
 270
 271     install -v -m 0644 ${OUT_DIR}/image/${CBE_DATA_PATH}/icudtl.dat ${D}${CBE_DATA_PATH}
 272     install -v -m 0644 ${OUT_DIR}/image/${CBE_DATA_PATH}/snapshot_blob.bin ${D}${CBE_DATA_PATH}
 273     # app_runtime_content.pak, webos_content.pak, extensions_shell_and_test.pak
 274     install -v -m 0644 ${OUT_DIR}/image/${CBE_DATA_PATH}/*.pak ${D}${CBE_DATA_PATH}
 275
 276     cp -R --no-dereference --preserve=mode,links -v ${OUT_DIR}/image/${CBE_DATA_LOCALES_PATH}/*.pak ${D}${CBE_DATA_LOCALES_PATH}
 277
 278     chown root:root -R ${D}${libdir}
 279     chown root:root -R ${D}${includedir}
 280     chown root:root -R ${D}${CBE_DATA_LOCALES_PATH}
 281
 282     # move this to separate mksnapshot-cross recipe once we figure out how to build just cross mksnapshot from chromium repository
 283     install -d ${D}${base_bindir}
 284     gzip -c ${OUT_DIR}/${MKSNAPSHOT_PATH}mksnapshot > ${D}${base_bindir}/${HOST_SYS}-mksnapshot.gz
 285
 286 }
 287
 288 do_install() {
 289     install_webruntime
 290     install_chromium_browser
 291 }
 292
 293 WEBOS_SYSTEM_BUS_DIRS_LEGACY_BROWSER_APPLICATION = " \
 294     ${webos_sysbus_prvservicesdir}/${BROWSER_APPLICATION}.service \
 295     ${webos_sysbus_pubservicesdir}/${BROWSER_APPLICATION}.service \
 296     ${webos_sysbus_prvrolesdir}/${BROWSER_APPLICATION}.json \
 297     ${webos_sysbus_pubrolesdir}/${BROWSER_APPLICATION}.json \
 298 "
 299
 300 SYSROOT_DIRS:append = " ${bindir_cross}"
 301
 302 PACKAGES:prepend = " \
 303     ${PN}-cross-mksnapshot \
 304     ${BROWSER_APPLICATION} \
 305 "
 306
 307 FILES:${BROWSER_APPLICATION} += " \
 308     ${BROWSER_APPLICATION_DIR} \
 309     ${WEBOS_SYSTEM_BUS_DIRS_LEGACY_BROWSER_APPLICATION} \
 310 "
 311
 312 RDEPENDS:${BROWSER_APPLICATION} += "${PN}"
 313
 314 VIRTUAL-RUNTIME_gpu-libs ?= ""
 315 RDEPENDS:${PN} += "${VIRTUAL-RUNTIME_gpu-libs}"
 316
 317 # The text relocations are intentional -- see comments in [GF-52468]
 318 # TODO: check if we need INSANE_SKIP on ldflags
 319 INSANE_SKIP:${BROWSER_APPLICATION} += "libdir ldflags textrel"
 320
 321 FILES:${PN} = " \
 322     ${libdir}/*.so \
 323     ${libdir}/swiftshader/*.so \
 324     ${CBE_DATA_PATH}/* \
 325     ${libdir}/${BPN}/*.so \
 326     ${WEBOS_SYSTEM_BUS_DIRS} \
 327 "
 328
 329 FILES:${PN}-dev = " \
 330     ${includedir} \
 331 "
 332
 333 FILES:${PN}-cross-mksnapshot = "${bindir_cross}/${HOST_SYS}-mksnapshot.gz"