recipes-connectivity/vss/vss-agl_4.0.bb

   1 SUMMARY = "Vehicle Signal Specification with AGL overlays"
   2 LICENSE = "MPL-2.0"
   3 LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
   4
   5 DEPENDS = "vss-tools-native"
   6
   7 inherit allarch update-alternatives
   8
   9 require vss.inc
  10
  11 SRC_URI += "file://agl_vss_overlay.vspec \
  12             file://agl_vss_overlay.vspec.control-panel \
  13             file://agl_vss_overlay.vspec.gw-control-panel \
  14             file://agl_vss_overlay.vspec.gw-hardware \
  15 "
  16 # Since we're not relying on the simple upstream repo Makefile, use
  17 # best practices and output into a separate directory.
  18 B = "${WORKDIR}/build"
  19
  20 do_configure[noexec] = "1"
  21
  22 #VSPEC2JSON_OPTS = "-e dbc2vss,vss2dbc -o ${WORKDIR}/agl_vss_overlay.vspec --no-uuid --json-pretty"
  23 VSPEC2JSON_OPTS = "-e dbc2vss,vss2dbc --no-uuid --json-pretty"
  24
  25 do_compile() {
  26     vspec2json.py -I ${S}/spec ${VSPEC2JSON_OPTS} -o ${WORKDIR}/agl_vss_overlay.vspec -u ${S}/spec/units.yaml ${S}/spec/VehicleSignalSpecification.vspec vss_rel_${PV}-agl.json
  27     vspec2json.py -I ${S}/spec ${VSPEC2JSON_OPTS} -o ${WORKDIR}/agl_vss_overlay.vspec.control-panel -u ${S}/spec/units.yaml ${S}/spec/VehicleSignalSpecification.vspec vss_rel_${PV}-agl-control-panel.json
  28     vspec2json.py -I ${S}/spec ${VSPEC2JSON_OPTS} -o ${WORKDIR}/agl_vss_overlay.vspec.gw-control-panel -u ${S}/spec/units.yaml ${S}/spec/VehicleSignalSpecification.vspec vss_rel_${PV}-agl-gw-control-panel.json
  29     vspec2json.py -I ${S}/spec ${VSPEC2JSON_OPTS} -o ${WORKDIR}/agl_vss_overlay.vspec.gw-hardware -u ${S}/spec/units.yaml ${S}/spec/VehicleSignalSpecification.vspec vss_rel_${PV}-agl-gw-hardware.json
  30 }
  31
  32 do_install() {
  33     install -d ${D}${datadir}/vss
  34     install -m 0644 vss_rel_${PV}-agl.json ${D}${datadir}/vss/
  35     install -m 0644 vss_rel_${PV}-agl-control-panel.json ${D}${datadir}/vss/
  36     install -m 0644 vss_rel_${PV}-agl-gw-control-panel.json ${D}${datadir}/vss/
  37     install -m 0644 vss_rel_${PV}-agl-gw-hardware.json ${D}${datadir}/vss/
  38 }
  39
  40 PACKAGE_BEFORE_PN += "${PN}-control-panel ${PN}-gw-control-panel ${PN}-gw-hardware"
  41
  42 ALTERNATIVE_LINK_NAME[vss.json] = "${datadir}/vss/vss.json"
  43
  44 ALTERNATIVE:${PN} = "vss.json"
  45 ALTERNATIVE_TARGET_${PN} = "${datadir}/vss/vss_rel_${PV}-agl.json"
  46 ALTERNATIVE_PRIORITY_${PN} = "20"
  47 FILES:${PN} += "${datadir}/vss/vss_rel_${PV}-agl.json"
  48
  49 ALTERNATIVE:${PN}-control-panel = "vss.json"
  50 ALTERNATIVE_TARGET_${PN}-control-panel = "${datadir}/vss/vss_rel_${PV}-agl-control-panel.json"
  51 ALTERNATIVE_PRIORITY_${PN}-control-panel = "30"
  52 FILES:${PN}-control-panel += "${datadir}/vss/vss_rel_${PV}-agl-control-panel.json"
  53
  54 ALTERNATIVE:${PN}-gw-hardware = "vss.json"
  55 ALTERNATIVE_TARGET_${PN}-gw-hardware = "${datadir}/vss/vss_rel_${PV}-agl-gw-hardware.json"
  56 ALTERNATIVE_PRIORITY_${PN}-gw-hardware = "31"
  57 FILES:${PN}-gw-hardware += "${datadir}/vss/vss_rel_${PV}-agl-gw-hardware.json"
  58
  59 # Higher priority than gw-hardware, as we want it to be the default
  60 # if both are installed (as is the case with the full gateway demo
  61 # setup).
  62 ALTERNATIVE:${PN}-gw-control-panel = "vss.json"
  63 ALTERNATIVE_TARGET_${PN}-gw-control-panel = "${datadir}/vss/vss_rel_${PV}-agl-gw-control-panel.json"
  64 ALTERNATIVE_PRIORITY_${PN}-gw-control-panel = "32"
  65 FILES:${PN}-gw-control-panel += "${datadir}/vss/vss_rel_${PV}-agl-gw-control-panel.json"