meta-ivi-common/recipes-extended/dlt-daemon/dlt-daemon_2.15.0.bb

   1 SUMMARY = "Diagnostic Log and Trace"
   2 DESCRIPTION = "This component provides a standardised log and trace interface, \
   3 based on the standardised protocol specified in the AUTOSAR standard 4.0 DLT. \
   4 This component can be used by GENIVI components and other applications as \
   5 logging facility providing: \
   6 - the DLT shared library \
   7 - the DLT daemon, including startup scripts \
   8 - the DLT daemon adaptors- the DLT client console utilities \
   9 - the DLT test applications"
  10 HOMEPAGE = "https://www.genivi.org/"
  11 SECTION = "console/utils"
  12 LICENSE = "MPLv2"
  13 LIC_FILES_CHKSUM = "file://LICENSE;md5=8184208060df880fe3137b93eb88aeea"
  14
  15 DEPENDS = "dbus zlib"
  16
  17 SRCREV = "e9a486a08fff6d3cc7133a350cec3ee10f463207"
  18 SRC_URI = "git://git.projects.genivi.org/${BPN}.git;protocol=http \
  19     file://0002-Don-t-execute-processes-as-a-specific-user.patch \
  20     file://0004-Modify-systemd-config-directory.patch \
  21     "
  22 S = "${WORKDIR}/git"
  23
  24 inherit gzipnative autotools gettext cmake systemd
  25
  26 # -fPIC is needed to prevent relocation errors when we compile gtest with
  27 # Yocto security flags. See this issue for more details:
  28 #
  29 # https://github.com/google/googletest/issues/854
  30 #
  31 # If that issue is fixed, we can probably remove the manual -fPIC flags here.
  32 OECMAKE_C_FLAGS += "-fPIC"
  33 OECMAKE_CXX_FLAGS += "-fPIC"
  34
  35 PACKAGES += "${PN}-systemd"
  36 SYSTEMD_PACKAGES = "${PN} ${PN}-systemd"
  37 SYSTEMD_SERVICE_${PN} = "dlt-system.service dlt.service"
  38 SYSTEMD_AUTO_ENABLE_${PN} = "enable"
  39 SYSTEMD_SERVICE_${PN}-systemd = "dlt-example-user.service \
  40     dlt-dbus.service \
  41     dlt-adaptor-udp.service \
  42     dlt-receive.service"
  43 SYSTEMD_AUTO_ENABLE_${PN}-systemd = "disable"
  44
  45 EXTRA_OECMAKE = "-DWITH_SYSTEMD=ON"
  46
  47 FILES_${PN}-doc += "/usr/share/dlt-filetransfer"
  48
  49 do_install_append() {
  50    rm -f ${D}${bindir}/dlt-test-*
  51 }