recipes-demo/navigation/ondemandnavi_git.bb

   1 SUMMARY     = "Navigation application."
   2 DESCRIPTION = "AGL demonstration Navigation application based on QtLocation widget."
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/ondemandnavi"
   4 SECTION     = "apps"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   8
   9 DEPENDS = "qtquickcontrols2 qtlocation libqtappfw"
  10
  11 PV = "2.0+git${SRCPV}"
  12
  13 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/ondemandnavi;protocol=https;branch=${AGL_BRANCH} \
  14            file://navigation.conf \
  15            file://navigation.conf.kvm-demo \
  16            file://navigation.conf.gateway-demo \
  17            file://navigation.token \
  18 "
  19 SRCREV = "d6b883ef6bdb63fb501b03d64c9a32bc29b7b2c7"
  20
  21 S = "${WORKDIR}/git"
  22
  23 inherit qmake5 pkgconfig agl-app update-alternatives
  24
  25 AGL_APP_ID = "navigation"
  26 AGL_APP_NAME = "Navigation"
  27
  28 do_install:append() {
  29     # Currently using default global client and CA certificates
  30     # for KUKSA.val SSL, installing app specific ones would go here.
  31
  32     # VIS authorization token file for KUKSA.val should ideally not
  33     # be readable by other users, but currently that's not doable
  34     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  35     # something like OAuth is plumbed in as an alternative.
  36     install -d ${D}${sysconfdir}/xdg/AGL/navigation
  37     install -m 0644 ${WORKDIR}/navigation.conf ${D}${sysconfdir}/xdg/AGL/navigation.conf.default
  38     install -m 0644 ${WORKDIR}/navigation.conf.kvm-demo ${D}${sysconfdir}/xdg/AGL/
  39     install -m 0644 ${WORKDIR}/navigation.conf.gateway-demo ${D}${sysconfdir}/xdg/AGL/
  40     install -m 0644 ${WORKDIR}/navigation.token ${D}${sysconfdir}/xdg/AGL/navigation/
  41 }
  42
  43 ALTERNATIVE_LINK_NAME[navigation.conf] = "${sysconfdir}/xdg/AGL/navigation.conf"
  44
  45 PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-kvm-demo ${PN}-conf-gateway-demo"
  46
  47 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/navigation.conf.default"
  48 RDEPENDS:${PN}-conf = "${PN}"
  49 RPROVIDES:${PN}-conf = "navigation.conf"
  50 ALTERNATIVE:${PN}-conf = "navigation.conf"
  51 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/navigation.conf.default"
  52
  53 FILES:${PN}-conf-gateway-demo += "${sysconfdir}/xdg/AGL/navigation.conf.gateway-demo"
  54 RDEPENDS:${PN}-conf-gateway-demo = "${PN}"
  55 RPROVIDES:${PN}-conf-gateway-demo = "navigation.conf"
  56 ALTERNATIVE:${PN}-conf-gateway-demo = "navigation.conf"
  57 ALTERNATIVE_TARGET_${PN}-conf-gateway-demo = "${sysconfdir}/xdg/AGL/navigation.conf.gateway-demo"
  58 ALTERNATIVE_PRIORITY_${PN}-conf-gateway-demo = "20"
  59
  60 FILES:${PN}-conf-kvm-demo += "${sysconfdir}/xdg/AGL/navigation.conf.kvm-demo"
  61 RDEPENDS:${PN}-conf-kvm-demo = "${PN}"
  62 RPROVIDES:${PN}-conf-kvm-demo = "navigation.conf"
  63 ALTERNATIVE:${PN}-conf-kvm-demo = "navigation.conf"
  64 ALTERNATIVE_TARGET_${PN}-conf-kvm-demo = "${sysconfdir}/xdg/AGL/navigation.conf.kvm-demo"
  65 ALTERNATIVE_PRIORITY_${PN}-conf-kvm-demo = "30"
  66
  67 RDEPENDS:${PN} += " \
  68     qtwayland \
  69     qtbase-qmlplugins \
  70     qtgraphicaleffects-qmlplugins \
  71     qtquickcontrols-qmlplugins \
  72     qtquickcontrols2-qmlplugins \
  73     qtquickcontrols2-agl \
  74     qtquickcontrols2-agl-style \
  75     qtlocation \
  76     flite \
  77     libqtappfw \
  78     openjtalk \
  79     gstreamer1.0 \
  80     ondemandnavi-config \
  81 "