recipes-demo/flutter-cluster-dashboard/flutter-cluster-dashboard_git.bb

   1 SUMMARY = "Flutter Instrument Cluster "
   2 DESCRIPTION = "An instrument cluster app written in dart for the flutter runtime"
   3 AUTHOR = "Aakash Solanki"
   4 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster"
   5
   6 SECTION = "graphics"
   7
   8 LICENSE = "Apache-2.0"
   9 LIC_FILES_CHKSUM = "file://LICENSE.md;md5=0c52b0e4b5f0dbf57ea7d44bebb2e29d"
  10
  11 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster;protocol=https;branch=${AGL_BRANCH} \
  12     file://flutter-cluster-dashboard.service \
  13     file://flutter_cluster_dashboard_on_bg.json \
  14     file://cluster-dashboard.yaml \
  15     file://cluster-dashboard.yaml.demo \
  16     file://cluster-dashboard.yaml.gateway-demo \
  17     file://cluster-dashboard.yaml.kvm-demo \
  18     file://cluster-dashboard.yaml.kvm-demo-preconfigured \
  19     file://cluster-dashboard.token \
  20     file://kvm.conf \
  21 "
  22
  23 PV = "1.0+git${SRCPV}"
  24 SRCREV = "5bd594ae8ad92e8e74966c4ad87df83ec8088c2d"
  25
  26 S = "${WORKDIR}/git"
  27
  28 PUBSPEC_APPNAME = "flutter_cluster_dashboard"
  29
  30 inherit flutter-app update-alternatives systemd
  31
  32 APP_CONFIG = "flutter_cluster_dashboard_on_bg.json"
  33
  34 SYSTEMD_SERVICE:${PN} = "flutter-cluster-dashboard.service"
  35
  36 do_install:append() {
  37     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  38
  39     install -D -m 0644 ${WORKDIR}/kvm.conf ${D}${systemd_system_unitdir}/${BPN}.service.d/kvm.conf
  40
  41     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/${BPN}.json
  42
  43     install -d ${D}${sysconfdir}/xdg/AGL/cluster-dashboard
  44     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml ${D}${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default
  45     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.demo ${D}${sysconfdir}/xdg/AGL/
  46     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.gateway-demo ${D}${sysconfdir}/xdg/AGL/
  47     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.kvm-demo ${D}${sysconfdir}/xdg/AGL/
  48     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.kvm-demo-preconfigured ${D}${sysconfdir}/xdg/AGL/
  49     install -m 0644 ${WORKDIR}/cluster-dashboard.token ${D}${sysconfdir}/xdg/AGL/cluster-dashboard/
  50 }
  51
  52 ALTERNATIVE_LINK_NAME[cluster-dashboard.yaml] = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml"
  53
  54 FILES:${PN} += "${datadir} ${sysconfdir}/xdg/AGL"
  55
  56 RDEPENDS:${PN} += "flutter-auto agl-flutter-env liberation-fonts"
  57
  58 PACKAGE_BEFORE_PN += "${PN}-conf"
  59 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  60 RDEPENDS:${PN}-conf = "${PN}"
  61 RPROVIDES:${PN}-conf = "cluster-dashboard.yaml"
  62 ALTERNATIVE:${PN}-conf = "cluster-dashboard.yaml"
  63 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  64
  65 PACKAGE_BEFORE_PN += "${PN}-conf-demo"
  66 FILES:${PN}-conf-demo += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo"
  67 RDEPENDS:${PN}-conf-demo = "${PN}"
  68 RPROVIDES:${PN}-conf-demo = "cluster-dashboard.yaml"
  69 ALTERNATIVE:${PN}-conf-demo = "cluster-dashboard.yaml"
  70 ALTERNATIVE_TARGET_${PN}-conf-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo"
  71
  72 PACKAGE_BEFORE_PN += "${PN}-conf-gateway-demo"
  73 FILES:${PN}-conf-gateway-demo += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.gateway-demo"
  74 RDEPENDS:${PN}-conf-gateway-demo = "${PN}"
  75 RPROVIDES:${PN}-conf-gateway-demo = "cluster-dashboard.yaml"
  76 ALTERNATIVE:${PN}-conf-gateway-demo = "cluster-dashboard.yaml"
  77 ALTERNATIVE_TARGET_${PN}-conf-gateway-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.gateway-demo"
  78
  79 # systemd override to add network-online.target dependency for KVM setups
  80 PACKAGE_BEFORE_PN += "${PN}-conf-kvm"
  81 FILES:${PN}-conf-kvm += "${systemd_system_unitdir}/flutter-cluster-dashboard.service.d/kvm.conf"
  82 RDEPENDS:${PN}-conf-kvm = "${PN}"
  83
  84 PACKAGE_BEFORE_PN += "${PN}-conf-kvm-demo"
  85 FILES:${PN}-conf-kvm-demo += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.kvm-demo"
  86 RDEPENDS:${PN}-conf-kvm-demo = "${PN} ${PN}-conf-kvm"
  87 RPROVIDES:${PN}-conf-kvm-demo = "cluster-dashboard.yaml"
  88 ALTERNATIVE:${PN}-conf-kvm-demo = "cluster-dashboard.yaml"
  89 ALTERNATIVE_TARGET_${PN}-conf-kvm-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.kvm-demo"
  90
  91 PACKAGE_BEFORE_PN += "${PN}-conf-kvm-demo-preconfigured"
  92 FILES:${PN}-conf-kvm-demo-preconfigured += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.kvm-demo-preconfigured"
  93 RDEPENDS:${PN}-conf-kvm-demo-preconfigured = "${PN} ${PN}-conf-kvm"
  94 RPROVIDES:${PN}-conf-kvm-demo-preconfigured = "cluster-dashboard.yaml"
  95 ALTERNATIVE:${PN}-conf-kvm-demo-preconfigured = "cluster-dashboard.yaml"
  96 ALTERNATIVE_TARGET_${PN}-conf-kvm-demo-preconfigured = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.kvm-demo-preconfigured"