recipes-wam/chromium/chromium.inc

   1 # Copyright (c) 2018 LG Electronics, Inc.
   2
   3 SUMMARY = "Chromium webruntime for webOS"
   4 AUTHOR = "Lokesh Kumar Goel <lokeshkumar.goel@lge.com>"
   5 SECTION = "webos/apps"
   6 LICENSE = "Apache-2.0 & BSD-3-Clause & LGPL-2.0 & LGPL-2.1"
   7 LIC_FILES_CHKSUM = "\
   8     file://src/LICENSE;md5=0fca02217a5d49a14dfe2d11837bb34d \
   9     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
  10     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
  11 "
  12
  13 require gn-utils.inc
  14
  15 inherit gettext qemu pythonnative
  16
  17 DEPENDS = "virtual/gettext wayland wayland-native pixman freetype glib-2.0 fontconfig openssl pango cairo icu libxkbcommon libexif dbus pciutils udev libcap alsa-lib virtual/egl elfutils-native libdrm atk at-spi2-atk gperf-native gconf nss nss-native nspr nspr-native bison-native qemu-native"
  18
  19 PROVIDES = "${BROWSER_APPLICATION}"
  20
  21 SRCREV_v8 = "1e3af71f1ff3735e8a5b639c48dfca63a7b8a647"
  22
  23 # we don't include SRCPV in PV, so we have to manually include SRCREVs in do_fetch vardeps
  24 do_fetch[vardeps] += "SRCREV_v8"
  25 SRCREV_FORMAT = "main_v8"
  26
  27 S = "${WORKDIR}/git"
  28
  29 SRC_DIR = "${S}/src"
  30 OUT_DIR = "${WORKDIR}/build"
  31 BUILD_TYPE = "Release"
  32
  33 B = "${OUT_DIR}/${BUILD_TYPE}"
  34
  35 WEBRUNTIME_BUILD_TARGET = "webos:weboswebruntime"
  36 BROWSER_APP_BUILD_TARGET = "chrome"
  37 BROWSER_APPLICATION = "chromium84-browser"
  38 BROWSER_APPLICATION_DIR = "/opt/chromium84"
  39
  40 TARGET = "${WEBRUNTIME_BUILD_TARGET}"
  41
  42 # Skip do_install_append of webos_system_bus. It is not compatible with this component.
  43 WEBOS_SYSTEM_BUS_FILES_LOCATION = "${S}/files/sysbus"
  44
  45 PACKAGECONFIG ?= "jumbo use-upstream-wayland"
  46
  47
  48 # Set a default value for jumbo file merge of 8. This should be good for build
  49 # servers and workstations with a big number of cores. In case build is
  50 # happening in a machine with less cores but still enough RAM a good value could
  51 # be 50.
  52 JUMBO_FILE_MERGE_LIMIT="8"
  53 PACKAGECONFIG[jumbo] = "use_jumbo_build=true jumbo_file_merge_limit=${JUMBO_FILE_MERGE_LIMIT}, use_jumbo_build=false"
  54
  55 PACKAGECONFIG[lttng] = "use_lttng=true,use_lttng=false,lttng-ust,lttng-tools lttng-modules babeltrace"
  56
  57 # Chromium can use v4l2 device for hardware accelerated video decoding on such boards as Renesas R-car M3, for example.
  58 # In case of R-car m3, additional patches are required for gstreamer and v4l2apps.
  59 # See https://github.com/igel-oss/meta-browser-hwdecode/tree/igalia-chromium71.
  60 PACKAGECONFIG[use-linux-v4l2] = "use_v4l2_codec=true use_v4lplugin=true use_linux_v4l2_only=true"
  61
  62 PACKAGECONFIG[use-upstream-wayland] = " \
  63     ozone_platform_wayland_external=false ozone_platform_wayland=true, \
  64     ozone_platform_wayland_external=true ozone_platform_wayland=false \
  65 "
  66
  67 GN_ARGS = "\
  68     enable_memorymanager_webapi=false\
  69     ffmpeg_branding=\"Chrome\"\
  70     host_os=\"linux\"\
  71     ozone_auto_platforms=false\
  72     proprietary_codecs=true\
  73     target_os=\"linux\"\
  74     treat_warnings_as_errors=false\
  75     is_agl=true\
  76     use_cbe=true\
  77     is_chrome_cbe=false\
  78     use_cups=false\
  79     use_custom_libcxx=false\
  80     use_kerberos=false\
  81     use_neva_media=false\
  82     use_ozone=true\
  83     use_xkbcommon=true\
  84     use_wayland_gbm=false\
  85     use_pmlog=false\
  86     use_system_debugger_abort=true\
  87     ${PACKAGECONFIG_CONFARGS}\
  88 "
  89
  90 # From Chromium's BUILDCONFIG.gn:
  91 # Set to enable the official build level of optimization. This has nothing
  92 # to do with branding, but enables an additional level of optimization above
  93 # release (!is_debug). This might be better expressed as a tri-state
  94 # (debug, release, official) but for historical reasons there are two
  95 # separate flags.
  96 # See also: https://groups.google.com/a/chromium.org/d/msg/chromium-dev/hkcb6AOX5gE/PPT1ukWoBwAJ
  97 GN_ARGS += "is_debug=false is_official_build=true"
  98
  99 # is_cfi default value is true for x86-64 builds with is_official_build=true.
 100 # As of M63, we explicitly need to set it to false, otherwise we fail the
 101 # following assertion in //build/config/sanitizers/sanitizers.gni:
 102 #   assert(!is_cfi || is_clang,
 103 #          "is_cfi requires setting is_clang = true in 'gn args'")
 104 GN_ARGS += "is_cfi=false"
 105
 106 # By default, passing is_official_build=true to GN causes its symbol_level
 107 # variable to be set to "2". This means the compiler will be passed "-g2" and
 108 # we will end up with a very large chrome binary (around 5Gb as of M58)
 109 # regardless of whether DEBUG_BUILD has been set or not. In addition, binutils,
 110 # file and other utilities are unable to read a 32-bit binary this size, which
 111 # causes it not to be stripped.
 112 # The solution is two-fold:
 113 # 1. Make sure -g is not passed on 32-bit architectures via DEBUG_FLAGS. -g is
 114 #    the same as -g2. -g1 generates an 800MB binary, which is a lot more
 115 #    manageable.
 116 # 2. Explicitly pass symbol_level=0 to GN. This causes -g0 to be passed
 117 #    instead, so that if DEBUG_BUILD is not set GN will not create a huge debug
 118 #    binary anyway. Since our compiler flags are passed after GN's, -g0 does
 119 #    not cause any issues if DEBUG_BUILD is set, as -g1 will be passed later.
 120 DEBUG_FLAGS_remove_arm = "-g"
 121 DEBUG_FLAGS_append_arm = "-g1"
 122 DEBUG_FLAGS_remove_x86 = "-g"
 123 DEBUG_FLAGS_append_x86 = "-g1"
 124 GN_ARGS += "symbol_level=0"
 125
 126 # We do not want to use Chromium's own Debian-based sysroots, it is easier to
 127 # just let Chromium's build system assume we are not using a sysroot at all and
 128 # let Yocto handle everything.
 129 GN_ARGS += "use_sysroot=false"
 130
 131 # ARM builds need special additional flags (see ${S}/build/config/arm.gni).
 132 # If we do not pass |arm_arch| and friends to GN, it will deduce a value that
 133 # will then conflict with TUNE_CCARGS and CC.
 134 # Note that as of M61 in some corner cases parts of the build system disable
 135 # the "compiler_arm_fpu" GN config, whereas -mfpu is always passed via ${CC}.
 136 # We might want to rework that if there are issues in the future.
 137 def get_compiler_flag(params, param_name, d):
 138     """Given a sequence of compiler arguments in |params|, returns the value of
 139     an option |param_name| or an empty string if the option is not present."""
 140     for param in params:
 141       if param.startswith(param_name):
 142         return param.split('=')[1]
 143     return ''
 144
 145 ARM_FLOAT_ABI = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'hard', 'softfp', d)}"
 146 ARM_FPU = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mfpu', d)}"
 147 ARM_TUNE = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mcpu', d)}"
 148 ARM_VERSION_aarch64 = "8"
 149 ARM_VERSION_armv7a = "7"
 150 ARM_VERSION_armv7ve = "7"
 151 ARM_VERSION_armv6 = "6"
 152
 153 # GN computes and defaults to it automatically where needed
 154 # forcing it from cmdline breaks build on places where it ends up
 155 # overriding what GN wants
 156 TUNE_CCARGS_remove = "-mthumb"
 157
 158 GN_ARGS_append_arm = " \
 159         arm_float_abi=\"${ARM_FLOAT_ABI}\" \
 160         arm_fpu=\"${ARM_FPU}\" \
 161         arm_tune=\"${ARM_TUNE}\" \
 162         arm_version=${ARM_VERSION} \
 163 "
 164 # tcmalloc's atomicops-internals-arm-v6plus.h uses the "dmb" instruction that
 165 # is not available on (some?) ARMv6 models, which causes the build to fail.
 166 GN_ARGS_append_armv6 += 'use_allocator="none"'
 167 # The WebRTC code fails to build on ARMv6 when NEON is enabled.
 168 # https://bugs.chromium.org/p/webrtc/issues/detail?id=6574
 169 GN_ARGS_append_armv6 += 'arm_use_neon=false'
 170
 171 # Disable glibc shims on musl
 172 # tcmalloc does not play well with musl as of M62 (and possibly earlier).
 173 # https://github.com/gperftools/gperftools/issues/693
 174 GN_ARGS_append_libc-musl = ' use_allocator_shim=false'
 175
 176 # More options to speed up the build
 177 GN_ARGS += "\
 178     enable_nacl=false\
 179     disable_ftp_support=true\
 180     enable_print_preview=false\
 181     enable_remoting=false\
 182     use_glib=true\
 183     use_gnome_keyring=false\
 184     use_pulseaudio=false\
 185 "
 186
 187 # Doesn't build for armv[45]*
 188 COMPATIBLE_MACHINE = "(-)"
 189 COMPATIBLE_MACHINE_aarch64 = "(.*)"
 190 COMPATIBLE_MACHINE_armv6 = "(.*)"
 191 COMPATIBLE_MACHINE_armv7a = "(.*)"
 192 COMPATIBLE_MACHINE_armv7ve = "(.*)"
 193 COMPATIBLE_MACHINE_x86 = "(.*)"
 194 COMPATIBLE_MACHINE_x86-64 = "(.*)"
 195
 196 #CHROMIUM_PLUGINS_PATH = "${libdir}"
 197 CBE_DATA_PATH = "${libdir}/cbe"
 198 CBE_DATA_LOCALES_PATH = "${CBE_DATA_PATH}/locales"
 199
 200 # The text relocations are intentional -- see comments in [GF-52468]
 201 # TODO: check if we need INSANE_SKIP on ldflags
 202 INSANE_SKIP_${PN} = "textrel ldflags"
 203
 204
 205 do_compile[progress] = "outof:^\[(\d+)/(\d+)\]\s+"
 206 do_compile() {
 207     if [ ! -f ${OUT_DIR}/${BUILD_TYPE}/build.ninja ]; then
 208          do_configure
 209     fi
 210
 211     export PATH="${S}/depot_tools:$PATH"
 212     ${S}/depot_tools/ninja ${PARALLEL_MAKE} -v -C ${OUT_DIR}/${BUILD_TYPE} ${TARGET}
 213 }
 214
 215 do_configure() {
 216     configure_env
 217 }
 218
 219 configure_env() {
 220     export GYP_CHROMIUM_NO_ACTION=1
 221     export PATH="${S}/depot_tools:$PATH"
 222
 223     GN_ARGS="${GN_ARGS}"
 224     echo GN_ARGS is ${GN_ARGS}
 225     echo BUILD_TARGETS are ${TARGET}
 226     cd ${SRC_DIR}
 227     gn gen ${OUT_DIR}/${BUILD_TYPE} --args="${GN_ARGS}"
 228 }
 229
 230 WINDOW_SIZE ?= "1920,1080"
 231
 232 configure_browser_settings() {
 233     USER_AGENT="Mozilla/5.0 (Linux; NetCast; U) AppleWebKit/537.31 (KHTML, like Gecko) Chrome/${CHROMIUM_VERSION} Safari/537.31"
 234     echo "${USER_AGENT}" > ${D_DIR}/user_agent_conf
 235     #We can replace below WINDOW_SIZE values from build configuration if available
 236     #echo "${WINDOW_SIZE}" > ${D_DIR}/window_size_conf
 237 }
 238
 239 install_chromium_browser() {
 240     D_DIR=${D}${BROWSER_APPLICATION_DIR}
 241     install -d ${D_DIR}
 242
 243     # Install browser files
 244      if [ -e "${SRC_DIR}/webos/install" ]; then
 245          cd ${OUT_DIR}/${BUILD_TYPE}
 246          xargs --arg-file=${SRC_DIR}/webos/install/default_browser/binary.list cp -R --no-dereference --preserve=mode,links -v --target-directory=${D_DIR}
 247          cd ${SRC_DIR}
 248          xargs --arg-file=${SRC_DIR}/webos/install/default_browser/runtime.list cp -R --no-dereference --preserve=mode,links -v --target-directory=${D_DIR}
 249      fi
 250
 251     # AGL does not have PMLOG
 252     sed -i.bak s/PmLogCtl.*// ${D_DIR}/run_webbrowser
 253
 254     # To execute chromium in JAILER, Security Part needs permissions change
 255     # run_webbrowser: Script file for launching chromium
 256     chmod -v 755 ${D_DIR}/chrome
 257     chmod -v 755 ${D_DIR}/kill_webbrowser
 258     chmod -v 755 ${D_DIR}/run_webbrowser
 259
 260     configure_browser_settings
 261 }
 262
 263 install_webruntime() {
 264
 265     # # Generate install webos webview files
 266     # ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR}/${BUILD_TYPE} webos/install/weboswebruntime
 267
 268     # # Move installation files to D directory
 269     # mv ${OUT_DIR}/${BUILD_TYPE}/image/* ${D}
 270     # # Rename include and locale directories
 271     # mv ${D}${includedir}/webruntime ${D}${includedir}/${BPN}
 272     # mv ${D}${CBE_DATA_PATH}/neva_locales ${D}${CBE_DATA_LOCALES_PATH}
 273
 274     # # move this to separate mksnapshot-cross recipe once we figure out how to build just cross mksnapshot from chromium repository
 275     # install -d ${D}${bindir_cross}
 276     # gzip -c ${OUT_DIR}/${BUILD_TYPE}/${MKSNAPSHOT_PATH}mksnapshot > ${D}${bindir_cross}/${HOST_SYS}-mksnapshot.gz
 277
 278     install -d ${D}${libdir}
 279     install -d ${D}${libdir}/swiftshader
 280     install -d ${D}${includedir}/${BPN}
 281     install -d ${D}${CBE_DATA_PATH}
 282     install -d ${D}${CBE_DATA_LOCALES_PATH}
 283
 284     # Install webos webview files
 285     ${S}/depot_tools/ninja ${PARALLEL_MAKE} -C ${OUT_DIR}/${BUILD_TYPE} webos/install/weboswebruntime
 286
 287     install -v -m 0644 ${OUT_DIR}/${BUILD_TYPE}/swiftshader/*.so ${D}${libdir}/swiftshader
 288
 289     chown root:root -R ${D}${libdir}
 290     chown root:root -R ${D}${includedir}
 291
 292     # move this to separate mksnapshot-cross recipe once we figure out how to build just cross mksnapshot from chromium repository
 293     install -d ${D}${base_bindir}
 294     gzip -c ${OUT_DIR}/${BUILD_TYPE}/${MKSNAPSHOT_PATH}mksnapshot > ${D}${base_bindir}/${HOST_SYS}-mksnapshot.gz
 295
 296 }
 297
 298 do_install() {
 299     install_webruntime
 300 }
 301
 302 WEBOS_SYSTEM_BUS_DIRS_LEGACY_BROWSER_APPLICATION = " \
 303     ${webos_sysbus_prvservicesdir}/${BROWSER_APPLICATION}.service \
 304     ${webos_sysbus_pubservicesdir}/${BROWSER_APPLICATION}.service \
 305     ${webos_sysbus_prvrolesdir}/${BROWSER_APPLICATION}.json \
 306     ${webos_sysbus_pubrolesdir}/${BROWSER_APPLICATION}.json \
 307 "
 308
 309 SYSROOT_DIRS_append = " ${bindir_cross}"
 310
 311 PACKAGES_prepend = " \
 312     ${PN}-cross-mksnapshot \
 313     ${BROWSER_APPLICATION} \
 314 "
 315
 316 FILES_${BROWSER_APPLICATION} += " \
 317     ${BROWSER_APPLICATION_DIR} \
 318     ${WEBOS_SYSTEM_BUS_DIRS_LEGACY_BROWSER_APPLICATION} \
 319 "
 320
 321 RDEPENDS_${BROWSER_APPLICATION} += "${PN}"
 322
 323 VIRTUAL-RUNTIME_gpu-libs ?= ""
 324 RDEPENDS_${PN} += "${VIRTUAL-RUNTIME_gpu-libs}"
 325
 326 # The text relocations are intentional -- see comments in [GF-52468]
 327 # TODO: check if we need INSANE_SKIP on ldflags
 328 INSANE_SKIP_${BROWSER_APPLICATION} += "libdir ldflags textrel"
 329
 330 FILES_${PN} = " \
 331     ${libdir}/*.so \
 332     ${libdir}/swiftshader/*.so \
 333     ${CBE_DATA_PATH}/* \
 334     ${libdir}/${BPN}/*.so \
 335     ${WEBOS_SYSTEM_BUS_DIRS} \
 336 "
 337
 338 FILES_${PN}-dev = " \
 339     ${includedir} \
 340 "
 341
 342 FILES_${PN}-cross-mksnapshot = "${bindir_cross}/${HOST_SYS}-mksnapshot.gz"