recipes-connectivity/kuksa-val/kuksa-dbc-feeder-sllin.bb

   1 SUMMARY = "Demo LIN configuration for DBC feeder for KUKSA.val"
   2 HOMEPAGE = "https://github.com/eclipse/kuksa.val"
   3 BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
   4
   5 LICENSE = "MIT"
   6 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
   7
   8 SRC_URI += "file://config-sllin.ini \
   9             file://kuksa-dbc-feeder-sllin.service \
  10 "
  11
  12 inherit allarch systemd
  13
  14 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
  15
  16 do_install() {
  17     # NOTE: Installing into same /etc directory as the main configuration for now,
  18     #       this may be worth re-evaluating at some point (e.g. splitting the DBC
  19     #       files, having a dedicated token, etc.).
  20     install -d ${D}${sysconfdir}/kuksa-dbc-feeder
  21     install -m 0644 ${WORKDIR}/config-sllin.ini ${D}${sysconfdir}/kuksa-dbc-feeder/
  22     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  23         install -d ${D}${systemd_system_unitdir}
  24         install -m 0644 ${WORKDIR}/kuksa-dbc-feeder-sllin.service ${D}${systemd_system_unitdir}
  25     fi
  26 }
  27
  28 FILES:${PN} += "${systemd_system_unitdir}"
  29
  30 RDEPENDS:${PN} += " \
  31     kuksa-dbc-feeder \
  32     can-dev-helper \
  33     sllin-demo \
  34 "