meta-pipewire/recipes-multimedia/pipewire/pipewire_0.3.47.bbappend

   1 PACKAGECONFIG = "\
   2     ${@bb.utils.contains('DISTRO_FEATURES', 'bluez5', 'bluez', '', d)} \
   3     ${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa pipewire-alsa', '', d)} \
   4     ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'sndfile', '', d)} \
   5     ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
   6     gstreamer v4l2 \
   7 "
   8
   9 SRC_URI += "\
  10     file://0001-Revert-treewide-meson.build-use-project_-build-sourc.patch \
  11     file://0002-Revert-treewide-meson.build-use-feature.allowed.patch \
  12     file://0003-Revert-treewide-meson.build-use-dependency-variable-.patch \
  13     file://0004-Revert-treewide-meson.build-simplify-get_variable-ca.patch \
  14     file://0005-Revert-treewide-meson.build-get-SPA_PLUGIN_DIR-from-.patch \
  15     file://0006-Revert-meson-declare-spa_dep-and-override_dependency.patch \
  16     file://0007-Revert-meson-use-meson-variables-for-the-SMs-uninsta.patch \
  17     file://0008-Revert-meson-declare-spa_dep-and-override_dependency.patch \
  18     file://0009-Revert-test-add-test-for-the-loop.patch \
  19     file://0010-Revert-spa-improve-the-AEC-interface.patch \
  20     file://0011-Revert-module-echo-cancel-Move-backends-to-dynamic-l.patch \
  21     file://0012-Miscellanous-changes-to-account-for-lower-version-of.patch \
  22 "
  23
  24 do_install:append() {
  25     # install symlinks to alsalib configuration files
  26     for i in 50-pipewire.conf 99-pipewire-default.conf; do
  27         if [ -f ${D}${datadir}/alsa/alsa.conf.d/${i} ]; then
  28             mkdir -p ${D}${sysconfdir}/alsa/conf.d
  29             ln -s ${datadir}/alsa/alsa.conf.d/${i} ${D}${sysconfdir}/alsa/conf.d/${i}
  30         fi
  31     done
  32 }
  33
  34 FILES:${PN}-alsa:append = "\
  35     ${sysconfdir}/alsa/conf.d/* \
  36 "