meta-pipewire/dynamic-layers/meta-app-framework/recipes-multimedia/pipewire/pipewire_0.3.40.bbappend

   1 FILESEXTRAPATHS:prepend := "${THISDIR}/pipewire:"
   2
   3 SRC_URI:append= "\
   4     file://0001-modules-add-new-access-seclabel-module.patch \
   5     file://0002-meson-remove-pipewire_module_c_args-as-it-is-no-long.patch \
   6     file://pipewire.conf \
   7     file://pipewire.service \
   8     file://pipewire.socket \
   9     file://smack-pipewire \
  10 "
  11
  12 do_install:append() {
  13      # replace the original config with our smack-aware config
  14     mkdir -p ${D}${sysconfdir}/pipewire/
  15     install -m 0644 ${WORKDIR}/pipewire.conf ${D}${sysconfdir}/pipewire/pipewire.conf
  16
  17     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  18         # remove the original unit files shipped by pipewire
  19         rm -rf ${D}${systemd_system_unitdir}/pipewire.*
  20
  21         # install our own system-level templates
  22         mkdir -p ${D}${systemd_system_unitdir}/
  23         install -m 0644 ${WORKDIR}/pipewire.service ${D}${systemd_system_unitdir}/pipewire.service
  24         install -m 0644 ${WORKDIR}/pipewire.socket ${D}${systemd_system_unitdir}/pipewire.socket
  25
  26         # install smack rules
  27         mkdir -p ${D}${sysconfdir}/smack/accesses.d
  28         install -m 0644 ${WORKDIR}/smack-pipewire ${D}${sysconfdir}/smack/accesses.d/pipewire
  29     fi
  30 }
  31
  32 FILES:${PN}:append = "\
  33     ${sysconfdir}/smack/accesses.d/* \
  34     ${sysconfdir}/pipewire/pipewire.conf \
  35 "