meta-security/recipes-core/dbus/dbus_%.bbappend

   1 # Optionally, compilation of the main package with the daemon gets moved into
   2 # dbus-cynara. That is necessary to break a dependency cycle once the
   3 # daemon gets compiled with Cynara support (dbus -> cynara -> systemd
   4 # -> dbus).
   5 do_install_append_class-target () {
   6     if ${@bb.utils.contains('DISTRO_FEATURES', 'dbus-cynara', 'true', 'false', d)}; then
   7         for i in ${@' '.join([d.getVar('D', True) + x for x in (d.getVar('FILES_${PN}', True) or '').split()])}; do
   8             rm -rf $i
   9         done
  10
  11         # Try to remove empty directories, starting with the
  12         # longest path (= deepest directory) first.
  13         # Find needs a valid current directory. Somehow the directory
  14         # we get called in is gone by the time that we get invoked.
  15         ( cd ${D}
  16           for i in `find . -type d | sort -r`; do
  17             rmdir $i || true
  18           done
  19         )
  20     fi
  21 }
  22
  23 # The main package will be empty, but we want to have it created
  24 # anyway because of the dependencies on it. Installing it will pull in
  25 # the replacement dbus-cynara package.
  26 ALLOW_EMPTY_${PN}_class-target = "1"
  27 RDEPENDS_${PN}_append_class-target = "${@bb.utils.contains('DISTRO_FEATURES', 'dbus-cynara', ' dbus-cynara', '', d)}"