meta-pipewire/recipes-multimedia/pipewire/pipewire_0.3.83.bbappend

   1 SRC_URI += "\
   2     file://0001-systemd-Do-not-override-rootprefix.patch \
   3     file://0002-gst-avoid-reporting-error-twice.patch \
   4     file://0003-gstpipewiresrc-break-out-of-wait_started-also-on-STA.patch \
   5 "
   6
   7 PACKAGECONFIG = "\
   8     ${@bb.utils.contains('DISTRO_FEATURES', 'bluez5', 'bluez', '', d)} \
   9     ${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa pipewire-alsa', '', d)} \
  10     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'sndfile', '', d)} \
  11     ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
  12     gstreamer v4l2 \
  13 "
  14
  15 do_install:append() {
  16     # install symlinks to alsalib configuration files
  17     for i in 50-pipewire.conf 99-pipewire-default.conf; do
  18         if [ -f ${D}${datadir}/alsa/alsa.conf.d/${i} ]; then
  19             install -d ${D}${sysconfdir}/alsa/conf.d
  20             ln -s ${datadir}/alsa/alsa.conf.d/${i} ${D}${sysconfdir}/alsa/conf.d/${i}
  21         fi
  22     done
  23 }
  24
  25 FILES:${PN}-alsa:append = "\
  26     ${sysconfdir}/alsa/conf.d/* \
  27 "