meta-speech-framework/meta-aac/recipes-apis/alexa-voiceagent-service/alexa-voiceagent-service_git.bb

   1 SUMMARY = "Alexa voice agent binding"
   2 DESCRIPTION = "alexa-voiceagent-service is an Alexa Auto SDK based voiceagent binding"
   3 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/agl-service-voice-high"
   4 SECTION = "apps"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://License.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
   8
   9 DEPENDS = " \
  10         libafb-helpers \
  11         libappcontroller \
  12         avs-device-sdk \
  13         aac-module-core \
  14         aac-module-alexa \
  15         aac-module-cbl \
  16         aac-module-contact-uploader \
  17         aac-module-navigation \
  18         aac-module-phone-control \
  19         aac-module-gstreamer \
  20         ${@bb.utils.contains("ALEXA_WAKEWORD", "true", "aac-module-amazonlite pryon-lite", "", d)} \
  21 "
  22
  23 SRC_URI = "git://github.com/alexa/alexa-auto-sdk.git;protocol=https;branch=2.0 \
  24            file://alexa.json \
  25            file://0001-remove-library-dependency-copying.patch \
  26            file://0002-update-config.xml.in.patch \
  27            file://0003-update-audio-device-configuration.patch \
  28            file://0004-update-config-and-database-paths.patch \
  29            file://0005-fix-segmentation-fault-for-release-build-mode.patch \
  30            file://0006-fix-event-argument-json.patch \
  31            file://0007-add-autobuild-scripts.patch \
  32 "
  33 SRCREV = "86916d2d8c1702a8be3c88a9012ca56583bcc0c8"
  34
  35 PV = "2.0+git${SRCPV}"
  36 S = "${WORKDIR}/git/platforms/agl/alexa-voiceagent-service"
  37
  38 inherit cmake aglwgt
  39
  40 EXTRA_OECMAKE += "-DAAC_HOME=${RECIPE_SYSROOT}/${AAC_PREFIX}"
  41
  42 ALEXA_WAKEWORD ??= "false"
  43
  44 do_install_append() {
  45     install -D -m 0644 ${WORKDIR}/alexa.json ${D}${sysconfdir}/xdg/AGL/voiceagents/alexa.json
  46 }
  47
  48 PACKAGES =+ "${PN}-conf"
  49
  50 FILES_${PN}-conf = "${sysconfdir}/xdg/AGL/voiceagents/*"
  51
  52 # NOTE: curl and opus are from the base SDK libraries, sqlite3 from the
  53 #       core module
  54 RDEPENDS_${PN} += " \
  55         libcurl \
  56         libopus \
  57         libsqlite3 \
  58         ${PN}-conf \
  59         ${@bb.utils.contains("ALEXA_WAKEWORD", "true", "pryon-lite", "", d)} \
  60         gstreamer1.0-plugins-bad-hls \
  61 "