meta-security/recipes-security/libcap-ng/libcap-ng_0.7.3.bb

   1 SUMMARY = "An alternate posix capabilities library"
   2 DESCRIPTION = "The libcap-ng library is intended to make programming \
   3 with POSIX capabilities much easier than the traditional libcap library."
   4 HOMEPAGE = "http://freecode.com/projects/libcap-ng"
   5 SECTION = "base"
   6 LICENSE = "GPLv2+ & LGPLv2.1+"
   7 LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
   8                     file://COPYING.LIB;md5=e3eda01d9815f8d24aae2dbd89b68b06"
   9
  10 SRC_URI = "http://people.redhat.com/sgrubb/libcap-ng/libcap-ng-${PV}.tar.gz \
  11            file://python.patch \
  12            file://CVE-2014-3215.patch \
  13           "
  14
  15 inherit lib_package autotools pythonnative
  16
  17 SRC_URI[md5sum] = "610afb774f80a8032b711281df126283"
  18 SRC_URI[sha256sum] = "5ca441c8d3a1e4cfe8a8151907977662679457311ccaa7eaac91447c33a35bb1"
  19
  20 DEPENDS += "swig-native python"
  21
  22 EXTRA_OEMAKE += "PYLIBVER='python${PYTHON_BASEVERSION}' PYINC='${STAGING_INCDIR}/${PYLIBVER}'"
  23
  24 PACKAGES += "${PN}-python"
  25
  26 FILES_${PN}-dbg += "${libdir}/python${PYTHON_BASEVERSION}/*/.debug"
  27 FILES_${PN}-python = "${libdir}/python${PYTHON_BASEVERSION}"
  28
  29 BBCLASSEXTEND = "native"
  30
  31 do_install_append() {
  32         # Moving libcap-ng to base_libdir
  33         if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then
  34                 mkdir -p ${D}/${base_libdir}/
  35                 mv -f ${D}${libdir}/libcap-ng.so.* ${D}${base_libdir}/
  36                 relpath=${@os.path.relpath("${base_libdir}", "${libdir}")}
  37                 ln -sf ${relpath}/libcap-ng.so.0.0.0 ${D}${libdir}/libcap-ng.so
  38         fi
  39 }