meta-uhmi/meta-rvgpu/recipes-graphics/mesa-virtio/mesa-virtio_18.2.0.bb

   1 # This recipe temporarily install mesa-18.2.0 as mesa-virtio to run remote-virtio-gpu.
   2 # The mesa-virtio will be removed after remote-virtio-gpu supports upstream mesa.
   3
   4 SUMMARY = "Mesa library"
   5 SECTION = "graphics"
   6
   7 LICENSE = "MIT"
   8 LIC_FILES_CHKSUM = "file://docs/license.html;md5=725f991a1cc322aa7a0cd3a2016621c4"
   9
  10 DEPENDS = "expat makedepend-native flex-native bison-native libxml2-native zlib chrpath-replacement-native"
  11 DEPENDS:append = " libdrm wayland wayland-native wayland-protocols python3-native"
  12
  13 RDEPENDS:${PN}:append = " libgcc wayland libdrm glibc libstdc++ zlib expat"
  14
  15 LINUX_MAJOR = "${@(d.getVar('PREFERRED_VERSION_linux-yocto') or "x.y").split('.')[0]}"
  16 LINUX_MINOR = "${@(d.getVar('PREFERRED_VERSION_linux-yocto') or "x.y").split('.')[1].split('%')[0]}"
  17
  18 SRC_URI = "https://mesa.freedesktop.org/archive/mesa-${PV}.tar.xz \
  19     file://0001-glBufferData-Update-resource-backing-memory.patch \
  20     file://0001-Use-wayland-scanner-in-the-path.patch \
  21     file://0002-mesa-virtio-Fix-missing-wayland-egl-backend-build-error.patch \
  22     file://0001-add-stride-status-to-virtgpu-3d-transfer-to-host-linux-${LINUX_MAJOR}-${LINUX_MINOR}.patch \
  23     file://0001-Enable-using-python3.patch \
  24 "
  25
  26 SRC_URI[md5sum] = "88e1a7f31f259cec69bb76b3cb10c956"
  27 SRC_URI[sha256sum] = "22452bdffff8e11bf4284278155a9f77cb28d6d73a12c507f1490732d0d9ddce"
  28
  29 S = "${WORKDIR}/mesa-${PV}"
  30
  31 inherit autotools pkgconfig gettext
  32
  33 EXTRA_OEMAKE += "WAYLAND_PROTOCOLS_DATADIR=${STAGING_DATADIR}/wayland-protocols"
  34
  35 EXTRA_OECONF = " \
  36     --prefix=/usr/lib/mesa-virtio \
  37     --exec_prefix=/usr/lib/mesa-virtio \
  38     --libdir=/usr/lib/mesa-virtio \
  39     --includedir=/usr/include/mesa-virtio \
  40     --sysconfdir=/etc/mesa-virtio \
  41     --datadir=/usr/share/mesa-virtio \
  42 "
  43
  44 EXTRA_OECONF:append = " \
  45     --with-dri-drivers=swrast \
  46     --with-gallium-drivers=swrast,virgl \
  47     --with-platforms=drm,wayland \
  48     --disable-glx \
  49     --disable-dri3 \
  50 "
  51
  52 EXCLUDE_FROM_SHLIBS = "1"
  53
  54 FILES:${PN} = " \
  55     /usr/lib/mesa-virtio/* \
  56     /etc/mesa-virtio/drirc \
  57     /usr/share/mesa-virtio/* \
  58 "
  59
  60 FILES:${PN}-dev += " \
  61     /usr/lib/mesa-virtio/libglapi.so \
  62     /usr/lib/mesa-virtio/libEGL.so \
  63     /usr/lib/mesa-virtio/libgbm.so \
  64     /usr/lib/mesa-virtio/libGLESv2.so \
  65     /usr/lib/mesa-virtio/libGLESv1_CM.so \
  66 "