recipes-graphics/wayland/weston-ini-conf_agldemo.inc

   1 FILESEXTRAPATHS:prepend := "${THISDIR}/weston-ini-conf:"
   2
   3 SRC_URI += "file://remote-output.cfg.in"
   4
   5 # Options for the user to change in local.conf
   6 # e.g. REMOTING_OUTPUT_MODE = "1080x1488"
   7 REMOTING_OUTPUT_MODE ??= "640x720@30"
   8 REMOTING_OUTPUT_HOST ??= "192.168.10.3"
   9 REMOTING_OUTPUT_PORT ??= "5005"
  10
  11 do_configure:append() {
  12     # Standalone cluster support version
  13     sed -e "s#host=.*#host=${REMOTING_OUTPUT_HOST}#" \
  14         -e "s#port=.*#port=${REMOTING_OUTPUT_PORT}#" \
  15         ${WORKDIR}/remote-output.cfg.in  > ${WORKDIR}/remote-output.cfg
  16 }
  17
  18 do_compile:append() {
  19     # Create remoting enabled versions of the default portrait
  20     # and landscape demo IVI configurations
  21     for c in weston.ini.default weston.ini.landscape; do
  22         cp ${WORKDIR}/$c ${WORKDIR}/${c}-remoting
  23         echo >> ${WORKDIR}/${c}-remoting
  24         cat ${WORKDIR}/remote-output.cfg >> ${WORKDIR}/${c}-remoting
  25     done
  26 }
  27
  28 do_install:append() {
  29     install -m 0644 ${WORKDIR}/weston.ini.default-remoting ${D}${weston_ini_dir}/
  30     install -m 0644 ${WORKDIR}/weston.ini.landscape-remoting ${D}${weston_ini_dir}/
  31 }
  32
  33 # remoting
  34
  35 PACKAGE_BEFORE_PN += "${PN}-remoting"
  36 FILES:${PN}-remoting = "${weston_ini_dir}/weston.ini.default-remoting"
  37 RPROVIDES:${PN}-remoting = "weston-ini"
  38 ALTERNATIVE:${PN}-remoting = "weston.ini"
  39 ALTERNATIVE_TARGET_${PN}-remoting = "${weston_ini_dir}/weston.ini.default-remoting"
  40 ALTERNATIVE_PRIORITY_${PN}-remoting = "30"
  41
  42 # landscape-remoting
  43
  44 PACKAGE_BEFORE_PN += "${PN}-landscape-remoting"
  45 FILES:${PN}-landscape-remoting = "${weston_ini_dir}/weston.ini.landscape-remoting"
  46 RPROVIDES:${PN}-landscape-remoting = "weston-ini"
  47 ALTERNATIVE:${PN}-landscape-remoting = "weston.ini"
  48 ALTERNATIVE_TARGET_${PN}-landscape-remoting = "${weston_ini_dir}/weston.ini.landscape-remoting"
  49 ALTERNATIVE_PRIORITY_${PN}-landscape-remoting = "31"