recipes-graphics/wayland/weston-ini-conf_agldemo.inc

   1 FILESEXTRAPATHS:prepend := "${THISDIR}/weston-ini-conf:"
   2
   3 SRC_URI += " \
   4     file://remote-output.cfg.in \
   5     file://weston.ini.kvm.in \
   6 "
   7
   8 # Options for the user to change in local.conf
   9 # e.g. REMOTING_OUTPUT_MODE = "1080x1488"
  10 REMOTING_OUTPUT_MODE ??= "640x720@30"
  11 REMOTING_OUTPUT_HOST ??= "192.168.10.3"
  12 REMOTING_OUTPUT_PORT ??= "5005"
  13
  14 # Default app IDs for KVM guests
  15 GUEST_VM1_IMAGE ?= "agl-ivi-demo-flutter"
  16 GUEST_VM2_IMAGE ?= "agl-cluster-demo-flutter"
  17
  18 do_configure:append() {
  19     # Standalone cluster support version
  20     sed -e "s#host=.*#host=${REMOTING_OUTPUT_HOST}#" \
  21         -e "s#port=.*#port=${REMOTING_OUTPUT_PORT}#" \
  22         ${WORKDIR}/remote-output.cfg.in  > ${WORKDIR}/remote-output.cfg
  23
  24     # KVM guest cluster version
  25     sed -e "s#host=.*#host=172.16.10.3#" \
  26         -e "s#port=.*#port=${REMOTING_OUTPUT_PORT}#" \
  27         ${WORKDIR}/remote-output.cfg.in  > ${WORKDIR}/remote-output-kvm.cfg
  28 }
  29
  30 do_compile:append() {
  31     # Create regular and KVM remoting enabled versions of the default
  32     # portrait and landscape demo IVI configurations
  33     for c in weston.ini.default weston.ini.landscape; do
  34         cp ${WORKDIR}/$c ${WORKDIR}/${c}-remoting
  35         echo >> ${WORKDIR}/${c}-remoting
  36         cat ${WORKDIR}/remote-output.cfg >> ${WORKDIR}/${c}-remoting
  37
  38         cp ${WORKDIR}/$c ${WORKDIR}/${c}-remoting-kvm
  39         echo >> ${WORKDIR}/${c}-remoting-kvm
  40         cat ${WORKDIR}/remote-output-kvm.cfg >> ${WORKDIR}/${c}-remoting-kvm
  41     done
  42
  43     # Create a canned configuration for the a KVM host, filling in
  44     # the guest VM application ids to pin them to specific outputs.
  45     rm -f ${WORKDIR}/weston.ini.kvm
  46     sed -e "s/@GUEST_VM1_ID@/${GUEST_VM1_IMAGE}/g" \
  47         -e "s/@GUEST_VM2_ID@/${GUEST_VM2_IMAGE}/g" \
  48         ${WORKDIR}/weston.ini.kvm.in > ${WORKDIR}/weston.ini.kvm
  49 }
  50
  51 do_install:append() {
  52     install -m 0644 ${WORKDIR}/weston.ini.default-remoting ${D}${weston_ini_dir}/
  53     install -m 0644 ${WORKDIR}/weston.ini.default-remoting-kvm ${D}${weston_ini_dir}/
  54     install -m 0644 ${WORKDIR}/weston.ini.landscape-remoting ${D}${weston_ini_dir}/
  55     install -m 0644 ${WORKDIR}/weston.ini.landscape-remoting-kvm ${D}${weston_ini_dir}/
  56     install -m 0644 ${WORKDIR}/weston.ini.kvm ${D}${weston_ini_dir}/
  57 }
  58
  59 # remoting
  60
  61 PACKAGE_BEFORE_PN += "${PN}-remoting"
  62 FILES:${PN}-remoting = "${weston_ini_dir}/weston.ini.default-remoting"
  63 RPROVIDES:${PN}-remoting = "weston-ini"
  64 ALTERNATIVE:${PN}-remoting = "weston.ini"
  65 ALTERNATIVE_TARGET_${PN}-remoting = "${weston_ini_dir}/weston.ini.default-remoting"
  66 ALTERNATIVE_PRIORITY_${PN}-remoting = "30"
  67
  68 # remoting-kvm
  69
  70 PACKAGE_BEFORE_PN += "${PN}-remoting-kvm"
  71 FILES:${PN}-remoting-kvm = "${weston_ini_dir}/weston.ini.default-remoting-kvm"
  72 RPROVIDES:${PN}-remoting-kvm = "weston-ini"
  73 ALTERNATIVE:${PN}-remoting-kvm = "weston.ini"
  74 ALTERNATIVE_TARGET_${PN}-remoting-kvm = "${weston_ini_dir}/weston.ini.default-remoting-kvm"
  75 ALTERNATIVE_PRIORITY_${PN}-remoting-kvm = "35"
  76
  77 # landscape-remoting
  78
  79 PACKAGE_BEFORE_PN += "${PN}-landscape-remoting"
  80 FILES:${PN}-landscape-remoting = "${weston_ini_dir}/weston.ini.landscape-remoting"
  81 RPROVIDES:${PN}-landscape-remoting = "weston-ini"
  82 ALTERNATIVE:${PN}-landscape-remoting = "weston.ini"
  83 ALTERNATIVE_TARGET_${PN}-landscape-remoting = "${weston_ini_dir}/weston.ini.landscape-remoting"
  84 ALTERNATIVE_PRIORITY_${PN}-landscape-remoting = "31"
  85
  86 # landscape-remoting-kvm
  87
  88 PACKAGE_BEFORE_PN += "${PN}-landscape-remoting-kvm"
  89 FILES:${PN}-landscape-remoting-kvm = "${weston_ini_dir}/weston.ini.landscape-remoting-kvm"
  90 RPROVIDES:${PN}-landscape-remoting-kvm = "weston-ini"
  91 ALTERNATIVE:${PN}-landscape-remoting-kvm = "weston.ini"
  92 ALTERNATIVE_TARGET_${PN}-landscape-remoting-kvm = "${weston_ini_dir}/weston.ini.landscape-remoting-kvm"
  93 ALTERNATIVE_PRIORITY_${PN}-landscape-remoting-kvm = "36"
  94
  95 # kvm
  96
  97 PACKAGE_BEFORE_PN += "${PN}-kvm"
  98 FILES:${PN}-kvm = "${weston_ini_dir}/weston.ini.kvm"
  99 RPROVIDES:${PN}-kvm = "weston-ini"
 100 ALTERNATIVE:${PN}-kvm = "weston.ini"
 101 ALTERNATIVE_TARGET_${PN}-kvm = "${weston_ini_dir}/weston.ini.kvm"
 102 ALTERNATIVE_PRIORITY_${PN}-kvm = "40"