recipes-platform/images/agl-ivi-demo-control-panel.bb

   1 require recipes-platform/images/agl-image-weston.bb
   2 require agl-demo-features.inc
   3
   4 SUMMARY = "AGL demo control panel image"
   5
   6 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   7
   8 # KUKSA.val databroker is only installed with
   9 # "agl-demo-gateway-preload" feature, as it used as
  10 # a bridge to CAN output via kuksa-dbc-feeder in that
  11 # configuration.
  12 IMAGE_FEATURES += " \
  13     kuksa-val-databroker-client \
  14     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-gateway-preload", "kuksa-val-databroker", "", d)} \
  15 "
  16
  17 # NOTE: The client key and certificate in kuksa-certificates-agl-client
  18 #       seem required by kuksa-client at the moment even though client
  19 #       certification has been deprecated upstream, this needs further
  20 #       investigation so it can be dropped from the image.
  21 #
  22 IMAGE_KUKSA_PACKAGES = " \
  23     kuksa-client \
  24     kuksa-certificates-agl-ca \
  25     kuksa-certificates-agl-client \
  26 "
  27
  28 IMAGE_INSTALL += "\
  29     packagegroup-agl-networking \
  30     weston-ini-conf-landscape \
  31     weston-agl-driver-conf \
  32     ${IMAGE_KUKSA_PACKAGES} \
  33     agl-demo-control-panel \
  34     qtwayland \
  35     qtwayland-plugins \
  36     qtwayland-qmlplugins \
  37     ${@bb.utils.contains("DISTRO_FEATURES", "agl-devel", "can-test-tools" , "", d)} \
  38 "