recipes-demo/agl-service-hvac/agl-service-hvac_git.bb

   1 SUMMARY     = "Demo HVAC Service Daemon"
   2 DESCRIPTION = "Demo HVAC Service Daemon"
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-service-hvac"
   4
   5 LICENSE     = "Apache-2.0"
   6 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   7
   8 DEPENDS = " \
   9     glib-2.0 \
  10     boost \
  11     openssl \
  12     systemd \
  13     protobuf-native \
  14     grpc-native \
  15     protobuf \
  16     grpc \
  17     kuksa-databroker \
  18 "
  19
  20 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-service-hvac;protocol=https;branch=${AGL_BRANCH} \
  21            file://agl-service-hvac.conf.default \
  22            file://agl-service-hvac.conf.gateway-demo \
  23            file://agl-service-hvac.token \
  24 "
  25 SRCREV  = "1f55937667e35fb79dabee0e180787e34a59169a"
  26
  27 PV = "2.0+git${SRCPV}"
  28 S  = "${WORKDIR}/git"
  29
  30 inherit meson pkgconfig systemd update-alternatives
  31
  32 EXTRA_OEMESON += "-Dprotos=${STAGING_INCDIR}"
  33
  34 SYSTEMD_SERVICE:${PN} = "agl-service-hvac.service"
  35
  36 do_install:append() {
  37     # Currently using default global client and CA certificates
  38     # for KUKSA.val SSL, installing app specific ones would go here.
  39
  40     # VIS authorization token file for KUKSA.val should ideally not
  41     # be readable by other users, but currently that's not doable
  42     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  43     # something like OAuth is plumbed in as an alternative.
  44     install -d ${D}${sysconfdir}/xdg/AGL/agl-service-hvac
  45     install -m 0644 ${WORKDIR}/agl-service-hvac.conf.default ${D}${sysconfdir}/xdg/AGL/
  46     install -m 0644 ${WORKDIR}/agl-service-hvac.conf.gateway-demo ${D}${sysconfdir}/xdg/AGL/
  47     install -m 0644 ${WORKDIR}/agl-service-hvac.token ${D}${sysconfdir}/xdg/AGL/agl-service-hvac/
  48 }
  49
  50 FILES:${PN} += "${systemd_system_unitdir}"
  51
  52 RDEPENDS:${PN} += "${PN}-conf"
  53
  54 ALTERNATIVE_LINK_NAME[agl-service-hvac.conf] = "${sysconfdir}/xdg/AGL/agl-service-hvac.conf"
  55
  56 PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-gateway-demo"
  57
  58 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/agl-service-hvac.conf.default"
  59 RDEPENDS:${PN}-conf = "${PN}"
  60 RPROVIDES:${PN}-conf = "agl-service-hvac.conf"
  61 ALTERNATIVE:${PN}-conf = "agl-service-hvac.conf"
  62 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/agl-service-hvac.conf.default"
  63
  64 FILES:${PN}-conf-gateway-demo += "${sysconfdir}/xdg/AGL/agl-service-hvac.conf.gateway-demo"
  65 RDEPENDS:${PN}-conf-gateway-demo = "${PN}"
  66 RPROVIDES:${PN}-conf-gateway-demo = "agl-service-hvac.conf"
  67 ALTERNATIVE:${PN}-conf-gateway-demo = "agl-service-hvac.conf"
  68 ALTERNATIVE_TARGET_${PN}-conf-gateway-demo = "${sysconfdir}/xdg/AGL/agl-service-hvac.conf.gateway-demo"
  69 ALTERNATIVE_PRIORITY_${PN}-conf-gateway-demo = "20"
  70