meta-pipewire/recipes-multimedia/wireplumber/wireplumber_git.bb

   1 SUMMARY     = "Session / Policy Manager for PipeWire"
   2 HOMEPAGE    = "https://gitlab.freedesktop.org/pipewire/wireplumber"
   3 BUGTRACKER  = "https://gitlab.freedesktop.org/pipewire/wireplumber/issues"
   4 AUTHOR      = "George Kiagiadakis <george.kiagiadakis@collabora.com>"
   5 SECTION     = "multimedia"
   6
   7 LICENSE = "MIT"
   8 LIC_FILES_CHKSUM = "file://LICENSE;beginline=3;md5=e8ad01a5182f2c1b3a2640e9ea268264"
   9
  10 inherit meson pkgconfig gobject-introspection
  11
  12 DEPENDS = "glib-2.0 glib-2.0-native pipewire"
  13
  14 SRC_URI = "\
  15     git://gitlab.freedesktop.org/pipewire/wireplumber.git;protocol=https;branch=master \
  16     https://raw.githubusercontent.com/skystrife/cpptoml/fededad7169e538ca47e11a9ee9251bc361a9a65/include/cpptoml.h \
  17     file://0001-Build-cpptoml-without-a-cmake-subproject.patch \
  18 "
  19 SRCREV = "0e98e4150b73d0bed9b72bf8d3eba49671962991"
  20 SRC_URI[sha256sum] = "3e4e1d315fa1229921c7a4297ead08775b5bb1220c18a7eac62db9ca7e79df0d"
  21
  22 PV = "0.1.90+git${SRCPV}"
  23 S  = "${WORKDIR}/git"
  24
  25 do_configure_prepend() {
  26     mkdir -p ${WORKDIR}/git/subprojects/cpptoml/include
  27     cp -f ${WORKDIR}/cpptoml.h ${WORKDIR}/git/subprojects/cpptoml/include/
  28 }
  29
  30 PACKAGES =+ "${PN}-config"
  31
  32 FILES_${PN} += "\
  33     ${libdir}/wireplumber-*/* \
  34 "
  35 RPROVIDES_${PN} += "virtual/pipewire-sessionmanager"
  36 RDEPENDS_${PN} += "virtual/wireplumber-config"
  37
  38
  39 FILES_${PN}-config += "\
  40     ${sysconfdir}/wireplumber/* \
  41 "
  42 CONFFILES_${PN}-config += "\
  43     ${sysconfdir}/wireplumber/* \
  44 "
  45
  46 RPROVIDES_${PN}-config += "virtual/wireplumber-config"