recipes-demo/navigation/ondemandnavi_git.bb

   1 SUMMARY     = "Navigation application."
   2 DESCRIPTION = "AGL demonstration Navigation application based on QtLocation widget."
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/ondemandnavi"
   4 SECTION     = "apps"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   8
   9 DEPENDS = "qtquickcontrols2 qtlocation libqtappfw"
  10
  11 PV = "2.0+git${SRCPV}"
  12
  13 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/ondemandnavi;protocol=https;branch=${AGL_BRANCH} \
  14            file://navigation.conf \
  15            file://navigation.token \
  16 "
  17 SRCREV = "1a014832f3da70e413650e0eeb4f40e598feb257"
  18
  19 S = "${WORKDIR}/git"
  20
  21 inherit qmake5 pkgconfig
  22
  23 do_install:append() {
  24     # Currently using default global client and CA certificates
  25     # for KUKSA.val SSL, installing app specific ones would go here.
  26
  27     # VIS authorization token file for KUKSA.val should ideally not
  28     # be readable by other users, but currently that's not doable
  29     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  30     # something like OAuth is plumbed in as an alternative.
  31     install -d ${D}${sysconfdir}/xdg/AGL/navigation
  32     install -m 0644 ${WORKDIR}/navigation.conf ${D}${sysconfdir}/xdg/AGL/
  33     install -m 0644 ${WORKDIR}/navigation.token ${D}${sysconfdir}/xdg/AGL/navigation/
  34 }
  35
  36 # HACK: new systemd-enabled applaunchd for now relies on .desktop and DBusActivatable
  37 do_install:append() {
  38     sed -n "/^DBusActivatable=/!p" -i ${D}${datadir}/applications/navigation.desktop
  39     echo "DBusActivatable=true" >> ${D}${datadir}/applications/navigation.desktop
  40 }
  41
  42 FILES:${PN} += "${datadir}/icons/"
  43
  44 RDEPENDS:${PN} += " \
  45     qtlocation \
  46     flite \
  47     libqtappfw \
  48     openjtalk \
  49     gstreamer1.0 \
  50     ondemandnavi-config \
  51 "