meta-security/recipes-security/keyutils/keyutils_1.5.8.bb

   1 SUMMARY = "Linux Key Management Utilities"
   2 DESCRIPTION = "Keyutils is a set of utilities for managing the key retention \
   3 facility in the kernel, which can be used by filesystems, block devices and \
   4 more to gain and retain the authorization and encryption keys required to \
   5 perform secure operations."
   6 SECTION = "base"
   7 LICENSE = "GPLv2"
   8 LIC_FILES_CHKSUM = "file://LICENCE.GPL;md5=5f6e72824f5da505c1f4a7197f004b45"
   9
  10 PR = "r1"
  11
  12 SRCREV = "dd64114721edca5808872190e7e2e927ee2e994c"
  13
  14 SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/dhowells/keyutils.git;protocol=git \
  15           file://keyutils_fix_library_install.patch \
  16           "
  17 SRC_URI_append_arm = " file://keyutils-arm-remove-m32-m64.patch"
  18 SRC_URI_append_x86 = " file://keyutils_fix_x86_cflags.patch"
  19 SRC_URI_append_x86-64 = " file://keyutils_fix_x86-64_cflags.patch"
  20
  21 S = "${WORKDIR}/git"
  22
  23 INSTALL_FLAGS = " \
  24 BINDIR=${bindir} \
  25 SBINDIR=${sbindir} \
  26 INCLUDEDIR=${includedir} \
  27 ETCDIR=${sysconfdir} \
  28 LIBDIR=${libdir} \
  29 USRLIBDIR=${libdir} \
  30 SHAREDIR=${datadir} \
  31 MAN1=${mandir}/man1 \
  32 MAN3=${mandir}/man3 \
  33 MAN5=${mandir}/man5 \
  34 MAN8=${mandir}/man8 \
  35 DESTDIR=${D}"
  36
  37 do_install() {
  38     cd ${S} && oe_runmake ${INSTALL_FLAGS} install
  39
  40     # Debugging script of unknown value, not packaged.
  41     rm -f "${D}${datadir}/request-key-debug.sh"
  42 }
  43
  44 BBCLASSEXTEND = "native"