linux: add missing CONFIG_BT_HCIUART option to usb-devices.cfg
[AGL/meta-agl.git] / meta-security / recipes-core / dbus-cynara / dbus-cynara_1.12.10.bb
1 require ${COREBASE}/meta/recipes-core/dbus/dbus_1.12.10.bb
2
3 FILESEXTRAPATHS_prepend := "${COREBASE}/meta/recipes-core/dbus/dbus:${THISDIR}/dbus-cynara:"
4 S = "${WORKDIR}/dbus-${PV}"
5
6 SRC_URI_append = "\
7    file://0001-Integration-of-Cynara-asynchronous-security-checks.patch \
8    file://0002-Disable-message-dispatching-when-send-rule-result-is.patch \
9    file://0003-Handle-unavailability-of-policy-results-for-broadcas.patch \
10    file://0004-Add-own-rule-result-unavailability-handling.patch \
11    file://0005-Perform-Cynara-runtime-policy-checks-by-default.patch \
12    file://0006-Fix-gcc-8-warnings.patch \
13 "
14
15 DEPENDS += "cynara smack"
16 RDEPENDS_${PN} += "dbus"
17
18 EXTRA_OECONF += "--enable-cynara --disable-selinux"
19
20 inherit distro_features_check
21 REQUIRED_DISTRO_FEATURES += "smack"
22
23 # Only the main package gets created here, everything else remains in the
24 # normal dbus recipe.
25 do_install_append () {
26     for i in ${@' '.join([d.getVar('D', True) + x for x in (' '.join([d.getVar('FILES_${PN}-' + p, True) or '' for p in ['lib', 'dev', 'staticdev', 'doc', 'locale', 'ptest']])).split()])}; do
27         rm -rf $i
28     done
29
30     # Try to remove empty directories, starting with the
31     # longest path (= deepest directory) first.
32     # Find needs a valid current directory. Somehow the directory
33     # we get called in is gone by the time that we get invoked.
34     ( cd ${D}
35       for i in `find . -type d | sort -r`; do
36         rmdir $i || true
37       done
38     )
39 }
40
41 # Avoid warning about dbus and dbus-cynara providing dbus-x11.
42 RPROVIDES_${PN}_remove = "${OLDPKGNAME}"