meta-pipewire/recipes-multimedia/wireplumber/wireplumber_git.bb

   1 SUMMARY     = "Session / Policy Manager for PipeWire"
   2 HOMEPAGE    = "https://gitlab.freedesktop.org/pipewire/wireplumber"
   3 BUGTRACKER  = "https://gitlab.freedesktop.org/pipewire/wireplumber/issues"
   4 AUTHOR      = "George Kiagiadakis <george.kiagiadakis@collabora.com>"
   5 SECTION     = "multimedia"
   6
   7 LICENSE = "MIT"
   8 LIC_FILES_CHKSUM = "file://LICENSE;beginline=3;md5=e8ad01a5182f2c1b3a2640e9ea268264"
   9
  10 inherit meson pkgconfig systemd
  11
  12 DEPENDS = "glib-2.0 glib-2.0-native pipewire lua"
  13
  14 SRC_URI = "\
  15     git://gitlab.freedesktop.org/pipewire/wireplumber.git;protocol=https;branch=master \
  16 "
  17 SRCREV = "4af7e2bd68c4862bb707b62edf7557df56dad10f"
  18
  19 PV = "0.4.0"
  20 S  = "${WORKDIR}/git"
  21
  22 WPAPI="0.4"
  23
  24 # use shared lua from the system instead of the static bundled one
  25 EXTRA_OEMESON += "-Dsystem-lua=true"
  26
  27 # introspection in practice is only used for generating API docs
  28 # API docs are available on the website and we don't need to build them
  29 # (plus they depend on hotdoc which is not available here)
  30 EXTRA_OEMESON += "-Dintrospection=disabled -Ddoc=disabled"
  31
  32 PACKAGECONFIG = "\
  33     ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
  34 "
  35
  36 PACKAGECONFIG[systemd] = "-Dsystemd=enabled -Dsystemd-system-service=true -Dsystemd-user-service=false,-Dsystemd=disabled -Dsystemd-system-service=false -Dsystemd-user-service=false,systemd"
  37
  38 do_configure:prepend() {
  39     # relax meson version requirement
  40     # we only need 0.54 when building with -Dsystem-lua=false
  41     sed "s/meson_version : '>= 0.54.0'/meson_version : '>= 0.51.0'/" ${S}/meson.build > ${S}/tmp.build
  42     mv -f ${S}/tmp.build ${S}/meson.build
  43 }
  44
  45 PACKAGES =+ "\
  46     lib${PN}-${WPAPI} \
  47     ${PN}-config \
  48 "
  49
  50 SYSTEMD_SERVICE:${PN} = "wireplumber.service"
  51 FILES:${PN} = "\
  52     ${bindir}/wireplumber \
  53     ${bindir}/wpctl \
  54     ${bindir}/wpexec \
  55     ${libdir}/wireplumber-${WPAPI}/* \
  56     ${datadir}/wireplumber/* \
  57     ${systemd_system_unitdir}/* \
  58 "
  59 RPROVIDES:${PN} += "virtual/pipewire-sessionmanager"
  60 RDEPENDS:${PN} += "virtual/wireplumber-config"
  61
  62 FILES:lib${PN}-${WPAPI} = "\
  63     ${libdir}/libwireplumber-${WPAPI}.so.* \
  64 "
  65
  66 FILES:${PN}-config += "\
  67     ${sysconfdir}/wireplumber/* \
  68 "
  69 CONFFILES:${PN}-config += "\
  70     ${sysconfdir}/wireplumber/* \
  71 "
  72 RPROVIDES:${PN}-config += "virtual/wireplumber-config"