recipes-connectivity/kuksa-val/kuksa-databroker_git.bb

   1 SUMMARY = "KUKSA.val databroker, the KUKSA Vehicle Abstraction Layer"
   2 #DESCRIPTION = "KUKSA.val provides a COVESA VSS data model describing data in a vehicle."
   3 HOMEPAGE = "https://github.com/eclipse/kuksa.val"
   4 BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327 \
   8 "
   9
  10 DEPENDS = "protobuf-native grpc-native"
  11
  12 PV = "0.4.5+git${SRCPV}"
  13
  14 SRC_URI = "git://github.com/eclipse-kuksa/kuksa-databroker.git;protocol=https;branch=main \
  15            file://0001-Remove-protobuf-src-usage.patch \
  16            file://kuksa-databroker.service \
  17 "
  18 SRCREV = "8eb7d1a36ccdbec18f742bcecddf8691cb57df46"
  19
  20 require ${BPN}-crates.inc
  21
  22 S = "${WORKDIR}/git"
  23
  24 inherit cargo cargo-update-recipe-crates systemd useradd
  25
  26 # Enable optional VISS support for potential use by e.g. the web apps
  27 CARGO_BUILD_FLAGS += "--features viss"
  28
  29 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
  30
  31 USERADD_PACKAGES = "${PN}"
  32 USERADDEXTENSION = "useradd-staticids"
  33 GROUPADD_PARAM:${PN} = "-g 900 kuksa ;"
  34 USERADD_PARAM:${PN} = "--system -g 900 -u 900 -o -d / --shell /bin/nologin kuksa ;"
  35
  36 do_install:append() {
  37     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  38         install -d ${D}${systemd_system_unitdir}
  39         install -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}
  40     fi
  41
  42     # Install gRPC API protobuf files
  43     install -d ${D}${includedir}
  44     cp -dr ${S}/proto/* ${D}${includedir}/
  45 }
  46
  47 PACKAGE_BEFORE_PN += "${PN}-cli"
  48
  49 FILES:${PN} += "${systemd_system_unitdir} ${datadir}"
  50
  51 FILES:${PN}-cli = "${bindir}/databroker-cli"
  52
  53 # The upstream Cargo.toml builds optimized and stripped binaries, for
  54 # now disable the QA check as opposed to tweaking the configuration.
  55 INSANE_SKIP:${PN} = "already-stripped"
  56 INSANE_SKIP:${PN}-cli = "already-stripped"