recipes-platform/packagegroups/packagegroup-agl-demo-platform.bb

   1 SUMMARY = "The software for DEMO platform of AGL IVI profile"
   2 DESCRIPTION = "A set of packages belong to AGL Demo Platform"
   3
   4 LICENSE = "MIT"
   5
   6 inherit packagegroup
   7
   8 PROVIDES = "${PACKAGES}"
   9 PACKAGES = "\
  10     packagegroup-agl-demo-platform \
  11     packagegroup-agl-demo-platform-devel \
  12     "
  13
  14 ALLOW_EMPTY_${PN} = "1"
  15
  16 RDEPENDS_${PN} += "\
  17     packagegroup-agl-image-ivi \
  18     "
  19
  20 RDEPENDS_${PN} += "\
  21     packagegroup-agl-profile-graphical-qt5 \
  22     packagegroup-hmi-framework \
  23     packagegroup-agl-demo \
  24     "
  25
  26 AGL_APPS = " \
  27     dashboard \
  28     hvac \
  29     mediaplayer \
  30     virtual/navigation \
  31     phone \
  32     poiapp \
  33     radio \
  34     settings \
  35     messaging \
  36     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'taskmanager' , '', d)} \
  37     virtual/mixer \
  38     "
  39
  40 QTAGLEXTRAS = " libqtappfw"
  41
  42 # add support for websocket in Qt and QML
  43 QTAGLEXTRAS_append = " qtwebsockets qtwebsockets-qmlplugins"
  44 #PREFERRED_PROVIDER_virtual/webruntime = "web-runtime"
  45
  46 # Cluster demo support.
  47 # ATM no cluster map viewer is supported with the older navigation application.
  48 MAPVIEWER = "${@bb.utils.contains("PREFERRED_RPROVIDER_virtual/navigation", "ondemandnavi", "tbtnavi", "",d)}"
  49 CLUSTER_SUPPORT_PACKAGES = " \
  50         ${MAPVIEWER} \
  51         cluster-demo-network-config \
  52         cluster-lin-bridging-config \
  53         cluster-demo-simulator \
  54 "
  55 CLUSTER_SUPPORT = "${@bb.utils.contains("DISTRO_FEATURES", "agl-cluster-demo-support", "${CLUSTER_SUPPORT_PACKAGES}", "",d)}"
  56
  57 DEMO_UNIT_CONF ?= ""
  58 # Hook for demo platform configuration
  59 # ATM used for:
  60 # 1) Adding udev configuration and scripts for supporting USB attached
  61 #    I2C devices for RTC and HVAC LED support.
  62 DEMO_UNIT_CONF += " demo-i2c-udev-conf "
  63
  64 # Preload poi API key for demo if requested, and potentially maps for older
  65 # navigation application if it is configured.
  66 DEMO_MAPS_LOCALE ?= "uk"
  67 DEMO_PRELOAD_MAPS = "${@bb.utils.contains("PREFERRED_RPROVIDER_virtual/navigation", "navigation", " navigation-maps-${DEMO_MAPS_LOCALE}", "",d)}"
  68
  69 # Preload only if agl-demo-preload is set
  70 DEMO_PRELOAD = "${@bb.utils.contains("DISTRO_FEATURES", "agl-demo-preload", " ${DEMO_PRELOAD_MAPS} ${DEMO_UNIT_CONF} poiapp-api-key", "",d)}"
  71
  72 RDEPENDS_${PN}_append = " \
  73     qtquickcontrols2-agl \
  74     qtquickcontrols2-agl-style \
  75     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'unzip' , '', d)} \
  76     ${AGL_APPS} \
  77     ${QTAGLEXTRAS} \
  78     ${CLUSTER_SUPPORT} \
  79     ${DEMO_PRELOAD} \
  80     "
  81
  82 # NOTE: Currently no coverage versions for the application widgets,
  83 #       they should be added here when available.
  84 #       Also, the navigation and mixer debug widgets are currently
  85 #       specified explicitly, as there's no simple way to derive their
  86 #       names from the virtual/ RPROVIDES at present.
  87 RDEPENDS_${PN}-devel = " \
  88     packagegroup-hmi-framework-devel \
  89     dashboard-dbg \
  90     hvac-dbg \
  91     mediaplayer-dbg \
  92     mixer-dbg \
  93     phone-dbg \
  94     ondemandnavi-dbg \
  95     poiapp-dbg \
  96     radio-dbg \
  97     settings-dbg \
  98     messaging-dbg \
  99     taskmanager-dbg \
 100     "