recipes-platform/images/agl-kvm-demo-platform.bb

   1 DESCRIPTION = "AGL KVM+QEMU Demo Platform image."
   2
   3 LICENSE = "MIT"
   4
   5 require recipes-platform/images/agl-image-weston.inc
   6
   7 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   8
   9 # Add packages for KVM+QEMU demo platform here
  10 IMAGE_INSTALL:append = " \
  11     packagegroup-agl-image-minimal \
  12     packagegroup-agl-core-connectivity \
  13     kernel-image \
  14     agl-compositor \
  15     weston-ini-conf-kvm \
  16     output-udev-conf \
  17     native-shell-client \
  18     qemu \
  19     ${QEMU_GUEST_CONFIGS} \
  20     util-linux-taskset \
  21     screen \
  22     alsa-utils \
  23 "
  24
  25 # Potential size reduction options
  26 #IMAGE_LINGUAS = " "
  27 #NO_RECOMMENDATIONS = "1"
  28
  29 GUEST_MACHINE ?= "virtio-${TUNE_ARCH}"
  30
  31 GUEST_VM1_IMAGE ?= "agl-demo-platform"
  32 GUEST_VM2_IMAGE ?= "agl-cluster-demo-platform"
  33
  34 GUEST_IMAGES ?= "agl-kvm-guest:${GUEST_VM1_IMAGE} agl-kvm-guest:${GUEST_VM2_IMAGE}"
  35
  36 QEMU_GUEST_CONFIGS ?= ""
  37
  38 # Handle modification of IMAGE_LINK_NAME done by ULCB builds with Kingfisher support
  39 MACHINE_SUFFIX = "${@bb.utils.contains('AGL_FEATURES', 'kingfisher', '-kf', '', d)}"
  40
  41 python __anonymous() {
  42     for c in (d.getVar('GUEST_IMAGES') or "").split():
  43         (mc, image) = c.split(':')
  44         dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
  45         d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
  46
  47         # Assume there is a qemu-config-X package for guest image X
  48         d.appendVar('QEMU_GUEST_CONFIGS', ' ' + 'qemu-config-' + image)
  49 }
  50
  51 install_guest_images() {
  52     for c in ${GUEST_IMAGES}; do
  53         config=${c%:*}
  54         image=${c#*:}
  55         name=${image}
  56         rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
  57         install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
  58         src="${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/${image}-${GUEST_MACHINE}${MACHINE_SUFFIX}.ext4"
  59         bbnote "Installing ${src}"
  60         install -m 0600 ${src} ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  61         # Placeholder until booting from kernel in VM image is worked out
  62         install -m 0600 ${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/Image-${GUEST_MACHINE}.bin ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  63     done
  64 }
  65
  66 ROOTFS_POSTPROCESS_COMMAND += "install_guest_images; "
  67
  68 IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"