recipes-platform/packagegroups/packagegroup-agl-demo-platform.bb

   1 SUMMARY = "The software for DEMO platform of AGL IVI profile"
   2 DESCRIPTION = "A set of packages belong to AGL Demo Platform"
   3
   4 LICENSE = "MIT"
   5
   6 inherit packagegroup
   7
   8 PROVIDES = "${PACKAGES}"
   9 PACKAGES = "\
  10     packagegroup-agl-demo-platform \
  11     packagegroup-agl-demo-platform-devel \
  12     "
  13
  14 ALLOW_EMPTY_${PN} = "1"
  15
  16 RDEPENDS_${PN} += "\
  17     packagegroup-agl-image-ivi \
  18     "
  19
  20 RDEPENDS_${PN} += "\
  21     packagegroup-agl-profile-graphical-qt5 \
  22     packagegroup-hmi-framework \
  23     packagegroup-agl-demo \
  24     "
  25
  26 AGL_APPS = " \
  27     dashboard \
  28     hvac \
  29     mediaplayer \
  30     virtual/navigation \
  31     phone \
  32     poiapp \
  33     radio \
  34     settings \
  35     messaging \
  36     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'taskmanager' , '', d)} \
  37     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-weston-waltham-remoting', 'waltham-receiver' , '', d)} \
  38     virtual/mixer \
  39     virtual/qtwayland-config \
  40     "
  41
  42 QTAGLEXTRAS = " libqtappfw"
  43
  44 # add support for websocket in Qt and QML
  45 QTAGLEXTRAS_append = " qtwebsockets qtwebsockets-qmlplugins"
  46 #PREFERRED_PROVIDER_virtual/webruntime = "web-runtime"
  47
  48 # Cluster demo support.
  49 # ATM no cluster map viewer is supported with the older navigation application.
  50 MAPVIEWER = "${@bb.utils.contains("PREFERRED_RPROVIDER_virtual/navigation", "ondemandnavi", "tbtnavi", "",d)}"
  51 CLUSTER_SUPPORT_PACKAGES = " \
  52         ${MAPVIEWER} \
  53         cluster-demo-network-config \
  54         cluster-lin-bridging-config \
  55         cluster-demo-simulator \
  56 "
  57 CLUSTER_SUPPORT = "${@bb.utils.contains("DISTRO_FEATURES", "agl-cluster-demo-support", "${CLUSTER_SUPPORT_PACKAGES}", "",d)}"
  58
  59 DEMO_UNIT_CONF ?= ""
  60 # Hook for demo platform configuration
  61 # ATM used for:
  62 # 1) Adding udev configuration and scripts for supporting USB attached
  63 #    I2C devices for RTC and HVAC LED support.
  64 DEMO_UNIT_CONF += " demo-i2c-udev-conf "
  65
  66 # Preload poi API key for demo if requested, and potentially maps for older
  67 # navigation application if it is configured.
  68 DEMO_MAPS_LOCALE ?= "uk"
  69 DEMO_PRELOAD_MAPS = "${@bb.utils.contains("PREFERRED_RPROVIDER_virtual/navigation", "navigation", " navigation-maps-${DEMO_MAPS_LOCALE}", "",d)}"
  70
  71 # Preload only if agl-demo-preload is set
  72 DEMO_PRELOAD = "${@bb.utils.contains("DISTRO_FEATURES", "agl-demo-preload", " ${DEMO_PRELOAD_MAPS} ${DEMO_UNIT_CONF} poiapp-api-key", "",d)}"
  73
  74 RDEPENDS_${PN}_append = " \
  75     weston-ini-conf \
  76     qtquickcontrols2-agl \
  77     qtquickcontrols2-agl-style \
  78     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'unzip' , '', d)} \
  79     ${AGL_APPS} \
  80     ${QTAGLEXTRAS} \
  81     ${CLUSTER_SUPPORT} \
  82     ${DEMO_PRELOAD} \
  83     "
  84
  85 # NOTE: Currently no coverage versions for the application widgets,
  86 #       they should be added here when available.
  87 #       Also, the navigation and mixer debug widgets are currently
  88 #       specified explicitly, as there's no simple way to derive their
  89 #       names from the virtual/ RPROVIDES at present.
  90 RDEPENDS_${PN}-devel = " \
  91     packagegroup-hmi-framework-devel \
  92     dashboard-dbg \
  93     hvac-dbg \
  94     mediaplayer-dbg \
  95     mixer-dbg \
  96     phone-dbg \
  97     ondemandnavi-dbg \
  98     poiapp-dbg \
  99     radio-dbg \
 100     settings-dbg \
 101     messaging-dbg \
 102     taskmanager-dbg \
 103     "