meta-security/recipes-core/dbus-cynara/dbus-cynara_1.10.20.bb

   1 require ${COREBASE}/meta/recipes-core/dbus/dbus_1.10.20.bb
   2
   3 FILESEXTRAPATHS_prepend := "${COREBASE}/meta/recipes-core/dbus/dbus:${THISDIR}/dbus-cynara:"
   4 S = "${WORKDIR}/dbus-${PV}"
   5
   6 SRC_URI_append = "\
   7    file://0001-Integration-of-Cynara-asynchronous-security-checks.patch \
   8    file://0002-Disable-message-dispatching-when-send-rule-result-is.patch \
   9    file://0003-Handle-unavailability-of-policy-results-for-broadcas.patch \
  10    file://0004-Add-own-rule-result-unavailability-handling.patch \
  11    file://0005-Perform-Cynara-runtime-policy-checks-by-default.patch \
  12 "
  13
  14 DEPENDS += "cynara smack"
  15 EXTRA_OECONF += "--enable-cynara --disable-selinux"
  16
  17 inherit distro_features_check
  18 REQUIRED_DISTRO_FEATURES += "smack"
  19
  20 # Only the main package gets created here, everything else remains in the
  21 # normal dbus recipe.
  22 do_install_append () {
  23     for i in ${@' '.join([d.getVar('D', True) + x for x in (' '.join([d.getVar('FILES_${PN}-' + p, True) or '' for p in ['lib', 'dev', 'staticdev', 'doc', 'locale', 'ptest']])).split()])}; do
  24         rm -rf $i
  25     done
  26
  27     # Try to remove empty directories, starting with the
  28     # longest path (= deepest directory) first.
  29     # Find needs a valid current directory. Somehow the directory
  30     # we get called in is gone by the time that we get invoked.
  31     ( cd ${D}
  32       for i in `find . -type d | sort -r`; do
  33         rmdir $i || true
  34       done
  35     )
  36 }
  37
  38 # Avoid warning about dbus and dbus-cynara providing dbus-x11.
  39 RPROVIDES_${PN}_remove = "${OLDPKGNAME}"