recipes-graphics/wayland/weston-ini-conf_agldemo.inc

   1 FILESEXTRAPATHS:prepend := "${THISDIR}/weston-ini-conf:"
   2
   3 SRC_URI += "file://remote-output.cfg.in"
   4
   5 WESTON_FRAGMENTS_BASE += "grpc-proxy"
   6
   7 # Options for the user to change in local.conf
   8 # e.g. REMOTING_OUTPUT_MODE = "1080x1488"
   9 REMOTING_OUTPUT_MODE ??= "640x720@30"
  10 REMOTING_OUTPUT_HOST ??= "192.168.10.3"
  11 REMOTING_OUTPUT_PORT ??= "5005"
  12
  13 do_configure:append() {
  14     # Standalone cluster support version
  15     sed -e "s#host=.*#host=${REMOTING_OUTPUT_HOST}#" \
  16         -e "s#port=.*#port=${REMOTING_OUTPUT_PORT}#" \
  17         ${WORKDIR}/remote-output.cfg.in  > ${WORKDIR}/remote-output.cfg
  18 }
  19
  20 do_compile:append() {
  21     # Create remoting enabled versions of the default portrait
  22     # and landscape demo IVI configurations
  23     for c in weston.ini.default weston.ini.landscape; do
  24         cp ${WORKDIR}/$c ${WORKDIR}/${c}-remoting
  25         echo >> ${WORKDIR}/${c}-remoting
  26         cat ${WORKDIR}/remote-output.cfg >> ${WORKDIR}/${c}-remoting
  27     done
  28 }
  29
  30 do_install:append() {
  31     install -m 0644 ${WORKDIR}/weston.ini.default-remoting ${D}${weston_ini_dir}/
  32     install -m 0644 ${WORKDIR}/weston.ini.landscape-remoting ${D}${weston_ini_dir}/
  33 }
  34
  35 # remoting
  36
  37 PACKAGE_BEFORE_PN += "${PN}-remoting"
  38 FILES:${PN}-remoting = "${weston_ini_dir}/weston.ini.default-remoting"
  39 RPROVIDES:${PN}-remoting = "weston-ini"
  40 ALTERNATIVE:${PN}-remoting = "weston.ini"
  41 ALTERNATIVE_TARGET_${PN}-remoting = "${weston_ini_dir}/weston.ini.default-remoting"
  42 ALTERNATIVE_PRIORITY_${PN}-remoting = "30"
  43
  44 # landscape-remoting
  45
  46 PACKAGE_BEFORE_PN += "${PN}-landscape-remoting"
  47 FILES:${PN}-landscape-remoting = "${weston_ini_dir}/weston.ini.landscape-remoting"
  48 RPROVIDES:${PN}-landscape-remoting = "weston-ini"
  49 ALTERNATIVE:${PN}-landscape-remoting = "weston.ini"
  50 ALTERNATIVE_TARGET_${PN}-landscape-remoting = "${weston_ini_dir}/weston.ini.landscape-remoting"
  51 ALTERNATIVE_PRIORITY_${PN}-landscape-remoting = "31"