recipes-connectivity/agl-vss-proxy/agl-vss-proxy_git.bb

   1 SUMMARY     = "AGL VSS Proxy"
   2 DESCRIPTION = "AGL VSS Proxy"
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-vss-proxy"
   4
   5 LICENSE     = "Apache-2.0"
   6 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   7
   8 DEPENDS = " \
   9     glib-2.0 \
  10     yaml-cpp \
  11     protobuf-native \
  12     grpc-native \
  13     protobuf \
  14     grpc \
  15     kuksa-databroker \
  16     mosquitto \
  17 "
  18
  19 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/agl-vss-proxy;protocol=https;branch=${AGL_BRANCH} \
  20            file://agl-vss-proxy.token \
  21 "
  22 SRCREV  = "e437300d0b5c20114ea1843dbf00815304af3f27"
  23
  24 PV = "1.0+git${SRCPV}"
  25 S  = "${WORKDIR}/git"
  26
  27 inherit meson pkgconfig systemd
  28
  29 EXTRA_OEMESON += "-Dprotos=${STAGING_INCDIR}"
  30
  31 SYSTEMD_SERVICE:${PN} = "agl-vss-proxy.service"
  32
  33 do_install:append() {
  34     # Currently using default global client and CA certificates
  35     # for KUKSA.val SSL, installing app specific ones would go here.
  36
  37     # VIS authorization token file for KUKSA.val should ideally not
  38     # be readable by other users, but currently that's not doable
  39     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  40     # something like OAuth is plumbed in as an alternative.
  41     install -d ${D}${sysconfdir}/agl-vss-proxy
  42     install -m 0644 ${WORKDIR}/agl-vss-proxy.token ${D}${sysconfdir}/agl-vss-proxy/
  43 }
  44
  45 FILES:${PN} += "${systemd_system_unitdir}"
  46
  47 RDEPENDS:${PN} += "kuksa-databroker kuksa-databroker-agl"