meta-security/recipes-devtools/e2fsprogs/e2fsprogs_git.bb

   1 COREDIR = "${COREBASE}/meta/recipes-devtools/e2fsprogs"
   2
   3 # This recipe is a copy of a e2fsprogs 1.42.99+1.43 from OE-core master and
   4 # only meant to be used when the current OE-core does not have that version yet.
   5 python () {
   6     import os
   7     upstream = os.path.join(d.getVar('COREDIR', True), 'e2fsprogs_1.42.9.bb')
   8     if not os.path.exists(upstream):
   9         raise bb.parse.SkipRecipe("This recipe replaces e2fsprogs 1.42.9 in OE-core. e2fsprogs from OE-core is something else and thus either recent enough to have xattr support or (less likely) something unexpected.")
  10 }
  11
  12
  13 require e2fsprogs.inc
  14
  15 SRC_URI += "file://acinclude.m4 \
  16             file://remove.ldconfig.call.patch \
  17             file://quiet-debugfs.patch \
  18             file://run-ptest \
  19             file://ptest.patch \
  20             file://mkdir.patch \
  21 "
  22
  23 SRCREV = "0f26747167cc9d82df849b0aad387bf824f04544"
  24 PV = "1.42.99+1.43+git${SRCPV}"
  25 UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+\.\d+(\.\d+)*)$"
  26
  27 EXTRA_OECONF += "--libdir=${base_libdir} --sbindir=${base_sbindir} \
  28                 --enable-elf-shlibs --disable-libuuid --disable-uuidd \
  29                 --disable-libblkid --enable-verbose-makecmds"
  30
  31 EXTRA_OECONF_darwin = "--libdir=${base_libdir} --sbindir=${base_sbindir} --enable-bsd-shlibs"
  32
  33 PACKAGECONFIG ??= ""
  34 PACKAGECONFIG[fuse] = '--enable-fuse2fs,--disable-fuse2fs,fuse'
  35
  36 do_configure_prepend () {
  37         cp ${WORKDIR}/acinclude.m4 ${S}/
  38 }
  39
  40 do_install () {
  41         oe_runmake 'DESTDIR=${D}' install
  42         oe_runmake 'DESTDIR=${D}' install-libs
  43         # We use blkid from util-linux now so remove from here
  44         rm -f ${D}${base_libdir}/libblkid*
  45         rm -rf ${D}${includedir}/blkid
  46         rm -f ${D}${base_libdir}/pkgconfig/blkid.pc
  47         rm -f ${D}${base_sbindir}/blkid
  48         rm -f ${D}${base_sbindir}/fsck
  49         rm -f ${D}${base_sbindir}/findfs
  50
  51         # e2initrd_helper and the pkgconfig files belong in libdir
  52         if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then
  53                 install -d ${D}${libdir}
  54                 mv ${D}${base_libdir}/e2initrd_helper ${D}${libdir}
  55                 mv ${D}${base_libdir}/pkgconfig ${D}${libdir}
  56         fi
  57
  58         oe_multilib_header ext2fs/ext2_types.h
  59         install -d ${D}${base_bindir}
  60         mv ${D}${bindir}/chattr ${D}${base_bindir}/chattr.e2fsprogs
  61
  62         install -v -m 755 ${S}/contrib/populate-extfs.sh ${D}${base_sbindir}/
  63 }
  64
  65 do_install_append_class-target() {
  66         # Clean host path in compile_et, mk_cmds
  67         sed -i -e "s,ET_DIR=\"${S}/lib/et\",ET_DIR=\"${datadir}/et\",g" ${D}${bindir}/compile_et
  68         sed -i -e "s,SS_DIR=\"${S}/lib/ss\",SS_DIR=\"${datadir}/ss\",g" ${D}${bindir}/mk_cmds
  69 }
  70
  71 RDEPENDS_e2fsprogs = "e2fsprogs-badblocks"
  72 RRECOMMENDS_e2fsprogs = "e2fsprogs-mke2fs e2fsprogs-e2fsck"
  73
  74 PACKAGES =+ "e2fsprogs-e2fsck e2fsprogs-mke2fs e2fsprogs-tune2fs e2fsprogs-badblocks e2fsprogs-resize2fs"
  75 PACKAGES =+ "libcomerr libss libe2p libext2fs"
  76
  77 FILES_e2fsprogs-resize2fs = "${base_sbindir}/resize2fs*"
  78 FILES_e2fsprogs-e2fsck = "${base_sbindir}/e2fsck ${base_sbindir}/fsck.ext*"
  79 FILES_e2fsprogs-mke2fs = "${base_sbindir}/mke2fs ${base_sbindir}/mkfs.ext* ${sysconfdir}/mke2fs.conf"
  80 FILES_e2fsprogs-tune2fs = "${base_sbindir}/tune2fs ${base_sbindir}/e2label"
  81 FILES_e2fsprogs-badblocks = "${base_sbindir}/badblocks"
  82 FILES_libcomerr = "${base_libdir}/libcom_err.so.*"
  83 FILES_libss = "${base_libdir}/libss.so.*"
  84 FILES_libe2p = "${base_libdir}/libe2p.so.*"
  85 FILES_libext2fs = "${libdir}/e2initrd_helper ${base_libdir}/libext2fs.so.*"
  86 FILES_${PN}-dev += "${datadir}/*/*.awk ${datadir}/*/*.sed ${base_libdir}/*.so"
  87
  88 ALTERNATIVE_${PN} = "chattr"
  89 ALTERNATIVE_PRIORITY = "100"
  90 ALTERNATIVE_LINK_NAME[chattr] = "${base_bindir}/chattr"
  91 ALTERNATIVE_TARGET[chattr] = "${base_bindir}/chattr.e2fsprogs"
  92
  93 ALTERNATIVE_${PN}-doc = "fsck.8"
  94 ALTERNATIVE_LINK_NAME[fsck.8] = "${mandir}/man8/fsck.8"
  95
  96 RDEPENDS_${PN}-ptest += "${PN} ${PN}-tune2fs coreutils procps bash"
  97
  98 do_compile_ptest() {
  99         oe_runmake -C ${B}/tests
 100 }
 101
 102 do_install_ptest() {
 103         cp -a ${B}/tests ${D}${PTEST_PATH}/test
 104         cp -a ${S}/tests/* ${D}${PTEST_PATH}/test
 105         sed -e 's!../e2fsck/e2fsck!e2fsck!g' -i ${D}${PTEST_PATH}/test/*/expect*
 106 }