meta-offline-voice-agent/recipes-python/python3-vosk/python3-vosk-api_0.3.42.bb

   1 SUMMARY = "Offline open source speech recognition API based on Kaldi and Vosk"
   2 HOMEPAGE = "https://github.com/alphacep/vosk-api"
   3 LICENSE = "Apache-2.0"
   4 LIC_FILES_CHKSUM = "file://../COPYING;md5=d09bbd7a3746b6052fbd78b26a87396b"
   5
   6 SRC_URI = "git://github.com/alphacep/vosk-api;protocol=https;branch=master \
   7            file://0001-Change-library-search-path-to-usr-lib.patch \
   8            file://run-ptest \
   9            "
  10
  11 PV = "0.3.42+git${SRCPV}"
  12 SRCREV = "b1b216d4c87d708935f1601287fe502aa11ee4a9"
  13
  14 S = "${WORKDIR}/git/python"
  15
  16 inherit setuptools3 ptest
  17
  18 DEPENDS += " \
  19     python3-srt-native \
  20     python3-tqdm-native \
  21     python3-requests-native \
  22     python3-pip-native \
  23     python3-charset-normalizer-native \
  24 "
  25
  26 RDEPENDS:${PN} += " \
  27     python3-cffi \
  28     python3-compression \
  29     python3-core \
  30     python3-datetime \
  31     python3-json \
  32     python3-logging \
  33     python3-misc \
  34     python3-multiprocessing \
  35     python3-netclient \
  36     python3-requests \
  37     python3-tqdm \
  38     python3-srt \
  39     python3-charset-normalizer \
  40     python3-sounddevice \
  41     virtual/vosk-model \
  42 "
  43
  44 do_install_ptest () {
  45     install -d ${D}${PTEST_PATH}/tests/
  46     cp ${S}/example/test_simple.py ${D}${PTEST_PATH}/tests/
  47     cp ${S}/example/test.wav ${D}${PTEST_PATH}/tests/
  48 }