recipes-demo/flutter-cluster-dashboard/flutter-cluster-dashboard_git.bb

   1 SUMMARY = "Flutter Instrument Cluster "
   2 DESCRIPTION = "An instrument cluster app written in dart for the flutter runtime"
   3 AUTHOR = "Aakash Solanki"
   4 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster"
   5
   6 SECTION = "graphics"
   7
   8 LICENSE = "Apache-2.0"
   9 LIC_FILES_CHKSUM = "file://LICENSE.md;md5=0c52b0e4b5f0dbf57ea7d44bebb2e29d"
  10
  11 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster;protocol=https;branch=${AGL_BRANCH} \
  12     file://flutter-cluster-dashboard.service \
  13     file://flutter_cluster_dashboard_on_bg.json \
  14     file://cluster-dashboard.yaml \
  15     file://cluster-dashboard.yaml.demo \
  16     file://cluster-dashboard.yaml.gateway-demo \
  17     file://cluster-dashboard.yaml.kvm-demo \
  18     file://cluster-dashboard.token \
  19     file://kvm.conf \
  20 "
  21
  22 PV = "1.0+git${SRCPV}"
  23 SRCREV = "5bd594ae8ad92e8e74966c4ad87df83ec8088c2d"
  24
  25 S = "${WORKDIR}/git"
  26
  27 PUBSPEC_APPNAME = "flutter_cluster_dashboard"
  28
  29 inherit flutter-app update-alternatives systemd
  30
  31 APP_CONFIG = "flutter_cluster_dashboard_on_bg.json"
  32
  33 SYSTEMD_SERVICE:${PN} = "flutter-cluster-dashboard.service"
  34
  35 do_install:append() {
  36     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  37
  38     install -D -m 0644 ${WORKDIR}/kvm.conf ${D}${systemd_system_unitdir}/${BPN}.service.d/kvm.conf
  39
  40     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/${BPN}.json
  41
  42     install -d ${D}${sysconfdir}/xdg/AGL/cluster-dashboard
  43     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml ${D}${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default
  44     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.demo ${D}${sysconfdir}/xdg/AGL/
  45     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.gateway-demo ${D}${sysconfdir}/xdg/AGL/
  46     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.kvm-demo ${D}${sysconfdir}/xdg/AGL/
  47     install -m 0644 ${WORKDIR}/cluster-dashboard.token ${D}${sysconfdir}/xdg/AGL/cluster-dashboard/
  48 }
  49
  50 ALTERNATIVE_LINK_NAME[cluster-dashboard.yaml] = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml"
  51
  52 FILES:${PN} += "${datadir} ${sysconfdir}/xdg/AGL"
  53
  54 RDEPENDS:${PN} += "flutter-auto agl-flutter-env liberation-fonts"
  55
  56 PACKAGE_BEFORE_PN += "${PN}-conf"
  57 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  58 RDEPENDS:${PN}-conf = "${PN}"
  59 RPROVIDES:${PN}-conf = "cluster-dashboard.yaml"
  60 ALTERNATIVE:${PN}-conf = "cluster-dashboard.yaml"
  61 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  62
  63 PACKAGE_BEFORE_PN += "${PN}-conf-demo"
  64 FILES:${PN}-conf-demo += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo"
  65 RDEPENDS:${PN}-conf-demo = "${PN}"
  66 RPROVIDES:${PN}-conf-demo = "cluster-dashboard.yaml"
  67 ALTERNATIVE:${PN}-conf-demo = "cluster-dashboard.yaml"
  68 ALTERNATIVE_TARGET_${PN}-conf-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo"
  69
  70 PACKAGE_BEFORE_PN += "${PN}-conf-gateway-demo"
  71 FILES:${PN}-conf-gateway-demo += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.gateway-demo"
  72 RDEPENDS:${PN}-conf-gateway-demo = "${PN}"
  73 RPROVIDES:${PN}-conf-gateway-demo = "cluster-dashboard.yaml"
  74 ALTERNATIVE:${PN}-conf-gateway-demo = "cluster-dashboard.yaml"
  75 ALTERNATIVE_TARGET_${PN}-conf-gateway-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.gateway-demo"
  76
  77 # systemd override to add network-online.target dependency for KVM setups
  78 PACKAGE_BEFORE_PN += "${PN}-conf-kvm"
  79 FILES:${PN}-conf-kvm += "${systemd_system_unitdir}/flutter-cluster-dashboard.service.d/kvm.conf"
  80 RDEPENDS:${PN}-conf-kvm = "${PN}"
  81
  82 PACKAGE_BEFORE_PN += "${PN}-conf-kvm-demo"
  83 FILES:${PN}-conf-kvm-demo += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.kvm-demo"
  84 RDEPENDS:${PN}-conf-kvm-demo = "${PN} ${PN}-conf-kvm"
  85 RPROVIDES:${PN}-conf-kvm-demo = "cluster-dashboard.yaml"
  86 ALTERNATIVE:${PN}-conf-kvm-demo = "cluster-dashboard.yaml"
  87 ALTERNATIVE_TARGET_${PN}-conf-kvm-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.kvm-demo"