recipes-platform/images/agl-kvm-demo.bb

   1 SUMMARY = "AGL KVM+QEMU Demo Platform image."
   2 LICENSE = "MIT"
   3
   4 require recipes-platform/images/agl-image-compositor.bb
   5 require agl-demo-features.inc
   6
   7 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   8
   9 # If building with "agl-kvm-host-kuksa", the databroker and likely
  10 # some clients run on the host
  11 IMAGE_FEATURES += " \
  12     ${@bb.utils.contains("AGL_FEATURES", "agl-kvm-host-kuksa", "kuksa-val-databroker kuksa-val-databroker-client", "", d)} \
  13     ${@bb.utils.contains("DISTRO_FEATURES", "agl-devel", "can-test-tools" , "", d)} \
  14 "
  15
  16 # Add packages for KVM+QEMU demo platform here
  17 IMAGE_INSTALL += " \
  18     packagegroup-agl-core-connectivity \
  19     kernel-image \
  20     agl-compositor \
  21     weston-ini-conf-kvm \
  22     output-udev-conf \
  23     native-shell-client \
  24     qemu \
  25     ${QEMU_GUEST_CONFIGS} \
  26     util-linux-taskset \
  27     screen \
  28     simple-can-simulator \
  29     alsa-utils \
  30 "
  31
  32 # Until virtio sound is workable with QEMU, run the audio using
  33 # services on the host for a better demo experience.  At the
  34 # moment, this also includes the HVAC service since it does not
  35 # make sense to try to make things more fine-grained with respect
  36 # to configuration for where things expect to find the databroker.
  37 # It will need to be revisited when virtio-snd, virtio-gpio, etc.
  38 # become feasible to use.
  39 HOST_AUDIO_INSTALL = " \
  40     packagegroup-agl-ivi-services-platform \
  41     agl-service-radio-conf-kvm-demo \
  42     packagegroup-pipewire \
  43     wireplumber-config-agl \
  44     wireplumber-policy-config-agl \
  45     mpd \
  46     udisks2 \
  47     ${@bb.utils.contains("DISTRO_FEATURES", "agl-devel", "packagegroup-pipewire-tools mpc" , "", d)} \
  48 "
  49
  50 IMAGE_INSTALL += "\
  51     ${@bb.utils.contains("AGL_FEATURES", "agl-kvm-host-kuksa", "kuksa-databroker-agl-demo-cluster", "", d)} \
  52     ${@bb.utils.contains("AGL_FEATURES", "agl-kvm-host-audio", "${HOST_AUDIO_INSTALL}", "", d)} \
  53 "
  54
  55 # Potential size reduction options
  56 #IMAGE_LINGUAS = " "
  57 #NO_RECOMMENDATIONS = "1"
  58
  59 GUEST_MACHINE ?= "virtio-${TUNE_ARCH}"
  60
  61 GUEST_VM1_IMAGE ?= "agl-ivi-demo-flutter"
  62 GUEST_VM2_IMAGE ?= "agl-cluster-demo-flutter"
  63
  64 GUEST_IMAGES ?= "agl-kvm-guest:${GUEST_VM1_IMAGE} agl-kvm-guest:${GUEST_VM2_IMAGE}"
  65
  66 QEMU_GUEST_CONFIGS ?= ""
  67
  68 python __anonymous() {
  69     for c in (d.getVar('GUEST_IMAGES') or "").split():
  70         (mc, image) = c.split(':')
  71         dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
  72         d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
  73
  74         # Assume there is a qemu-config-X package for guest image X
  75         d.appendVar('QEMU_GUEST_CONFIGS', ' ' + 'qemu-config-' + image)
  76 }
  77
  78 install_guest_images() {
  79     for c in ${GUEST_IMAGES}; do
  80         config=${c%:*}
  81         image=${c#*:}
  82         name=${image}
  83         rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
  84         install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
  85         src="${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/${image}-${GUEST_MACHINE}.ext4"
  86         bbnote "Installing ${src}"
  87         install -m 0600 ${src} ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  88         # Placeholder until booting from kernel in VM image is worked out
  89         install -m 0600 ${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/Image-${GUEST_MACHINE}.bin ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  90     done
  91 }
  92
  93 ROOTFS_POSTPROCESS_COMMAND += "install_guest_images; "
  94
  95 IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"