meta-security/recipes-security/audit/audit_2.3.2.bb

   1 SUMMARY = "User space tools for kernel auditing"
   2 DESCRIPTION = "The audit package contains the user space utilities for \
   3 storing and searching the audit records generated by the audit subsystem \
   4 in the Linux kernel."
   5 HOMEPAGE = "http://people.redhat.com/sgrubb/audit/"
   6 SECTION = "base"
   7 PR = "r8"
   8 LICENSE = "GPLv2+ & LGPLv2+"
   9 LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
  10
  11 SRC_URI = "http://people.redhat.com/sgrubb/audit/audit-${PV}.tar.gz \
  12            file://disable-ldap.patch \
  13            file://audit-python.patch \
  14            file://audit-python-configure.patch \
  15            file://audit-for-cross-compiling.patch \
  16            file://auditd \
  17            file://fix-swig-host-contamination.patch \
  18            file://auditd.service \
  19            file://audit-volatile.conf \
  20 "
  21 SRC_URI_append_arm = "file://add-system-call-table-for-ARM.patch"
  22
  23 inherit autotools pythonnative update-rc.d systemd
  24
  25 UPDATERCPN = "auditd"
  26 INITSCRIPT_NAME = "auditd"
  27 INITSCRIPT_PARAMS = "defaults"
  28
  29 SYSTEMD_SERVICE_${PN} = "auditd.service"
  30
  31 SRC_URI[md5sum] = "4e8d065b5cc16b77b9b61e93a9ed160e"
  32 SRC_URI[sha256sum] = "8872e0b5392888789061db8034164305ef0e1b34543e1e7004d275f039081d29"
  33
  34 DEPENDS += "python tcp-wrappers libcap-ng linux-libc-headers (>= 2.6.30)"
  35
  36 EXTRA_OECONF += "--without-prelude \
  37         --with-libwrap \
  38         --enable-gssapi-krb5=no \
  39         --without-ldap \
  40         --with-libcap-ng=yes \
  41         --with-python=yes \
  42         --libdir=${base_libdir} \
  43         --sbindir=${base_sbindir} \
  44         "
  45 EXTRA_OECONF_append_arm = " --with-armeb=yes"
  46
  47 EXTRA_OEMAKE += "PYLIBVER='python${PYTHON_BASEVERSION}' \
  48         PYINC='${STAGING_INCDIR}/$(PYLIBVER)' \
  49         pyexecdir=${libdir}/python${PYTHON_BASEVERSION}/site-packages \
  50         STDINC='${STAGING_INCDIR}' \
  51         "
  52
  53 SUMMARY_audispd-plugins = "Plugins for the audit event dispatcher"
  54 DESCRIPTION_audispd-plugins = "The audispd-plugins package provides plugins for the real-time \
  55 interface to the audit system, audispd. These plugins can do things \
  56 like relay events to remote machines or analyze events for suspicious \
  57 behavior."
  58
  59 PACKAGES =+ "audispd-plugins"
  60 PACKAGES += "auditd ${PN}-python"
  61
  62 FILES_${PN} = "${sysconfdir}/libaudit.conf ${base_libdir}/libaudit.so.1* ${base_libdir}/libauparse.so.*"
  63 FILES_auditd += "${bindir}/* ${base_sbindir}/* ${sysconfdir}/*"
  64 FILES_audispd-plugins += "${sysconfdir}/audisp/audisp-remote.conf \
  65         ${sysconfdir}/audisp/plugins.d/au-remote.conf \
  66         ${sbindir}/audisp-remote ${localstatedir}/spool/audit \
  67         "
  68 FILES_${PN}-dbg += "${libdir}/python${PYTHON_BASEVERSION}/*/.debug"
  69 FILES_${PN}-python = "${libdir}/python${PYTHON_BASEVERSION}"
  70 FILES_${PN}-dev += "${base_libdir}/*.so ${base_libdir}/*.la"
  71
  72 CONFFILES_auditd += "${sysconfdir}/audit/audit.rules"
  73 RDEPENDS_auditd += "bash"
  74
  75 do_install_append() {
  76         rm -f ${D}/${libdir}/python${PYTHON_BASEVERSION}/site-packages/*.a
  77         rm -f ${D}/${libdir}/python${PYTHON_BASEVERSION}/site-packages/*.la
  78
  79         # reuse auditd config
  80         [ ! -e ${D}/etc/default ] && mkdir ${D}/etc/default
  81         mv ${D}/etc/sysconfig/auditd ${D}/etc/default
  82         rmdir ${D}/etc/sysconfig/
  83
  84         # replace init.d
  85         install -D -m 0755 ${S}/../auditd ${D}/etc/init.d/auditd
  86         rm -rf ${D}/etc/rc.d
  87
  88         if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  89                 install -d ${D}${sysconfdir}/tmpfiles.d/
  90                 install -m 0644 ${WORKDIR}/audit-volatile.conf ${D}${sysconfdir}/tmpfiles.d/
  91         fi
  92
  93         # install systemd unit files
  94         install -d ${D}${systemd_unitdir}/system
  95         install -m 0644 ${WORKDIR}/auditd.service ${D}${systemd_unitdir}/system
  96
  97         chmod 750 ${D}/etc/audit ${D}/etc/audit/rules.d
  98         chmod 640 ${D}/etc/audit/auditd.conf ${D}/etc/audit/rules.d/audit.rules
  99
 100         # Based on the audit.spec "Copy default rules into place on new installation"
 101         cp ${D}/etc/audit/rules.d/audit.rules ${D}/etc/audit/audit.rules
 102 }