meta-offline-voice-agent/recipes-vosk/vosk-kaldi/vosk-kaldi_git.bb

   1 SUMMARY = "Kaldi Speech Recognition Toolkit"
   2 HOMEPAGE = "http://kaldi-asr.org/"
   3 LICENSE = "Apache-2.0"
   4 LIC_FILES_CHKSUM = "file://../COPYING;md5=a10e448a64dbd3723ff3fb2f397fba2e \
   5                     file://doc/legal.dox;md5=3cba845003f27e67da70faa5da924c1e"
   6
   7 SRC_URI = "git://github.com/alphacep/kaldi.git;protocol=https;branch=vosk \
   8            file://0001-Fixes-for-shared-library-compilation.patch \
   9            "
  10
  11 PV = "1.0+git${SRCPV}"
  12 SRCREV = "a25f216f5ce4eec5e45a6ab7651e20c9840a05cd"
  13 S = "${WORKDIR}/git/src"
  14
  15 DEPENDS += "openblas vosk-openfst"
  16
  17 inherit python3native
  18
  19 ALLOW_EMPTY_${PN} = "1"
  20
  21 MYCONF = "--mathlib=OPENBLAS --static --shared --use-cuda=no --fst-root=${STAGING_INCDIR}/../ --fst-version=1.8.0 --openblas-root=${STAGING_INCDIR}/../ "
  22
  23 # remove x86-specific optimizations
  24 do_configure:prepend:aarch64(){
  25 sed -i -e "s#-msse -msse2##g" ${S}/makefiles/linux_openblas.mk
  26 }
  27
  28 do_configure:prepend:arm(){
  29 sed -i -e "s#-msse -msse2##g" ${S}/makefiles/linux_openblas.mk
  30 }
  31
  32
  33 do_configure() {
  34   ./configure ${MYCONF}
  35 }
  36
  37 do_compile() {
  38   make ${PARALLEL_MAKE}
  39 }
  40
  41 do_install() {
  42   install -d ${D}${libdir}
  43
  44   for i in lib/*.so ; do
  45     install -m 0644 ${i} ${D}${libdir}/
  46   done
  47
  48   for i in */*.a ; do
  49     install -m 0644 ${i} ${D}${libdir}/
  50   done
  51
  52   for j in base chain decoder feat fstext gmm gst-plugin hmm itf ivector kws lat lm matrix nnet nnet2 nnet3 online online2 rnnlm sgmm2 tfrnnlm transform tree util cudadecoder  cudadecoderbin  cudafeat  cudamatrix ; do
  53     install -d ${D}${includedir}/kaldi/$j
  54     for i in $j/*.h ; do
  55       install -m 0644 $i ${D}${includedir}/kaldi/$j/
  56     done
  57   done
  58
  59   # make sure we have the package vosk-kaldi
  60
  61   install -d ${D}/usr/share/kaldi
  62   echo "This is vosk-kaldi" > ${D}/usr/share/kaldi/README
  63
  64 }
  65
  66 FILES:${PN} += " /usr/share/kaldi  /usr/share/kaldi/README"
  67 ERROR_QA:remove = "rpaths"
  68 ERROR_QA:remove = "dev-elf"