meta-html5-framework/recipes-wam/chromium/chromium68_git.bb

   1 # Copyright (c) 2018 LG Electronics, Inc.
   2
   3 SUMMARY = "Chromium webruntime for webOS"
   4 AUTHOR = "Lokesh Kumar Goel <lokeshkumar.goel@lge.com>"
   5 SECTION = "webos/apps"
   6 LICENSE = "Apache-2.0 & BSD-3-Clause & LGPL-2.0 & LGPL-2.1"
   7 LIC_FILES_CHKSUM = "\
   8     file://src/LICENSE;md5=0fca02217a5d49a14dfe2d11837bb34d \
   9     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
  10     file://src/third_party/blink/renderer/core/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
  11 "
  12
  13 require gn-utils.inc
  14
  15 inherit gettext qemu
  16
  17 DEPENDS = "virtual/gettext wayland wayland-native pixman freetype glib-2.0 fontconfig openssl pango cairo icu libxkbcommon libexif dbus pciutils udev libcap alsa-lib virtual/egl elfutils-native libdrm atk gperf-native gconf nss nss-native nspr nspr-native bison-native qemu-native"
  18
  19 PROVIDES = "${BROWSER_APPLICATION}"
  20
  21 SRC_URI = "\
  22     git://github.com/webosose/${PN};branch=@39.agl.guppy;protocol=https;rev=${SRCREV_chromium68} \
  23     git://github.com/webosose/v8;destsuffix=git/src/v8;rev=${SRCREV_v8} \
  24     file://v8-qemu-wrapper.patch \
  25 "
  26 SRCREV_chromium68 = "259a8b56bc833956f3acd318b7f19b028277beda"
  27 SRCREV_v8 = "1e3af71f1ff3735e8a5b639c48dfca63a7b8a647"
  28
  29 # Backport of https://chromium-review.googlesource.com/c/chromium/src/+/1138251/
  30 SRC_URI_append_armv7a = " file://0001-skia-Build-skcms-with-mfp16-format-ieee-on-GCC-ARM-b.patch"
  31 SRC_URI_append_armv7ve = " file://0001-skia-Build-skcms-with-mfp16-format-ieee-on-GCC-ARM-b.patch"
  32
  33 # we don't include SRCPV in PV, so we have to manually include SRCREVs in do_fetch vardeps
  34 do_fetch[vardeps] += "SRCREV_v8"
  35 SRCREV_FORMAT = "main_v8"
  36
  37 S = "${WORKDIR}/git"
  38
  39 SRC_DIR = "${S}/src"
  40 OUT_DIR = "${WORKDIR}/build"
  41 BUILD_TYPE = "Release"
  42
  43 B = "${OUT_DIR}/${BUILD_TYPE}"
  44
  45 WEBRUNTIME_BUILD_TARGET = "webos:weboswebruntime"
  46 BROWSER_APP_BUILD_TARGET = "chrome"
  47 BROWSER_APPLICATION = "chromium68-browser"
  48 BROWSER_APPLICATION_DIR = "/opt/chromium68"
  49
  50 TARGET = "${WEBRUNTIME_BUILD_TARGET} ${BROWSER_APP_BUILD_TARGET}"
  51
  52 # Skip do_install_append of webos_system_bus. It is not compatible with this component.
  53 WEBOS_SYSTEM_BUS_FILES_LOCATION = "${S}/files/sysbus"
  54
  55 PACKAGECONFIG ?= "jumbo use-upstream-wayland"
  56
  57 # Options to enable debug-webcore build.
  58 # Add the following line to local.conf (or local.dev.inc) to enable them:
  59 #   PACKAGECONFIG_append_pn-chromium68 = " debug-webcore"
  60 # Other debug options are controlled by sections later in this file
  61 PACKAGECONFIG[debug-webcore] = "remove_webcore_debug_symbols=false,remove_webcore_debug_symbols=true"
  62
  63 # Set a default value for jumbo file merge of 8. This should be good for build
  64 # servers and workstations with a big number of cores. In case build is
  65 # happening in a machine with less cores but still enough RAM a good value could
  66 # be 50.
  67 JUMBO_FILE_MERGE_LIMIT="8"
  68 PACKAGECONFIG[jumbo] = "use_jumbo_build=true jumbo_file_merge_limit=${JUMBO_FILE_MERGE_LIMIT}, use_jumbo_build=false"
  69
  70 PACKAGECONFIG[lttng] = "use_lttng=true,use_lttng=false,lttng-ust,lttng-tools lttng-modules babeltrace"
  71
  72 # Chromium can use v4l2 device for hardware accelerated video decoding on such boards as Renesas R-car M3, for example.
  73 # In case of R-car m3, additional patches are required for gstreamer and v4l2apps.
  74 # See https://github.com/igel-oss/meta-browser-hwdecode/tree/igalia-chromium71.
  75 PACKAGECONFIG[use-linux-v4l2] = "use_v4l2_codec=true use_v4lplugin=true use_linux_v4l2_only=true"
  76
  77 PACKAGECONFIG[use-upstream-wayland] = " \
  78         ozone_platform_wayland_external=false ozone_platform_wayland=true \
  79         use_system_minigbm=true, \
  80         ozone_platform_wayland_external=true ozone_platform_wayland=false \
  81 "
  82
  83 GN_ARGS = "\
  84     enable_memorymanager_webapi=false\
  85     ffmpeg_branding=\"Chrome\"\
  86     host_os=\"linux\"\
  87     ozone_auto_platforms=false\
  88     proprietary_codecs=true\
  89     target_os=\"linux\"\
  90     treat_warnings_as_errors=false\
  91     is_agl=true\
  92     use_cbe=true\
  93     is_chrome_cbe=true\
  94     use_cups=false\
  95     use_custom_libcxx=false\
  96     use_kerberos=false\
  97     use_neva_media=false\
  98     use_ozone=true\
  99     use_xkbcommon=true\
 100     use_pmlog=false\
 101     use_system_debugger_abort=true\
 102     use_webos_gpu_info_collector=false\
 103     ${PACKAGECONFIG_CONFARGS}\
 104 "
 105
 106 # From Chromium's BUILDCONFIG.gn:
 107 # Set to enable the official build level of optimization. This has nothing
 108 # to do with branding, but enables an additional level of optimization above
 109 # release (!is_debug). This might be better expressed as a tri-state
 110 # (debug, release, official) but for historical reasons there are two
 111 # separate flags.
 112 # See also: https://groups.google.com/a/chromium.org/d/msg/chromium-dev/hkcb6AOX5gE/PPT1ukWoBwAJ
 113 GN_ARGS += "is_debug=false is_official_build=true"
 114
 115 # is_cfi default value is true for x86-64 builds with is_official_build=true.
 116 # As of M63, we explicitly need to set it to false, otherwise we fail the
 117 # following assertion in //build/config/sanitizers/sanitizers.gni:
 118 #   assert(!is_cfi || is_clang,
 119 #          "is_cfi requires setting is_clang = true in 'gn args'")
 120 GN_ARGS += "is_cfi=false"
 121
 122 # By default, passing is_official_build=true to GN causes its symbol_level
 123 # variable to be set to "2". This means the compiler will be passed "-g2" and
 124 # we will end up with a very large chrome binary (around 5Gb as of M58)
 125 # regardless of whether DEBUG_BUILD has been set or not. In addition, binutils,
 126 # file and other utilities are unable to read a 32-bit binary this size, which
 127 # causes it not to be stripped.
 128 # The solution is two-fold:
 129 # 1. Make sure -g is not passed on 32-bit architectures via DEBUG_FLAGS. -g is
 130 #    the same as -g2. -g1 generates an 800MB binary, which is a lot more
 131 #    manageable.
 132 # 2. Explicitly pass symbol_level=0 to GN. This causes -g0 to be passed
 133 #    instead, so that if DEBUG_BUILD is not set GN will not create a huge debug
 134 #    binary anyway. Since our compiler flags are passed after GN's, -g0 does
 135 #    not cause any issues if DEBUG_BUILD is set, as -g1 will be passed later.
 136 DEBUG_FLAGS_remove_arm = "-g"
 137 DEBUG_FLAGS_append_arm = "-g1"
 138 DEBUG_FLAGS_remove_x86 = "-g"
 139 DEBUG_FLAGS_append_x86 = "-g1"
 140 GN_ARGS += "symbol_level=0"
 141
 142 # We do not want to use Chromium's own Debian-based sysroots, it is easier to
 143 # just let Chromium's build system assume we are not using a sysroot at all and
 144 # let Yocto handle everything.
 145 GN_ARGS += "use_sysroot=false"
 146
 147 # Toolchains we will use for the build. We need to point to the toolchain file
 148 # we've created, set the right target architecture and make sure we are not
 149 # using Chromium's toolchain (bundled clang, bundled binutils etc).
 150 GN_ARGS += "\
 151         custom_toolchain=\"//build/toolchain/yocto:yocto_target\" \
 152         gold_path=\"\" \
 153         host_toolchain=\"//build/toolchain/yocto:yocto_native\" \
 154         is_clang=${@is_default_cc_clang(d)} \
 155         clang_base_path=\"${@clang_install_path(d)}\" \
 156         clang_use_chrome_plugins=false \
 157         linux_use_bundled_binutils=false \
 158         target_cpu=\"${@gn_target_arch_name(d)}\" \
 159         v8_snapshot_toolchain=\"//build/toolchain/yocto:yocto_target\" \
 160 "
 161
 162 # ARM builds need special additional flags (see ${S}/build/config/arm.gni).
 163 # If we do not pass |arm_arch| and friends to GN, it will deduce a value that
 164 # will then conflict with TUNE_CCARGS and CC.
 165 # Note that as of M61 in some corner cases parts of the build system disable
 166 # the "compiler_arm_fpu" GN config, whereas -mfpu is always passed via ${CC}.
 167 # We might want to rework that if there are issues in the future.
 168 def get_compiler_flag(params, param_name, d):
 169     """Given a sequence of compiler arguments in |params|, returns the value of
 170     an option |param_name| or an empty string if the option is not present."""
 171     for param in params:
 172       if param.startswith(param_name):
 173         return param.split('=')[1]
 174     return ''
 175
 176 ARM_FLOAT_ABI = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'hard', 'softfp', d)}"
 177 ARM_FPU = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mfpu', d)}"
 178 ARM_TUNE = "${@get_compiler_flag(d.getVar('TUNE_CCARGS').split(), '-mcpu', d)}"
 179 ARM_VERSION_aarch64 = "8"
 180 ARM_VERSION_armv7a = "7"
 181 ARM_VERSION_armv7ve = "7"
 182 ARM_VERSION_armv6 = "6"
 183
 184 # GN computes and defaults to it automatically where needed
 185 # forcing it from cmdline breaks build on places where it ends up
 186 # overriding what GN wants
 187 TUNE_CCARGS_remove = "-mthumb"
 188
 189 GN_ARGS_append_arm = " \
 190         arm_float_abi=\"${ARM_FLOAT_ABI}\" \
 191         arm_fpu=\"${ARM_FPU}\" \
 192         arm_tune=\"${ARM_TUNE}\" \
 193         arm_version=${ARM_VERSION} \
 194 "
 195 # tcmalloc's atomicops-internals-arm-v6plus.h uses the "dmb" instruction that
 196 # is not available on (some?) ARMv6 models, which causes the build to fail.
 197 GN_ARGS_append_armv6 += 'use_allocator="none"'
 198 # The WebRTC code fails to build on ARMv6 when NEON is enabled.
 199 # https://bugs.chromium.org/p/webrtc/issues/detail?id=6574
 200 GN_ARGS_append_armv6 += 'arm_use_neon=false'
 201
 202 # Disable glibc shims on musl
 203 # tcmalloc does not play well with musl as of M62 (and possibly earlier).
 204 # https://github.com/gperftools/gperftools/issues/693
 205 GN_ARGS_append_libc-musl = ' use_allocator_shim=false'
 206
 207 # V8's JIT infrastructure requires binaries such as mksnapshot and
 208 # mkpeephole to be run in the host during the build. However, these
 209 # binaries must have the same bit-width as the target (e.g. a x86_64
 210 # host targeting ARMv6 needs to produce a 32-bit binary). Instead of
 211 # depending on a third Yocto toolchain, we just build those binaries
 212 # for the target and run them on the host with QEMU.
 213 python do_create_v8_qemu_wrapper () {
 214     """Creates a small wrapper that invokes QEMU to run some target V8 binaries
 215     on the host."""
 216     qemu_libdirs = [d.expand('${STAGING_DIR_HOST}${libdir}'),
 217                     d.expand('${STAGING_DIR_HOST}${base_libdir}')]
 218     qemu_cmd = qemu_wrapper_cmdline(d, d.getVar('STAGING_DIR_HOST', True),
 219                                     qemu_libdirs)
 220     wrapper_path = d.expand('${B}/v8-qemu-wrapper.sh')
 221     with open(wrapper_path, 'w') as wrapper_file:
 222         wrapper_file.write("""#!/bin/sh
 223
 224 # This file has been generated automatically.
 225 # It invokes QEMU to run binaries built for the target in the host during the
 226 # build process.
 227
 228 %s "$@"
 229 """ % qemu_cmd)
 230     os.chmod(wrapper_path, 0o755)
 231 }
 232 do_create_v8_qemu_wrapper[dirs] = "${B}"
 233 addtask create_v8_qemu_wrapper after do_patch before do_configure
 234
 235 python do_write_toolchain_file () {
 236     """Writes a BUILD.gn file for Yocto detailing its toolchains."""
 237     toolchain_dir = d.expand("${S}/src/build/toolchain/yocto")
 238     bb.utils.mkdirhier(toolchain_dir)
 239     toolchain_file = os.path.join(toolchain_dir, "BUILD.gn")
 240     write_toolchain_file(d, toolchain_file)
 241 }
 242 addtask write_toolchain_file after do_patch before do_configure
 243
 244 # More options to speed up the build
 245 GN_ARGS += "\
 246     enable_nacl=false\
 247     disable_ftp_support=true\
 248     enable_print_preview=false\
 249     enable_remoting=false\
 250     use_glib=true\
 251     use_gnome_keyring=false\
 252     use_pulseaudio=false\
 253 "
 254
 255 # Respect ld-is-gold in DISTRO_FEATURES when enabling gold
 256 # Similar patch applied in meta-browser
 257 # http://patchwork.openembedded.org/patch/77755/
 258 EXTRA_OEGN_GOLD = "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', 'use_gold=true', 'use_gold=false', d)}"
 259 GN_ARGS += "${EXTRA_OEGN_GOLD}"
 260
 261 # Doesn't build for armv[45]*
 262 COMPATIBLE_MACHINE = "(-)"
 263 COMPATIBLE_MACHINE_aarch64 = "(.*)"
 264 COMPATIBLE_MACHINE_armv6 = "(.*)"
 265 COMPATIBLE_MACHINE_armv7a = "(.*)"
 266 COMPATIBLE_MACHINE_armv7ve = "(.*)"
 267 COMPATIBLE_MACHINE_x86 = "(.*)"
 268 COMPATIBLE_MACHINE_x86-64 = "(.*)"
 269
 270 #CHROMIUM_PLUGINS_PATH = "${libdir}"
 271 CBE_DATA_PATH = "${libdir}/cbe"
 272 CBE_DATA_LOCALES_PATH = "${CBE_DATA_PATH}/locales"
 273
 274 # The text relocations are intentional -- see comments in [GF-52468]
 275 # TODO: check if we need INSANE_SKIP on ldflags
 276 INSANE_SKIP_${PN} = "textrel ldflags"
 277
 278
 279 do_compile[progress] = "outof:^\[(\d+)/(\d+)\]\s+"
 280 do_compile() {
 281     if [ ! -f ${OUT_DIR}/${BUILD_TYPE}/build.ninja ]; then
 282          do_configure
 283     fi
 284
 285     export PATH="${S}/depot_tools:$PATH"
 286     ${S}/depot_tools/ninja -v -C ${OUT_DIR}/${BUILD_TYPE} ${TARGET}
 287 }
 288
 289 do_configure() {
 290     configure_env
 291 }
 292
 293 configure_env() {
 294     export GYP_CHROMIUM_NO_ACTION=1
 295     export PATH="${S}/depot_tools:$PATH"
 296
 297     GN_ARGS="${GN_ARGS}"
 298     echo GN_ARGS is ${GN_ARGS}
 299     echo BUILD_TARGETS are ${TARGET}
 300     cd ${SRC_DIR}
 301     gn gen ${OUT_DIR}/${BUILD_TYPE} --args="${GN_ARGS}"
 302 }
 303
 304 WINDOW_SIZE ?= "1920,1080"
 305
 306 configure_browser_settings() {
 307     USER_AGENT="Mozilla/5.0 (Linux; NetCast; U) AppleWebKit/537.31 (KHTML, like Gecko) Chrome/${CHROMIUM_VERSION} Safari/537.31"
 308     echo "${USER_AGENT}" > ${D_DIR}/user_agent_conf
 309     #We can replace below WINDOW_SIZE values from build configuration if available
 310     #echo "${WINDOW_SIZE}" > ${D_DIR}/window_size_conf
 311 }
 312
 313 install_chromium_browser() {
 314     D_DIR=${D}${BROWSER_APPLICATION_DIR}
 315     install -d ${D_DIR}
 316
 317     # Install browser files
 318      if [ -e "${SRC_DIR}/webos/install" ]; then
 319          cd ${OUT_DIR}/${BUILD_TYPE}
 320          xargs --arg-file=${SRC_DIR}/webos/install/default_browser/binary.list cp -R --no-dereference --preserve=mode,links -v --target-directory=${D_DIR}
 321          cd ${SRC_DIR}
 322          xargs --arg-file=${SRC_DIR}/webos/install/default_browser/runtime.list cp -R --no-dereference --preserve=mode,links -v --target-directory=${D_DIR}
 323      fi
 324
 325     # AGL does not have PMLOG
 326     sed -i.bak s/PmLogCtl.*// ${D_DIR}/run_webbrowser
 327
 328     # To execute chromium in JAILER, Security Part needs permissions change
 329     # run_webbrowser: Script file for launching chromium
 330     chmod -v 755 ${D_DIR}/chrome
 331     chmod -v 755 ${D_DIR}/kill_webbrowser
 332     chmod -v 755 ${D_DIR}/run_webbrowser
 333
 334     configure_browser_settings
 335 }
 336
 337 MKSNAPSHOT_PATH = ""
 338 MKSNAPSHOT_PATH_arm = "clang_x86_v8_arm/"
 339 MKSNAPSHOT_PATH_aarch64 = "clang_x64_v8_arm64/"
 340
 341 install_webruntime() {
 342     install -d ${D}${libdir}
 343     install -d ${D}${includedir}/${BPN}
 344     install -d ${D}${CBE_DATA_PATH}
 345     install -d ${D}${CBE_DATA_LOCALES_PATH}
 346
 347     # Install webos webview files
 348     if [ -e "${SRC_DIR}/webos/install" ]; then
 349         cd ${SRC_DIR}
 350         xargs --arg-file=${SRC_DIR}/webos/install/weboswebruntime/staging_inc.list cp --parents --target-directory=${D}${includedir}/${BPN}
 351
 352         cd ${OUT_DIR}/${BUILD_TYPE}
 353
 354         cp libcbe.so ${D}${libdir}/
 355         if [ "${WEBOS_LTTNG_ENABLED}" = "1" ]; then
 356           # use bindir if building non-cbe
 357           cp libchromium_lttng_provider.so ${D}${libdir}/
 358         fi
 359         xargs --arg-file=${SRC_DIR}/webos/install/weboswebruntime/binary.list cp --parents --target-directory=${D}${CBE_DATA_PATH}
 360         cat ${SRC_DIR}/webos/install/weboswebruntime/data_locales.list | xargs -I{} install -m 755 -p {} ${D}${CBE_DATA_LOCALES_PATH}
 361     fi
 362
 363     # move this to separate mksnapshot-cross recipe once we figure out how to build just cross mksnapshot from chromium repository
 364     install -d ${D}${bindir_cross}
 365     gzip -c ${OUT_DIR}/${BUILD_TYPE}/${MKSNAPSHOT_PATH}mksnapshot > ${D}${bindir_cross}/${HOST_SYS}-mksnapshot.gz
 366 }
 367
 368 do_install() {
 369     install_webruntime
 370     install_chromium_browser
 371 }
 372
 373 WEBOS_SYSTEM_BUS_DIRS_LEGACY_BROWSER_APPLICATION = " \
 374     ${webos_sysbus_prvservicesdir}/${BROWSER_APPLICATION}.service \
 375     ${webos_sysbus_pubservicesdir}/${BROWSER_APPLICATION}.service \
 376     ${webos_sysbus_prvrolesdir}/${BROWSER_APPLICATION}.json \
 377     ${webos_sysbus_pubrolesdir}/${BROWSER_APPLICATION}.json \
 378 "
 379
 380 SYSROOT_DIRS_append = " ${bindir_cross}"
 381
 382 PACKAGES_prepend = " \
 383     ${PN}-cross-mksnapshot \
 384     ${BROWSER_APPLICATION} \
 385 "
 386
 387 FILES_${BROWSER_APPLICATION} += " \
 388     ${BROWSER_APPLICATION_DIR} \
 389     ${WEBOS_SYSTEM_BUS_DIRS_LEGACY_BROWSER_APPLICATION} \
 390 "
 391
 392 RDEPENDS_${BROWSER_APPLICATION} += "${PN}"
 393
 394 VIRTUAL-RUNTIME_gpu-libs ?= ""
 395 RDEPENDS_${PN} += "${VIRTUAL-RUNTIME_gpu-libs}"
 396
 397 # The text relocations are intentional -- see comments in [GF-52468]
 398 # TODO: check if we need INSANE_SKIP on ldflags
 399 INSANE_SKIP_${BROWSER_APPLICATION} += "libdir ldflags textrel"
 400
 401 FILES_${PN} = " \
 402     ${libdir}/*.so \
 403     ${CBE_DATA_PATH}/* \
 404     ${libdir}/${BPN}/*.so \
 405     ${WEBOS_SYSTEM_BUS_DIRS} \
 406 "
 407
 408 FILES_${PN}-dev = " \
 409     ${includedir} \
 410 "
 411
 412 FILES_${PN}-cross-mksnapshot = "${bindir_cross}/${HOST_SYS}-mksnapshot.gz"