recipes-demo/flutter-cluster-dashboard/flutter-cluster-dashboard_git.bb

   1 SUMMARY = "Flutter Instrument Cluster "
   2 DESCRIPTION = "An instrument cluster app written in dart for the flutter runtime"
   3 AUTHOR = "Aakash Solanki"
   4 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster"
   5
   6 SECTION = "graphics"
   7
   8 LICENSE = "Apache-2.0"
   9 LIC_FILES_CHKSUM = "file://LICENSE.md;md5=0c52b0e4b5f0dbf57ea7d44bebb2e29d"
  10
  11 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster;protocol=https;branch=${AGL_BRANCH} \
  12     file://flutter-cluster-dashboard.service \
  13     file://flutter_cluster_dashboard_on_bg.json \
  14     file://cluster-dashboard.yaml \
  15     file://cluster-dashboard.yaml.demo \
  16     file://cluster-dashboard.yaml.kvm-demo \
  17     file://cluster-dashboard.token \
  18     file://kvm.conf \
  19 "
  20
  21 PV = "1.0+git${SRCPV}"
  22 SRCREV = "5bd594ae8ad92e8e74966c4ad87df83ec8088c2d"
  23
  24 S = "${WORKDIR}/git"
  25
  26 PUBSPEC_APPNAME = "flutter_cluster_dashboard"
  27
  28 inherit flutter-app update-alternatives systemd
  29
  30 APP_CONFIG = "flutter_cluster_dashboard_on_bg.json"
  31
  32 SYSTEMD_SERVICE:${PN} = "flutter-cluster-dashboard.service"
  33
  34 do_install:append() {
  35     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  36
  37     install -D -m 0644 ${WORKDIR}/kvm.conf ${D}${systemd_system_unitdir}/${BPN}.service.d/kvm.conf
  38
  39     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/${BPN}.json
  40
  41     install -d ${D}${sysconfdir}/xdg/AGL/cluster-dashboard
  42     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml ${D}${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default
  43     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.demo ${D}${sysconfdir}/xdg/AGL/
  44     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.kvm-demo ${D}${sysconfdir}/xdg/AGL/
  45     install -m 0644 ${WORKDIR}/cluster-dashboard.token ${D}${sysconfdir}/xdg/AGL/cluster-dashboard/
  46 }
  47
  48 ALTERNATIVE_LINK_NAME[cluster-dashboard.yaml] = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml"
  49
  50 FILES:${PN} += "${datadir} ${sysconfdir}/xdg/AGL"
  51
  52 RDEPENDS:${PN} += "flutter-auto agl-flutter-env liberation-fonts"
  53
  54 PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-demo ${PN}-conf-kvm-demo"
  55
  56 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  57 RDEPENDS:${PN}-conf = "${PN}"
  58 RPROVIDES:${PN}-conf = "cluster-dashboard.yaml"
  59 RCONFLICTS:${PN}-conf = "${PN}-conf-demo"
  60 ALTERNATIVE:${PN}-conf = "cluster-dashboard.yaml"
  61 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  62
  63 FILES:${PN}-conf-demo += " \
  64     ${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo \
  65 "
  66 RDEPENDS:${PN}-conf-demo = "${PN}"
  67 RPROVIDES:${PN}-conf-demo = "cluster-dashboard.yaml"
  68 RCONFLICTS:${PN}-conf-demo = "${PN}-conf"
  69 ALTERNATIVE:${PN}-conf-demo = "cluster-dashboard.yaml"
  70 ALTERNATIVE_TARGET_${PN}-conf-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo"
  71
  72 FILES:${PN}-conf-kvm-demo += " \
  73     ${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.kvm-demo \
  74     ${systemd_system_unitdir}/flutter-cluster-dashboard.service.d/kvm.conf \
  75 "
  76 RDEPENDS:${PN}-conf-kvm-demo = "${PN}"
  77 RPROVIDES:${PN}-conf-kvm-demo = "cluster-dashboard.yaml"
  78 RCONFLICTS:${PN}-conf-kvm-demo = "${PN}-conf"
  79 ALTERNATIVE:${PN}-conf-kvm-demo = "cluster-dashboard.yaml"
  80 ALTERNATIVE_TARGET_${PN}-conf-kvm-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.kvm-demo"